gitweb.ps.run Git - ps-gitweb/blob - gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 require v5.26;
  11 use strict;
  12 use warnings;
  13 # handle ACL in file access tests
  14 use filetest 'access';
  15 use CGI qw(:standard :escapeHTML -nosticky);
  16 use CGI::Util qw(unescape);
  17 use CGI::Carp qw(fatalsToBrowser set_message);
  18 use Encode;
  19 use Fcntl ':mode';
  20 use File::Find qw();
  21 use File::Basename qw(basename dirname);
  22 use File::Spec;
  23 use Time::HiRes qw(gettimeofday tv_interval);
  24 use Digest::MD5 qw(md5_hex);
  25
  26 binmode STDOUT, ':utf8';
  27
  28 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  29         eval 'sub CGI::multi_param { CGI::param(@_) }'
  30 }
  31
  32 our $t0 = [ gettimeofday() ];
  33 our $number_of_git_cmds = 0;
  34
  35 BEGIN {
  36         CGI->compile() if $ENV{'MOD_PERL'};
  37 }
  38
  39 our $version = "@GIT_VERSION@";
  40
  41 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  42 sub evaluate_uri {
  43         our $cgi;
  44
  45         our $my_url = $cgi->url();
  46         our $my_uri = $cgi->url(-absolute => 1);
  47
  48         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  49         # needed and used only for URLs with nonempty PATH_INFO
  50         our $base_url = $my_url;
  51
  52         # When the script is used as DirectoryIndex, the URL does not contain the name
  53         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  54         # have to do it ourselves. We make $path_info global because it's also used
  55         # later on.
  56         #
  57         # Another issue with the script being the DirectoryIndex is that the resulting
  58         # $my_url data is not the full script URL: this is good, because we want
  59         # generated links to keep implying the script name if it wasn't explicitly
  60         # indicated in the URL we're handling, but it means that $my_url cannot be used
  61         # as base URL.
  62         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  63         # to build the base URL ourselves:
  64         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  65         if ($path_info) {
  66                 # $path_info has already been URL-decoded by the web server, but
  67                 # $my_url and $my_uri have not. URL-decode them so we can properly
  68                 # strip $path_info.
  69                 $my_url = unescape($my_url);
  70                 $my_uri = unescape($my_uri);
  71                 if ($my_url =~ s,\Q$path_info\E$,, &&
  72                     $my_uri =~ s,\Q$path_info\E$,, &&
  73                     defined $ENV{'SCRIPT_NAME'}) {
  74                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  75                 }
  76         }
  77
  78         # target of the home link on top of all pages
  79         our $home_link = $my_uri || "/";
  80 }
  81
  82 # core git executable to use
  83 # this can just be "git" if your webserver has a sensible PATH
  84 our $GIT = "@GIT_BINDIR@/git";
  85 our $PERL = "perl";
  86 our $MD = "markdown";
  87
  88 # absolute fs-path which will be prepended to the project path
  89 #our $projectroot = "/pub/scm";
  90 our $projectroot = "@GITWEB_PROJECTROOT@";
  91
  92 # fs traversing limit for getting project list
  93 # the number is relative to the projectroot
  94 our $project_maxdepth = @GITWEB_PROJECT_MAXDEPTH@;
  95
  96 # string of the home link on top of all pages
  97 our $home_link_str = "@GITWEB_HOME_LINK_STR@";
  98
  99 # extra breadcrumbs preceding the home link
 100 our @extra_breadcrumbs = ();
 101
 102 # name of your site or organization to appear in page titles
 103 # replace this with something more descriptive for clearer bookmarks
 104 our $site_name = "@GITWEB_SITENAME@"
 105                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
 106
 107 # html snippet to include in the <head> section of each page
 108 our $site_html_head_string = "@GITWEB_SITE_HTML_HEAD_STRING@";
 109 # filename of html text to include at top of each page
 110 our $site_header = "@GITWEB_SITE_HEADER@";
 111 # html text to include at home page
 112 our $home_text = "@GITWEB_HOMETEXT@";
 113 # filename of html text to include at bottom of each page
 114 our $site_footer = "@GITWEB_SITE_FOOTER@";
 115
 116 # URI of stylesheets
 117 our @stylesheets = ("@GITWEB_CSS@");
 118 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 119 our $stylesheet = undef;
 120 # URI of GIT logo (72x27 size)
 121 our $logo = "@GITWEB_LOGO@";
 122 # URI of GIT favicon, assumed to be image/png type
 123 our $favicon = "@GITWEB_FAVICON@";
 124 # URI of gitweb.js (JavaScript code for gitweb)
 125 our $javascript = "@GITWEB_JS@";
 126
 127 # URI and label (title) of GIT logo link
 128 #our $logo_url = "https://www.kernel.org/pub/software/scm/git/docs/";
 129 #our $logo_label = "git documentation";
 130 our $logo_url = "https://git-scm.com/";
 131 our $logo_label = "git homepage";
 132
 133 # source of projects list
 134 our $projects_list = "@GITWEB_LIST@";
 135
 136 # the width (in characters) of the projects list "Description" column
 137 our $projects_list_description_width = 25;
 138
 139 # group projects by category on the projects list
 140 # (enabled if this variable evaluates to true)
 141 our $projects_list_group_categories = 0;
 142
 143 # default category if none specified
 144 # (leave the empty string for no category)
 145 our $project_list_default_category = "";
 146
 147 # default order of projects list
 148 # valid values are none, project, descr, owner, and age
 149 our $default_projects_order = "project";
 150
 151 # show repository only if this file exists
 152 # (only effective if this variable evaluates to true)
 153 our $export_ok = "@GITWEB_EXPORT_OK@";
 154
 155 # don't generate age column on the projects list page
 156 our $omit_age_column = 0;
 157
 158 # don't generate information about owners of repositories
 159 our $omit_owner=0;
 160
 161 # show repository only if this subroutine returns true
 162 # when given the path to the project, for example:
 163 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 164 our $export_auth_hook = undef;
 165
 166 # only allow viewing of repositories also shown on the overview page
 167 our $strict_export = "@GITWEB_STRICT_EXPORT@";
 168
 169 # list of git base URLs used for URL to where fetch project from,
 170 # i.e. full URL is "$git_base_url/$project"
 171 our @git_base_url_list = grep { $_ ne '' } ("@GITWEB_BASE_URL@");
 172
 173 # default blob_plain mimetype and default charset for text/plain blob
 174 our $default_blob_plain_mimetype = 'text/plain';
 175 our $default_text_plain_charset  = undef;
 176
 177 # file to use for guessing MIME types before trying /etc/mime.types
 178 # (relative to the current git repository)
 179 our $mimetypes_file = undef;
 180
 181 # assume this charset if line contains non-UTF-8 characters;
 182 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 183 # for which encoding all byte sequences are valid, for example
 184 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 185 # could be even 'utf-8' for the old behavior)
 186 our $fallback_encoding = 'latin1';
 187
 188 # rename detection options for git-diff and git-diff-tree
 189 # - default is '-M', with the cost proportional to
 190 #   (number of removed files) * (number of new files).
 191 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 192 #   (number of changed files + number of removed files) * (number of new files)
 193 # - even more costly is '-C', '--find-copies-harder' with cost
 194 #   (number of files in the original tree) * (number of new files)
 195 # - one might want to include '-B' option, e.g. '-B', '-M'
 196 our @diff_opts = ('-M'); # taken from git_commit
 197
 198 # Disables features that would allow repository owners to inject script into
 199 # the gitweb domain.
 200 our $prevent_xss = 0;
 201
 202 # Path to the highlight executable to use (must be the one from
 203 # http://andre-simon.de/zip/download.php due to assumptions about parameters and output).
 204 # Useful if highlight is not installed on your webserver's PATH.
 205 # [Default: highlight]
 206 our $highlight_bin = "@HIGHLIGHT_BIN@";
 207
 208 # information about snapshot formats that gitweb is capable of serving
 209 our %known_snapshot_formats = (
 210         # name => {
 211         #       'display' => display name,
 212         #       'type' => mime type,
 213         #       'suffix' => filename suffix,
 214         #       'format' => --format for git-archive,
 215         #       'compressor' => [compressor command and arguments]
 216         #                       (array reference, optional)
 217         #       'disabled' => boolean (optional)}
 218         #
 219         'tgz' => {
 220                 'display' => 'tar.gz',
 221                 'type' => 'application/x-gzip',
 222                 'suffix' => '.tar.gz',
 223                 'format' => 'tar',
 224                 'compressor' => ['gzip', '-n']},
 225
 226         'tbz2' => {
 227                 'display' => 'tar.bz2',
 228                 'type' => 'application/x-bzip2',
 229                 'suffix' => '.tar.bz2',
 230                 'format' => 'tar',
 231                 'compressor' => ['bzip2']},
 232
 233         'txz' => {
 234                 'display' => 'tar.xz',
 235                 'type' => 'application/x-xz',
 236                 'suffix' => '.tar.xz',
 237                 'format' => 'tar',
 238                 'compressor' => ['xz'],
 239                 'disabled' => 1},
 240
 241         'zip' => {
 242                 'display' => 'zip',
 243                 'type' => 'application/x-zip',
 244                 'suffix' => '.zip',
 245                 'format' => 'zip'},
 246 );
 247
 248 # Aliases so we understand old gitweb.snapshot values in repository
 249 # configuration.
 250 our %known_snapshot_format_aliases = (
 251         'gzip'  => 'tgz',
 252         'bzip2' => 'tbz2',
 253         'xz'    => 'txz',
 254
 255         # backward compatibility: legacy gitweb config support
 256         'x-gzip' => undef, 'gz' => undef,
 257         'x-bzip2' => undef, 'bz2' => undef,
 258         'x-zip' => undef, '' => undef,
 259 );
 260
 261 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 262 # are changed, it may be appropriate to change these values too via
 263 # $GITWEB_CONFIG.
 264 our %avatar_size = (
 265         'default' => 16,
 266         'double'  => 32
 267 );
 268
 269 # Used to set the maximum load that we will still respond to gitweb queries.
 270 # If server load exceed this value then return "503 server busy" error.
 271 # If gitweb cannot determined server load, it is taken to be 0.
 272 # Leave it undefined (or set to 'undef') to turn off load checking.
 273 our $maxload = 300;
 274
 275 # configuration for 'highlight' (http://andre-simon.de/doku/highlight/en/highlight.php)
 276 # match by basename
 277 our %highlight_basename = (
 278         #'Program' => 'py',
 279         #'Library' => 'py',
 280         'SConstruct' => 'py', # SCons equivalent of Makefile
 281         'Makefile' => 'make',
 282 );
 283 # match by extension
 284 our %highlight_ext = (
 285         # main extensions, defining name of syntax;
 286         # see files in /usr/share/highlight/langDefs/ directory
 287         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 288         # alternate extensions, see /etc/highlight/filetypes.conf
 289         (map { $_ => 'c'   } qw(c h)),
 290         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 291         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 292         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 293         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 294         (map { $_ => 'make'} qw(make mak mk)),
 295         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 296 );
 297
 298 # You define site-wide feature defaults here; override them with
 299 # $GITWEB_CONFIG as necessary.
 300 our %feature = (
 301         # feature => {
 302         #       'sub' => feature-sub (subroutine),
 303         #       'override' => allow-override (boolean),
 304         #       'default' => [ default options...] (array reference)}
 305         #
 306         # if feature is overridable (it means that allow-override has true value),
 307         # then feature-sub will be called with default options as parameters;
 308         # return value of feature-sub indicates if to enable specified feature
 309         #
 310         # if there is no 'sub' key (no feature-sub), then feature cannot be
 311         # overridden
 312         #
 313         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 314         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 315         # is enabled
 316
 317         # Enable the 'blame' blob view, showing the last commit that modified
 318         # each line in the file. This can be very CPU-intensive.
 319
 320         # To enable system wide have in $GITWEB_CONFIG
 321         # $feature{'blame'}{'default'} = [1];
 322         # To have project specific config enable override in $GITWEB_CONFIG
 323         # $feature{'blame'}{'override'} = 1;
 324         # and in project config gitweb.blame = 0|1;
 325         'blame' => {
 326                 'sub' => sub { feature_bool('blame', @_) },
 327                 'override' => 0,
 328                 'default' => [0]},
 329
 330         # Enable the 'snapshot' link, providing a compressed archive of any
 331         # tree. This can potentially generate high traffic if you have large
 332         # project.
 333
 334         # Value is a list of formats defined in %known_snapshot_formats that
 335         # you wish to offer.
 336         # To disable system wide have in $GITWEB_CONFIG
 337         # $feature{'snapshot'}{'default'} = [];
 338         # To have project specific config enable override in $GITWEB_CONFIG
 339         # $feature{'snapshot'}{'override'} = 1;
 340         # and in project config, a comma-separated list of formats or "none"
 341         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 342         'snapshot' => {
 343                 'sub' => \&feature_snapshot,
 344                 'override' => 0,
 345                 'default' => ['tgz']},
 346
 347         # Enable text search, which will list the commits which match author,
 348         # committer or commit text to a given string.  Enabled by default.
 349         # Project specific override is not supported.
 350         #
 351         # Note that this controls all search features, which means that if
 352         # it is disabled, then 'grep' and 'pickaxe' search would also be
 353         # disabled.
 354         'search' => {
 355                 'override' => 0,
 356                 'default' => [1]},
 357
 358         # Enable grep search, which will list the files in currently selected
 359         # tree containing the given string. Enabled by default. This can be
 360         # potentially CPU-intensive, of course.
 361         # Note that you need to have 'search' feature enabled too.
 362
 363         # To enable system wide have in $GITWEB_CONFIG
 364         # $feature{'grep'}{'default'} = [1];
 365         # To have project specific config enable override in $GITWEB_CONFIG
 366         # $feature{'grep'}{'override'} = 1;
 367         # and in project config gitweb.grep = 0|1;
 368         'grep' => {
 369                 'sub' => sub { feature_bool('grep', @_) },
 370                 'override' => 0,
 371                 'default' => [1]},
 372
 373         # Enable the pickaxe search, which will list the commits that modified
 374         # a given string in a file. This can be practical and quite faster
 375         # alternative to 'blame', but still potentially CPU-intensive.
 376         # Note that you need to have 'search' feature enabled too.
 377
 378         # To enable system wide have in $GITWEB_CONFIG
 379         # $feature{'pickaxe'}{'default'} = [1];
 380         # To have project specific config enable override in $GITWEB_CONFIG
 381         # $feature{'pickaxe'}{'override'} = 1;
 382         # and in project config gitweb.pickaxe = 0|1;
 383         'pickaxe' => {
 384                 'sub' => sub { feature_bool('pickaxe', @_) },
 385                 'override' => 0,
 386                 'default' => [1]},
 387
 388         # Enable showing size of blobs in a 'tree' view, in a separate
 389         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 390
 391         # To disable system wide have in $GITWEB_CONFIG
 392         # $feature{'show-sizes'}{'default'} = [0];
 393         # To have project specific config enable override in $GITWEB_CONFIG
 394         # $feature{'show-sizes'}{'override'} = 1;
 395         # and in project config gitweb.showsizes = 0|1;
 396         'show-sizes' => {
 397                 'sub' => sub { feature_bool('showsizes', @_) },
 398                 'override' => 0,
 399                 'default' => [1]},
 400
 401         # Make gitweb use an alternative format of the URLs which can be
 402         # more readable and natural-looking: project name is embedded
 403         # directly in the path and the query string contains other
 404         # auxiliary information. All gitweb installations recognize
 405         # URL in either format; this configures in which formats gitweb
 406         # generates links.
 407
 408         # To enable system wide have in $GITWEB_CONFIG
 409         # $feature{'pathinfo'}{'default'} = [1];
 410         # Project specific override is not supported.
 411
 412         # Note that you will need to change the default location of CSS,
 413         # favicon, logo and possibly other files to an absolute URL. Also,
 414         # if gitweb.cgi serves as your indexfile, you will need to force
 415         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 416         'pathinfo' => {
 417                 'override' => 0,
 418                 'default' => [0]},
 419
 420         # Make gitweb consider projects in project root subdirectories
 421         # to be forks of existing projects. Given project $projname.git,
 422         # projects matching $projname/*.git will not be shown in the main
 423         # projects list, instead a '+' mark will be added to $projname
 424         # there and a 'forks' view will be enabled for the project, listing
 425         # all the forks. If project list is taken from a file, forks have
 426         # to be listed after the main project.
 427
 428         # To enable system wide have in $GITWEB_CONFIG
 429         # $feature{'forks'}{'default'} = [1];
 430         # Project specific override is not supported.
 431         'forks' => {
 432                 'override' => 0,
 433                 'default' => [0]},
 434
 435         # Insert custom links to the action bar of all project pages.
 436         # This enables you mainly to link to third-party scripts integrating
 437         # into gitweb; e.g. git-browser for graphical history representation
 438         # or custom web-based repository administration interface.
 439
 440         # The 'default' value consists of a list of triplets in the form
 441         # (label, link, position) where position is the label after which
 442         # to insert the link and link is a format string where %n expands
 443         # to the project name, %f to the project path within the filesystem,
 444         # %h to the current hash (h gitweb parameter) and %b to the current
 445         # hash base (hb gitweb parameter); %% expands to %.
 446
 447         # To enable system wide have in $GITWEB_CONFIG e.g.
 448         # $feature{'actions'}{'default'} = [('graphiclog',
 449         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 450         # Project specific override is not supported.
 451         'actions' => {
 452                 'override' => 0,
 453                 'default' => []},
 454
 455         # Allow gitweb scan project content tags of project repository,
 456         # and display the popular Web 2.0-ish "tag cloud" near the projects
 457         # list.  Note that this is something COMPLETELY different from the
 458         # normal Git tags.
 459
 460         # gitweb by itself can show existing tags, but it does not handle
 461         # tagging itself; you need to do it externally, outside gitweb.
 462         # The format is described in git_get_project_ctags() subroutine.
 463         # You may want to install the HTML::TagCloud Perl module to get
 464         # a pretty tag cloud instead of just a list of tags.
 465
 466         # To enable system wide have in $GITWEB_CONFIG
 467         # $feature{'ctags'}{'default'} = [1];
 468         # Project specific override is not supported.
 469
 470         # In the future whether ctags editing is enabled might depend
 471         # on the value, but using 1 should always mean no editing of ctags.
 472         'ctags' => {
 473                 'override' => 0,
 474                 'default' => [0]},
 475
 476         # The maximum number of patches in a patchset generated in patch
 477         # view. Set this to 0 or undef to disable patch view, or to a
 478         # negative number to remove any limit.
 479
 480         # To disable system wide have in $GITWEB_CONFIG
 481         # $feature{'patches'}{'default'} = [0];
 482         # To have project specific config enable override in $GITWEB_CONFIG
 483         # $feature{'patches'}{'override'} = 1;
 484         # and in project config gitweb.patches = 0|n;
 485         # where n is the maximum number of patches allowed in a patchset.
 486         'patches' => {
 487                 'sub' => \&feature_patches,
 488                 'override' => 0,
 489                 'default' => [16]},
 490
 491         # Avatar support. When this feature is enabled, views such as
 492         # shortlog or commit will display an avatar associated with
 493         # the email of the committer(s) and/or author(s).
 494
 495         # Currently available providers are gravatar and picon.
 496         # If an unknown provider is specified, the feature is disabled.
 497
 498         # Picon currently relies on the indiana.edu database.
 499
 500         # To enable system wide have in $GITWEB_CONFIG
 501         # $feature{'avatar'}{'default'} = ['<provider>'];
 502         # where <provider> is either gravatar or picon.
 503         # To have project specific config enable override in $GITWEB_CONFIG
 504         # $feature{'avatar'}{'override'} = 1;
 505         # and in project config gitweb.avatar = <provider>;
 506         'avatar' => {
 507                 'sub' => \&feature_avatar,
 508                 'override' => 0,
 509                 'default' => ['']},
 510
 511         # Enable displaying how much time and how many git commands
 512         # it took to generate and display page.  Disabled by default.
 513         # Project specific override is not supported.
 514         'timed' => {
 515                 'override' => 0,
 516                 'default' => [0]},
 517
 518         # Enable turning some links into links to actions which require
 519         # JavaScript to run (like 'blame_incremental').  Not enabled by
 520         # default.  Project specific override is currently not supported.
 521         'javascript-actions' => {
 522                 'override' => 0,
 523                 'default' => [0]},
 524
 525         # Enable and configure ability to change common timezone for dates
 526         # in gitweb output via JavaScript.  Enabled by default.
 527         # Project specific override is not supported.
 528         'javascript-timezone' => {
 529                 'override' => 0,
 530                 'default' => [
 531                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 532                                      # or undef to turn off this feature
 533                         'gitweb_tz', # name of cookie where to store selected timezone
 534                         'datetime',  # CSS class used to mark up dates for manipulation
 535                 ]},
 536
 537         # Syntax highlighting support. This is based on Daniel Svensson's
 538         # and Sham Chukoury's work in gitweb-xmms2.git.
 539         # It requires the 'highlight' program present in $PATH,
 540         # and therefore is disabled by default.
 541
 542         # To enable system wide have in $GITWEB_CONFIG
 543         # $feature{'highlight'}{'default'} = [1];
 544
 545         'highlight' => {
 546                 'sub' => sub { feature_bool('highlight', @_) },
 547                 'override' => 0,
 548                 'default' => [0]},
 549
 550         # Enable displaying of remote heads in the heads list
 551
 552         # To enable system wide have in $GITWEB_CONFIG
 553         # $feature{'remote_heads'}{'default'} = [1];
 554         # To have project specific config enable override in $GITWEB_CONFIG
 555         # $feature{'remote_heads'}{'override'} = 1;
 556         # and in project config gitweb.remoteheads = 0|1;
 557         'remote_heads' => {
 558                 'sub' => sub { feature_bool('remote_heads', @_) },
 559                 'override' => 0,
 560                 'default' => [0]},
 561
 562         # Enable showing branches under other refs in addition to heads
 563
 564         # To set system wide extra branch refs have in $GITWEB_CONFIG
 565         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 566         # To have project specific config enable override in $GITWEB_CONFIG
 567         # $feature{'extra-branch-refs'}{'override'} = 1;
 568         # and in project config gitweb.extrabranchrefs = dirs of choice
 569         # Every directory is separated with whitespace.
 570
 571         'extra-branch-refs' => {
 572                 'sub' => \&feature_extra_branch_refs,
 573                 'override' => 0,
 574                 'default' => []},
 575
 576         # Redact e-mail addresses.
 577
 578         # To enable system wide have in $GITWEB_CONFIG
 579         # $feature{'email-privacy'}{'default'} = [1];
 580         'email-privacy' => {
 581                 'sub' => sub { feature_bool('email-privacy', @_) },
 582                 'override' => 1,
 583                 'default' => [0]},
 584 );
 585
 586 sub gitweb_get_feature {
 587         my ($name) = @_;
 588         return unless exists $feature{$name};
 589         my ($sub, $override, @defaults) = (
 590                 $feature{$name}{'sub'},
 591                 $feature{$name}{'override'},
 592                 @{$feature{$name}{'default'}});
 593         # project specific override is possible only if we have project
 594         our $git_dir; # global variable, declared later
 595         if (!$override || !defined $git_dir) {
 596                 return @defaults;
 597         }
 598         if (!defined $sub) {
 599                 warn "feature $name is not overridable";
 600                 return @defaults;
 601         }
 602         return $sub->(@defaults);
 603 }
 604
 605 # A wrapper to check if a given feature is enabled.
 606 # With this, you can say
 607 #
 608 #   my $bool_feat = gitweb_check_feature('bool_feat');
 609 #   gitweb_check_feature('bool_feat') or somecode;
 610 #
 611 # instead of
 612 #
 613 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 614 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 615 #
 616 sub gitweb_check_feature {
 617         return (gitweb_get_feature(@_))[0];
 618 }
 619
 620
 621 sub feature_bool {
 622         my $key = shift;
 623         my ($val) = git_get_project_config($key, '--bool');
 624
 625         if (!defined $val) {
 626                 return ($_[0]);
 627         } elsif ($val eq 'true') {
 628                 return (1);
 629         } elsif ($val eq 'false') {
 630                 return (0);
 631         }
 632 }
 633
 634 sub feature_snapshot {
 635         my (@fmts) = @_;
 636
 637         my ($val) = git_get_project_config('snapshot');
 638
 639         if ($val) {
 640                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 641         }
 642
 643         return @fmts;
 644 }
 645
 646 sub feature_patches {
 647         my @val = (git_get_project_config('patches', '--int'));
 648
 649         if (@val) {
 650                 return @val;
 651         }
 652
 653         return ($_[0]);
 654 }
 655
 656 sub feature_avatar {
 657         my @val = (git_get_project_config('avatar'));
 658
 659         return @val ? @val : @_;
 660 }
 661
 662 sub feature_extra_branch_refs {
 663         my (@branch_refs) = @_;
 664         my $values = git_get_project_config('extrabranchrefs');
 665
 666         if ($values) {
 667                 $values = config_to_multi ($values);
 668                 @branch_refs = ();
 669                 foreach my $value (@{$values}) {
 670                         push @branch_refs, split /\s+/, $value;
 671                 }
 672         }
 673
 674         return @branch_refs;
 675 }
 676
 677 # checking HEAD file with -e is fragile if the repository was
 678 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 679 # and then pruned.
 680 sub check_head_link {
 681         my ($dir) = @_;
 682         my $headfile = "$dir/HEAD";
 683         return ((-e $headfile) ||
 684                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 685 }
 686
 687 sub check_export_ok {
 688         my ($dir) = @_;
 689         return (check_head_link($dir) &&
 690                 (!$export_ok || -e "$dir/$export_ok") &&
 691                 (!$export_auth_hook || $export_auth_hook->($dir)));
 692 }
 693
 694 # process alternate names for backward compatibility
 695 # filter out unsupported (unknown) snapshot formats
 696 sub filter_snapshot_fmts {
 697         my @fmts = @_;
 698
 699         @fmts = map {
 700                 exists $known_snapshot_format_aliases{$_} ?
 701                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 702         @fmts = grep {
 703                 exists $known_snapshot_formats{$_} &&
 704                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 705 }
 706
 707 sub filter_and_validate_refs {
 708         my @refs = @_;
 709         my %unique_refs = ();
 710
 711         foreach my $ref (@refs) {
 712                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 713                 # 'heads' are added implicitly in get_branch_refs().
 714                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 715         }
 716         return sort keys %unique_refs;
 717 }
 718
 719 # If it is set to code reference, it is code that it is to be run once per
 720 # request, allowing updating configurations that change with each request,
 721 # while running other code in config file only once.
 722 #
 723 # Otherwise, if it is false then gitweb would process config file only once;
 724 # if it is true then gitweb config would be run for each request.
 725 our $per_request_config = 1;
 726
 727 # read and parse gitweb config file given by its parameter.
 728 # returns true on success, false on recoverable error, allowing
 729 # to chain this subroutine, using first file that exists.
 730 # dies on errors during parsing config file, as it is unrecoverable.
 731 sub read_config_file {
 732         my $filename = shift;
 733         return unless defined $filename;
 734         if (-e $filename) {
 735                 do $filename;
 736                 # die if there is a problem accessing the file
 737                 die $! if $!;
 738                 # die if there are errors parsing config file
 739                 die $@ if $@;
 740                 return 1;
 741         }
 742         return;
 743 }
 744
 745 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 746 sub evaluate_gitweb_config {
 747         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "@GITWEB_CONFIG@";
 748         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "@GITWEB_CONFIG_SYSTEM@";
 749         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "@GITWEB_CONFIG_COMMON@";
 750
 751         # Protect against duplications of file names, to not read config twice.
 752         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 753         # there possibility of duplication of filename there doesn't matter.
 754         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 755         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 756
 757         # Common system-wide settings for convenience.
 758         # Those settings can be overridden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 759         read_config_file($GITWEB_CONFIG_COMMON);
 760
 761         # Use first config file that exists.  This means use the per-instance
 762         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 763         read_config_file($GITWEB_CONFIG) and return;
 764         read_config_file($GITWEB_CONFIG_SYSTEM);
 765 }
 766
 767 # Get loadavg of system, to compare against $maxload.
 768 # Currently it requires '/proc/loadavg' present to get loadavg;
 769 # if it is not present it returns 0, which means no load checking.
 770 sub get_loadavg {
 771         if( -e '/proc/loadavg' ){
 772                 open my $fd, '<', '/proc/loadavg'
 773                         or return 0;
 774                 my @load = split(/\s+/, scalar <$fd>);
 775                 close $fd;
 776
 777                 # The first three columns measure CPU and IO utilization of the last one,
 778                 # five, and 10 minute periods.  The fourth column shows the number of
 779                 # currently running processes and the total number of processes in the m/n
 780                 # format.  The last column displays the last process ID used.
 781                 return $load[0] || 0;
 782         }
 783         # additional checks for load average should go here for things that don't export
 784         # /proc/loadavg
 785
 786         return 0;
 787 }
 788
 789 # version of the core git binary
 790 our $git_version;
 791 sub evaluate_git_version {
 792         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 793         $number_of_git_cmds++;
 794 }
 795
 796 sub check_loadavg {
 797         if (defined $maxload && get_loadavg() > $maxload) {
 798                 die_error(503, "The load average on the server is too high");
 799         }
 800 }
 801
 802 # ======================================================================
 803 # input validation and dispatch
 804
 805 # Various hash size-related values.
 806 my $sha1_len = 40;
 807 my $sha256_extra_len = 24;
 808 my $sha256_len = $sha1_len + $sha256_extra_len;
 809
 810 # A regex matching $len hex characters. $len may be a range (e.g. 7,64).
 811 sub oid_nlen_regex {
 812         my $len = shift;
 813         my $hchr = qr/[0-9a-fA-F]/;
 814         return qr/(?:(?:$hchr){$len})/;
 815 }
 816
 817 # A regex matching two sets of $nlen hex characters, prefixed by the literal
 818 # string $prefix and with the literal string $infix between them.
 819 sub oid_nlen_prefix_infix_regex {
 820         my $nlen = shift;
 821         my $prefix = shift;
 822         my $infix = shift;
 823
 824         my $rx = oid_nlen_regex($nlen);
 825
 826         return qr/^\Q$prefix\E$rx\Q$infix\E$rx$/;
 827 }
 828
 829 # A regex matching a valid object ID.
 830 our $oid_regex;
 831 {
 832         my $x = oid_nlen_regex($sha1_len);
 833         my $y = oid_nlen_regex($sha256_extra_len);
 834         $oid_regex = qr/(?:$x(?:$y)?)/;
 835 }
 836
 837 # input parameters can be collected from a variety of sources (presently, CGI
 838 # and PATH_INFO), so we define an %input_params hash that collects them all
 839 # together during validation: this allows subsequent uses (e.g. href()) to be
 840 # agnostic of the parameter origin
 841
 842 our %input_params = ();
 843
 844 # input parameters are stored with the long parameter name as key. This will
 845 # also be used in the href subroutine to convert parameters to their CGI
 846 # equivalent, and since the href() usage is the most frequent one, we store
 847 # the name -> CGI key mapping here, instead of the reverse.
 848 #
 849 # XXX: Warning: If you touch this, check the search form for updating,
 850 # too.
 851
 852 our @cgi_param_mapping = (
 853         project => "p",
 854         action => "a",
 855         file_name => "f",
 856         file_parent => "fp",
 857         hash => "h",
 858         hash_parent => "hp",
 859         hash_base => "hb",
 860         hash_parent_base => "hpb",
 861         page => "pg",
 862         order => "o",
 863         searchtext => "s",
 864         searchtype => "st",
 865         snapshot_format => "sf",
 866         extra_options => "opt",
 867         search_use_regexp => "sr",
 868         ctag => "by_tag",
 869         diff_style => "ds",
 870         project_filter => "pf",
 871         # this must be last entry (for manipulation from JavaScript)
 872         javascript => "js"
 873 );
 874 our %cgi_param_mapping = @cgi_param_mapping;
 875
 876 # we will also need to know the possible actions, for validation
 877 our %actions = (
 878         "blame" => \&git_blame,
 879         "blame_incremental" => \&git_blame_incremental,
 880         "blame_data" => \&git_blame_data,
 881         "blobdiff" => \&git_blobdiff,
 882         "blobdiff_plain" => \&git_blobdiff_plain,
 883         "blob" => \&git_blob,
 884         "blob_plain" => \&git_blob_plain,
 885         "commitdiff" => \&git_commitdiff,
 886         "commitdiff_plain" => \&git_commitdiff_plain,
 887         "commit" => \&git_commit,
 888         "forks" => \&git_forks,
 889         "heads" => \&git_heads,
 890         "history" => \&git_history,
 891         "log" => \&git_log,
 892         "patch" => \&git_patch,
 893         "patches" => \&git_patches,
 894         "remotes" => \&git_remotes,
 895         "rss" => \&git_rss,
 896         "atom" => \&git_atom,
 897         "search" => \&git_search,
 898         "search_help" => \&git_search_help,
 899         "shortlog" => \&git_shortlog,
 900         "summary" => \&git_summary,
 901         "tag" => \&git_tag,
 902         "tags" => \&git_tags,
 903         "tree" => \&git_tree,
 904         "snapshot" => \&git_snapshot,
 905         "object" => \&git_object,
 906         # those below don't need $project
 907         "opml" => \&git_opml,
 908         "project_list" => \&git_project_list,
 909         "project_index" => \&git_project_index,
 910 );
 911
 912 # finally, we have the hash of allowed extra_options for the commands that
 913 # allow them
 914 our %allowed_options = (
 915         "--no-merges" => [ qw(rss atom log shortlog history) ],
 916 );
 917
 918 # fill %input_params with the CGI parameters. All values except for 'opt'
 919 # should be single values, but opt can be an array. We should probably
 920 # build an array of parameters that can be multi-valued, but since for the time
 921 # being it's only this one, we just single it out
 922 sub evaluate_query_params {
 923         our $cgi;
 924
 925         while (my ($name, $symbol) = each %cgi_param_mapping) {
 926                 if ($symbol eq 'opt') {
 927                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 928                 } else {
 929                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 930                 }
 931         }
 932 }
 933
 934 # now read PATH_INFO and update the parameter list for missing parameters
 935 sub evaluate_path_info {
 936         return if defined $input_params{'project'};
 937         return if !$path_info;
 938         $path_info =~ s,^/+,,;
 939         return if !$path_info;
 940
 941         # find which part of PATH_INFO is project
 942         my $project = $path_info;
 943         $project =~ s,/+$,,;
 944         while ($project && !check_head_link("$projectroot/$project")) {
 945                 $project =~ s,/*[^/]*$,,;
 946         }
 947         return unless $project;
 948         $input_params{'project'} = $project;
 949
 950         # do not change any parameters if an action is given using the query string
 951         return if $input_params{'action'};
 952         $path_info =~ s,^\Q$project\E/*,,;
 953
 954         # next, check if we have an action
 955         my $action = $path_info;
 956         $action =~ s,/.*$,,;
 957         if (exists $actions{$action}) {
 958                 $path_info =~ s,^$action/*,,;
 959                 $input_params{'action'} = $action;
 960         }
 961
 962         # list of actions that want hash_base instead of hash, but can have no
 963         # pathname (f) parameter
 964         my @wants_base = (
 965                 'tree',
 966                 'history',
 967         );
 968
 969         # we want to catch, among others
 970         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 971         my ($parentrefname, $parentpathname, $refname, $pathname) =
 972                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 973
 974         # first, analyze the 'current' part
 975         if (defined $pathname) {
 976                 # we got "branch:filename" or "branch:dir/"
 977                 # we could use git_get_type(branch:pathname), but:
 978                 # - it needs $git_dir
 979                 # - it does a git() call
 980                 # - the convention of terminating directories with a slash
 981                 #   makes it superfluous
 982                 # - embedding the action in the PATH_INFO would make it even
 983                 #   more superfluous
 984                 $pathname =~ s,^/+,,;
 985                 if (!$pathname || substr($pathname, -1) eq "/") {
 986                         $input_params{'action'} ||= "tree";
 987                         $pathname =~ s,/$,,;
 988                 } else {
 989                         # the default action depends on whether we had parent info
 990                         # or not
 991                         if ($parentrefname) {
 992                                 $input_params{'action'} ||= "blobdiff_plain";
 993                         } else {
 994                                 $input_params{'action'} ||= "blob_plain";
 995                         }
 996                 }
 997                 $input_params{'hash_base'} ||= $refname;
 998                 $input_params{'file_name'} ||= $pathname;
 999         } elsif (defined $refname) {
1000                 # we got "branch". In this case we have to choose if we have to
1001                 # set hash or hash_base.
1002                 #
1003                 # Most of the actions without a pathname only want hash to be
1004                 # set, except for the ones specified in @wants_base that want
1005                 # hash_base instead. It should also be noted that hand-crafted
1006                 # links having 'history' as an action and no pathname or hash
1007                 # set will fail, but that happens regardless of PATH_INFO.
1008                 if (defined $parentrefname) {
1009                         # if there is parent let the default be 'shortlog' action
1010                         # (for http://git.example.com/repo.git/A..B links); if there
1011                         # is no parent, dispatch will detect type of object and set
1012                         # action appropriately if required (if action is not set)
1013                         $input_params{'action'} ||= "shortlog";
1014                 }
1015                 if ($input_params{'action'} &&
1016                     grep { $_ eq $input_params{'action'} } @wants_base) {
1017                         $input_params{'hash_base'} ||= $refname;
1018                 } else {
1019                         $input_params{'hash'} ||= $refname;
1020                 }
1021         }
1022
1023         # next, handle the 'parent' part, if present
1024         if (defined $parentrefname) {
1025                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
1026                 # someproject/blobdiff/oldrev..newrev:/filename
1027                 if ($parentpathname) {
1028                         $parentpathname =~ s,^/+,,;
1029                         $parentpathname =~ s,/$,,;
1030                         $input_params{'file_parent'} ||= $parentpathname;
1031                 } else {
1032                         $input_params{'file_parent'} ||= $input_params{'file_name'};
1033                 }
1034                 # we assume that hash_parent_base is wanted if a path was specified,
1035                 # or if the action wants hash_base instead of hash
1036                 if (defined $input_params{'file_parent'} ||
1037                         grep { $_ eq $input_params{'action'} } @wants_base) {
1038                         $input_params{'hash_parent_base'} ||= $parentrefname;
1039                 } else {
1040                         $input_params{'hash_parent'} ||= $parentrefname;
1041                 }
1042         }
1043
1044         # for the snapshot action, we allow URLs in the form
1045         # $project/snapshot/$hash.ext
1046         # where .ext determines the snapshot and gets removed from the
1047         # passed $refname to provide the $hash.
1048         #
1049         # To be able to tell that $refname includes the format extension, we
1050         # require the following two conditions to be satisfied:
1051         # - the hash input parameter MUST have been set from the $refname part
1052         #   of the URL (i.e. they must be equal)
1053         # - the snapshot format MUST NOT have been defined already (e.g. from
1054         #   CGI parameter sf)
1055         # It's also useless to try any matching unless $refname has a dot,
1056         # so we check for that too
1057         if (defined $input_params{'action'} &&
1058                 $input_params{'action'} eq 'snapshot' &&
1059                 defined $refname && index($refname, '.') != -1 &&
1060                 $refname eq $input_params{'hash'} &&
1061                 !defined $input_params{'snapshot_format'}) {
1062                 # We loop over the known snapshot formats, checking for
1063                 # extensions. Allowed extensions are both the defined suffix
1064                 # (which includes the initial dot already) and the snapshot
1065                 # format key itself, with a prepended dot
1066                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1067                         my $hash = $refname;
1068                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1069                                 next;
1070                         }
1071                         my $sfx = $1;
1072                         # a valid suffix was found, so set the snapshot format
1073                         # and reset the hash parameter
1074                         $input_params{'snapshot_format'} = $fmt;
1075                         $input_params{'hash'} = $hash;
1076                         # we also set the format suffix to the one requested
1077                         # in the URL: this way a request for e.g. .tgz returns
1078                         # a .tgz instead of a .tar.gz
1079                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1080                         last;
1081                 }
1082         }
1083 }
1084
1085 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1086      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1087      $searchtext, $search_regexp, $project_filter);
1088 sub evaluate_and_validate_params {
1089         our $action = $input_params{'action'};
1090         if (defined $action) {
1091                 if (!is_valid_action($action)) {
1092                         die_error(400, "Invalid action parameter");
1093                 }
1094         }
1095
1096         # parameters which are pathnames
1097         our $project = $input_params{'project'};
1098         if (defined $project) {
1099                 if (!is_valid_project($project)) {
1100                         undef $project;
1101                         die_error(404, "No such project");
1102                 }
1103         }
1104
1105         our $project_filter = $input_params{'project_filter'};
1106         if (defined $project_filter) {
1107                 if (!is_valid_pathname($project_filter)) {
1108                         die_error(404, "Invalid project_filter parameter");
1109                 }
1110         }
1111
1112         our $file_name = $input_params{'file_name'};
1113         if (defined $file_name) {
1114                 if (!is_valid_pathname($file_name)) {
1115                         die_error(400, "Invalid file parameter");
1116                 }
1117         }
1118
1119         our $file_parent = $input_params{'file_parent'};
1120         if (defined $file_parent) {
1121                 if (!is_valid_pathname($file_parent)) {
1122                         die_error(400, "Invalid file parent parameter");
1123                 }
1124         }
1125
1126         # parameters which are refnames
1127         our $hash = $input_params{'hash'};
1128         if (defined $hash) {
1129                 if (!is_valid_refname($hash)) {
1130                         die_error(400, "Invalid hash parameter");
1131                 }
1132         }
1133
1134         our $hash_parent = $input_params{'hash_parent'};
1135         if (defined $hash_parent) {
1136                 if (!is_valid_refname($hash_parent)) {
1137                         die_error(400, "Invalid hash parent parameter");
1138                 }
1139         }
1140
1141         our $hash_base = $input_params{'hash_base'};
1142         if (defined $hash_base) {
1143                 if (!is_valid_refname($hash_base)) {
1144                         die_error(400, "Invalid hash base parameter");
1145                 }
1146         }
1147
1148         our @extra_options = @{$input_params{'extra_options'}};
1149         # @extra_options is always defined, since it can only be (currently) set from
1150         # CGI, and $cgi->param() returns the empty array in array context if the param
1151         # is not set
1152         foreach my $opt (@extra_options) {
1153                 if (not exists $allowed_options{$opt}) {
1154                         die_error(400, "Invalid option parameter");
1155                 }
1156                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1157                         die_error(400, "Invalid option parameter for this action");
1158                 }
1159         }
1160
1161         our $hash_parent_base = $input_params{'hash_parent_base'};
1162         if (defined $hash_parent_base) {
1163                 if (!is_valid_refname($hash_parent_base)) {
1164                         die_error(400, "Invalid hash parent base parameter");
1165                 }
1166         }
1167
1168         # other parameters
1169         our $page = $input_params{'page'};
1170         if (defined $page) {
1171                 if ($page =~ m/[^0-9]/) {
1172                         die_error(400, "Invalid page parameter");
1173                 }
1174         }
1175
1176         our $searchtype = $input_params{'searchtype'};
1177         if (defined $searchtype) {
1178                 if ($searchtype =~ m/[^a-z]/) {
1179                         die_error(400, "Invalid searchtype parameter");
1180                 }
1181         }
1182
1183         our $search_use_regexp = $input_params{'search_use_regexp'};
1184
1185         our $searchtext = $input_params{'searchtext'};
1186         our $search_regexp = undef;
1187         if (defined $searchtext) {
1188                 if (length($searchtext) < 2) {
1189                         die_error(403, "At least two characters are required for search parameter");
1190                 }
1191                 if ($search_use_regexp) {
1192                         $search_regexp = $searchtext;
1193                         if (!eval { qr/$search_regexp/; 1; }) {
1194                                 my $error = $@ =~ s/ at \S+ line \d+.*\n?//r;
1195                                 die_error(400, "Invalid search regexp '$search_regexp'",
1196                                           esc_html($error));
1197                         }
1198                 } else {
1199                         $search_regexp = quotemeta $searchtext;
1200                 }
1201         }
1202 }
1203
1204 # path to the current git repository
1205 our $git_dir;
1206 sub evaluate_git_dir {
1207         our $git_dir = "$projectroot/$project" if $project;
1208 }
1209
1210 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1211 sub configure_gitweb_features {
1212         # list of supported snapshot formats
1213         our @snapshot_fmts = gitweb_get_feature('snapshot');
1214         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1215
1216         our ($git_avatar) = gitweb_get_feature('avatar');
1217         $git_avatar = '' unless $git_avatar =~ /^(?:gravatar|picon)$/s;
1218
1219         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1220         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1221 }
1222
1223 sub get_branch_refs {
1224         return ('heads', @extra_branch_refs);
1225 }
1226
1227 # custom error handler: 'die <message>' is Internal Server Error
1228 sub handle_errors_html {
1229         my $msg = shift; # it is already HTML escaped
1230
1231         # to avoid infinite loop where error occurs in die_error,
1232         # change handler to default handler, disabling handle_errors_html
1233         set_message("Error occurred when inside die_error:\n$msg");
1234
1235         # you cannot jump out of die_error when called as error handler;
1236         # the subroutine set via CGI::Carp::set_message is called _after_
1237         # HTTP headers are already written, so it cannot write them itself
1238         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1239 }
1240 set_message(\&handle_errors_html);
1241
1242 # dispatch
1243 sub dispatch {
1244         if (!defined $action) {
1245                 if (defined $hash) {
1246                         $action = git_get_type($hash);
1247                         $action or die_error(404, "Object does not exist");
1248                 } elsif (defined $hash_base && defined $file_name) {
1249                         $action = git_get_type("$hash_base:$file_name");
1250                         $action or die_error(404, "File or directory does not exist");
1251                 } elsif (defined $project) {
1252                         $action = 'summary';
1253                 } else {
1254                         $action = 'project_list';
1255                 }
1256         }
1257         if (!defined($actions{$action})) {
1258                 die_error(400, "Unknown action");
1259         }
1260         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1261             !$project) {
1262                 die_error(400, "Project needed");
1263         }
1264         $actions{$action}->();
1265 }
1266
1267 sub reset_timer {
1268         our $t0 = [ gettimeofday() ]
1269                 if defined $t0;
1270         our $number_of_git_cmds = 0;
1271 }
1272
1273 our $first_request = 1;
1274 sub run_request {
1275         reset_timer();
1276
1277         evaluate_uri();
1278         if ($first_request) {
1279                 evaluate_gitweb_config();
1280                 evaluate_git_version();
1281         }
1282         if ($per_request_config) {
1283                 if (ref($per_request_config) eq 'CODE') {
1284                         $per_request_config->();
1285                 } elsif (!$first_request) {
1286                         evaluate_gitweb_config();
1287                 }
1288         }
1289         check_loadavg();
1290
1291         # $projectroot and $projects_list might be set in gitweb config file
1292         $projects_list ||= $projectroot;
1293
1294         evaluate_query_params();
1295         evaluate_path_info();
1296         evaluate_and_validate_params();
1297         evaluate_git_dir();
1298
1299         configure_gitweb_features();
1300
1301         dispatch();
1302 }
1303
1304 our $is_last_request = sub { 1 };
1305 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1306 our $CGI = 'CGI';
1307 our $cgi;
1308 our $FCGI_Stream_PRINT_raw = \&FCGI::Stream::PRINT;
1309 sub configure_as_fcgi {
1310         require CGI::Fast;
1311         our $CGI = 'CGI::Fast';
1312         # FCGI is not Unicode aware hence the UTF-8 encoding must be done manually.
1313         # However no encoding must be done within git_blob_plain() and git_snapshot()
1314         # which must still output in raw binary mode.
1315         no warnings 'redefine';
1316         my $enc = Encode::find_encoding('UTF-8');
1317         *FCGI::Stream::PRINT = sub {
1318                 my @OUTPUT = @_;
1319                 for (my $i = 1; $i < @_; $i++) {
1320                         $OUTPUT[$i] = $enc->encode($_[$i], Encode::FB_CROAK|Encode::LEAVE_SRC);
1321                 }
1322                 @_ = @OUTPUT;
1323                 goto $FCGI_Stream_PRINT_raw;
1324         };
1325
1326         my $request_number = 0;
1327         # let each child service 100 requests
1328         our $is_last_request = sub { ++$request_number > 100 };
1329 }
1330 sub evaluate_argv {
1331         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1332         configure_as_fcgi()
1333                 if $script_name =~ /\.fcgi$/;
1334
1335         return unless (@ARGV);
1336
1337         require Getopt::Long;
1338         Getopt::Long::GetOptions(
1339                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1340                 'nproc|n=i' => sub {
1341                         my ($arg, $val) = @_;
1342                         return unless eval { require FCGI::ProcManager; 1; };
1343                         my $proc_manager = FCGI::ProcManager->new({
1344                                 n_processes => $val,
1345                         });
1346                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1347                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1348                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1349                 },
1350         );
1351 }
1352
1353 sub run {
1354         evaluate_argv();
1355
1356         $first_request = 1;
1357         $pre_listen_hook->()
1358                 if $pre_listen_hook;
1359
1360  REQUEST:
1361         while ($cgi = $CGI->new()) {
1362                 $pre_dispatch_hook->()
1363                         if $pre_dispatch_hook;
1364
1365                 run_request();
1366
1367                 $post_dispatch_hook->()
1368                         if $post_dispatch_hook;
1369                 $first_request = 0;
1370
1371                 last REQUEST if ($is_last_request->());
1372         }
1373
1374  DONE_GITWEB:
1375         1;
1376 }
1377
1378 run();
1379
1380 if (defined caller) {
1381         # wrapped in a subroutine processing requests,
1382         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1383         return;
1384 } else {
1385         # pure CGI script, serving single request
1386         exit;
1387 }
1388
1389 ## ======================================================================
1390 ## action links
1391
1392 # possible values of extra options
1393 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1394 # -replay => 1      - start from a current view (replay with modifications)
1395 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1396 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1397 sub href {
1398         my %params = @_;
1399         # default is to use -absolute url() i.e. $my_uri
1400         my $href = $params{-full} ? $my_url : $my_uri;
1401
1402         # implicit -replay, must be first of implicit params
1403         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1404
1405         $params{'project'} = $project unless exists $params{'project'};
1406
1407         if ($params{-replay}) {
1408                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1409                         if (!exists $params{$name}) {
1410                                 $params{$name} = $input_params{$name};
1411                         }
1412                 }
1413         }
1414
1415         my $use_pathinfo = gitweb_check_feature('pathinfo');
1416         if (defined $params{'project'} &&
1417             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1418                 # try to put as many parameters as possible in PATH_INFO:
1419                 #   - project name
1420                 #   - action
1421                 #   - hash_parent or hash_parent_base:/file_parent
1422                 #   - hash or hash_base:/filename
1423                 #   - the snapshot_format as an appropriate suffix
1424
1425                 # When the script is the root DirectoryIndex for the domain,
1426                 # $href here would be something like http://gitweb.example.com/
1427                 # Thus, we strip any trailing / from $href, to spare us double
1428                 # slashes in the final URL
1429                 $href =~ s,/$,,;
1430
1431                 # Then add the project name, if present
1432                 $href .= "/".esc_path_info($params{'project'});
1433                 delete $params{'project'};
1434
1435                 # since we destructively absorb parameters, we keep this
1436                 # boolean that remembers if we're handling a snapshot
1437                 my $is_snapshot = $params{'action'} eq 'snapshot';
1438
1439                 # Summary just uses the project path URL, any other action is
1440                 # added to the URL
1441                 if (defined $params{'action'}) {
1442                         $href .= "/".esc_path_info($params{'action'})
1443                                 unless $params{'action'} eq 'summary';
1444                         delete $params{'action'};
1445                 }
1446
1447                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1448                 # stripping nonexistent or useless pieces
1449                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1450                         || $params{'hash_parent'} || $params{'hash'});
1451                 if (defined $params{'hash_base'}) {
1452                         if (defined $params{'hash_parent_base'}) {
1453                                 $href .= esc_path_info($params{'hash_parent_base'});
1454                                 # skip the file_parent if it's the same as the file_name
1455                                 if (defined $params{'file_parent'}) {
1456                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1457                                                 delete $params{'file_parent'};
1458                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1459                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1460                                                 delete $params{'file_parent'};
1461                                         }
1462                                 }
1463                                 $href .= "..";
1464                                 delete $params{'hash_parent'};
1465                                 delete $params{'hash_parent_base'};
1466                         } elsif (defined $params{'hash_parent'}) {
1467                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1468                                 delete $params{'hash_parent'};
1469                         }
1470
1471                         $href .= esc_path_info($params{'hash_base'});
1472                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1473                                 $href .= ":/".esc_path_info($params{'file_name'});
1474                                 delete $params{'file_name'};
1475                         }
1476                         delete $params{'hash'};
1477                         delete $params{'hash_base'};
1478                 } elsif (defined $params{'hash'}) {
1479                         $href .= esc_path_info($params{'hash'});
1480                         delete $params{'hash'};
1481                 }
1482
1483                 # If the action was a snapshot, we can absorb the
1484                 # snapshot_format parameter too
1485                 if ($is_snapshot) {
1486                         my $fmt = $params{'snapshot_format'};
1487                         # snapshot_format should always be defined when href()
1488                         # is called, but just in case some code forgets, we
1489                         # fall back to the default
1490                         $fmt ||= $snapshot_fmts[0];
1491                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1492                         delete $params{'snapshot_format'};
1493                 }
1494         }
1495
1496         # now encode the parameters explicitly
1497         my @result = ();
1498         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1499                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1500                 if (defined $params{$name}) {
1501                         if (ref($params{$name}) eq "ARRAY") {
1502                                 foreach my $par (@{$params{$name}}) {
1503                                         push @result, $symbol . "=" . esc_param($par);
1504                                 }
1505                         } else {
1506                                 push @result, $symbol . "=" . esc_param($params{$name});
1507                         }
1508                 }
1509         }
1510         $href .= "?" . join(';', @result) if scalar @result;
1511
1512         # final transformation: trailing spaces must be escaped (URI-encoded)
1513         $href =~ s/(\s+)$/CGI::escape($1)/e;
1514
1515         if ($params{-anchor}) {
1516                 $href .= "#".esc_param($params{-anchor});
1517         }
1518
1519         return $href;
1520 }
1521
1522
1523 ## ======================================================================
1524 ## validation, quoting/unquoting and escaping
1525
1526 sub is_valid_action {
1527         my $input = shift;
1528         return undef unless exists $actions{$input};
1529         return 1;
1530 }
1531
1532 sub is_valid_project {
1533         my $input = shift;
1534
1535         return unless defined $input;
1536         if (!is_valid_pathname($input) ||
1537                 !(-d "$projectroot/$input") ||
1538                 !check_export_ok("$projectroot/$input") ||
1539                 ($strict_export && !project_in_list($input))) {
1540                 return undef;
1541         } else {
1542                 return 1;
1543         }
1544 }
1545
1546 sub is_valid_pathname {
1547         my $input = shift;
1548
1549         return undef unless defined $input;
1550         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1551         # at the beginning, at the end, and between slashes.
1552         # also this catches doubled slashes
1553         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1554                 return undef;
1555         }
1556         # no null characters
1557         if ($input =~ m!\0!) {
1558                 return undef;
1559         }
1560         return 1;
1561 }
1562
1563 sub is_valid_ref_format {
1564         my $input = shift;
1565
1566         return undef unless defined $input;
1567         # restrictions on ref name according to git-check-ref-format
1568         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1569                 return undef;
1570         }
1571         return 1;
1572 }
1573
1574 sub is_valid_refname {
1575         my $input = shift;
1576
1577         return undef unless defined $input;
1578         # textual hashes are O.K.
1579         if ($input =~ m/^$oid_regex$/) {
1580                 return 1;
1581         }
1582         # it must be correct pathname
1583         is_valid_pathname($input) or return undef;
1584         # check git-check-ref-format restrictions
1585         is_valid_ref_format($input) or return undef;
1586         return 1;
1587 }
1588
1589 # decode sequences of octets in utf8 into Perl's internal form,
1590 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1591 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1592 sub to_utf8 {
1593         my $str = shift;
1594         return undef unless defined $str;
1595
1596         if (utf8::is_utf8($str) || utf8::decode($str)) {
1597                 return $str;
1598         } else {
1599                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1600         }
1601 }
1602
1603 # quote unsafe chars, but keep the slash, even when it's not
1604 # correct, but quoted slashes look too horrible in bookmarks
1605 sub esc_param {
1606         my $str = shift;
1607         return undef unless defined $str;
1608         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1609         $str =~ s/ /\+/g;
1610         return $str;
1611 }
1612
1613 # the quoting rules for path_info fragment are slightly different
1614 sub esc_path_info {
1615         my $str = shift;
1616         return undef unless defined $str;
1617
1618         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1619         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1620
1621         return $str;
1622 }
1623
1624 # quote unsafe chars in whole URL, so some characters cannot be quoted
1625 sub esc_url {
1626         my $str = shift;
1627         return undef unless defined $str;
1628         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1629         $str =~ s/ /\+/g;
1630         return $str;
1631 }
1632
1633 # quote unsafe characters in HTML attributes
1634 sub esc_attr {
1635
1636         # for XHTML conformance escaping '"' to '&quot;' is not enough
1637         return esc_html(@_);
1638 }
1639
1640 # replace invalid utf8 character with SUBSTITUTION sequence
1641 sub esc_html {
1642         my $str = shift;
1643         my %opts = @_;
1644
1645         return undef unless defined $str;
1646
1647         $str = to_utf8($str);
1648         $str = $cgi->escapeHTML($str);
1649         if ($opts{'-nbsp'}) {
1650                 $str =~ s/ /&nbsp;/g;
1651         }
1652         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1653         return $str;
1654 }
1655
1656 # quote control characters and escape filename to HTML
1657 sub esc_path {
1658         my $str = shift;
1659         my %opts = @_;
1660
1661         return undef unless defined $str;
1662
1663         $str = to_utf8($str);
1664         $str = $cgi->escapeHTML($str);
1665         if ($opts{'-nbsp'}) {
1666                 $str =~ s/ /&nbsp;/g;
1667         }
1668         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1669         return $str;
1670 }
1671
1672 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1673 sub sanitize {
1674         my $str = shift;
1675
1676         return undef unless defined $str;
1677
1678         $str = to_utf8($str);
1679         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1680         return $str;
1681 }
1682
1683 # Make control characters "printable", using character escape codes (CEC)
1684 sub quot_cec {
1685         my $cntrl = shift;
1686         my %opts = @_;
1687         my %es = ( # character escape codes, aka escape sequences
1688                 "\t" => '\t',   # tab             (HT)
1689                 "\n" => '\n',   # line feed       (LF)
1690                 "\r" => '\r',   # carriage return (CR)
1691                 "\f" => '\f',   # form feed       (FF)
1692                 "\b" => '\b',   # backspace       (BS)
1693                 "\a" => '\a',   # alarm (bell)    (BEL)
1694                 "\e" => '\e',   # escape          (ESC)
1695                 "\013" => '\v', # vertical tab    (VT)
1696                 "\000" => '\0', # nul character   (NUL)
1697         );
1698         my $chr = ( (exists $es{$cntrl})
1699                     ? $es{$cntrl}
1700                     : sprintf('\%2x', ord($cntrl)) );
1701         if ($opts{-nohtml}) {
1702                 return $chr;
1703         } else {
1704                 return "<span class=\"cntrl\">$chr</span>";
1705         }
1706 }
1707
1708 # Alternatively use unicode control pictures codepoints,
1709 # Unicode "printable representation" (PR)
1710 sub quot_upr {
1711         my $cntrl = shift;
1712         my %opts = @_;
1713
1714         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1715         if ($opts{-nohtml}) {
1716                 return $chr;
1717         } else {
1718                 return "<span class=\"cntrl\">$chr</span>";
1719         }
1720 }
1721
1722 # git may return quoted and escaped filenames
1723 sub unquote {
1724         my $str = shift;
1725
1726         sub unq {
1727                 my $seq = shift;
1728                 my %es = ( # character escape codes, aka escape sequences
1729                         't' => "\t",   # tab            (HT, TAB)
1730                         'n' => "\n",   # newline        (NL)
1731                         'r' => "\r",   # return         (CR)
1732                         'f' => "\f",   # form feed      (FF)
1733                         'b' => "\b",   # backspace      (BS)
1734                         'a' => "\a",   # alarm (bell)   (BEL)
1735                         'e' => "\e",   # escape         (ESC)
1736                         'v' => "\013", # vertical tab   (VT)
1737                 );
1738
1739                 if ($seq =~ m/^[0-7]{1,3}$/) {
1740                         # octal char sequence
1741                         return chr(oct($seq));
1742                 } elsif (exists $es{$seq}) {
1743                         # C escape sequence, aka character escape code
1744                         return $es{$seq};
1745                 }
1746                 # quoted ordinary character
1747                 return $seq;
1748         }
1749
1750         if ($str =~ m/^"(.*)"$/) {
1751                 # needs unquoting
1752                 $str = $1;
1753                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1754         }
1755         return $str;
1756 }
1757
1758 # escape tabs (convert tabs to spaces)
1759 sub untabify {
1760         my $line = shift;
1761
1762         while ((my $pos = index($line, "\t")) != -1) {
1763                 if (my $count = (8 - ($pos % 8))) {
1764                         my $spaces = ' ' x $count;
1765                         $line =~ s/\t/$spaces/;
1766                 }
1767         }
1768
1769         return $line;
1770 }
1771
1772 sub project_in_list {
1773         my $project = shift;
1774         my @list = git_get_projects_list();
1775         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1776 }
1777
1778 ## ----------------------------------------------------------------------
1779 ## HTML aware string manipulation
1780
1781 # Try to chop given string on a word boundary between position
1782 # $len and $len+$add_len. If there is no word boundary there,
1783 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1784 # (marking chopped part) would be longer than given string.
1785 sub chop_str {
1786         my $str = shift;
1787         my $len = shift;
1788         my $add_len = shift || 10;
1789         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1790
1791         # Make sure perl knows it is utf8 encoded so we don't
1792         # cut in the middle of a utf8 multibyte char.
1793         $str = to_utf8($str);
1794
1795         # allow only $len chars, but don't cut a word if it would fit in $add_len
1796         # if it doesn't fit, cut it if it's still longer than the dots we would add
1797         # remove chopped character entities entirely
1798
1799         # when chopping in the middle, distribute $len into left and right part
1800         # return early if chopping wouldn't make string shorter
1801         if ($where eq 'center') {
1802                 return $str if ($len + 5 >= length($str)); # filler is length 5
1803                 $len = int($len/2);
1804         } else {
1805                 return $str if ($len + 4 >= length($str)); # filler is length 4
1806         }
1807
1808         # regexps: ending and beginning with word part up to $add_len
1809         my $endre = qr/.{$len}\w{0,$add_len}/;
1810         my $begre = qr/\w{0,$add_len}.{$len}/;
1811
1812         if ($where eq 'left') {
1813                 $str =~ m/^(.*?)($begre)$/;
1814                 my ($lead, $body) = ($1, $2);
1815                 if (length($lead) > 4) {
1816                         $lead = " ...";
1817                 }
1818                 return "$lead$body";
1819
1820         } elsif ($where eq 'center') {
1821                 $str =~ m/^($endre)(.*)$/;
1822                 my ($left, $str)  = ($1, $2);
1823                 $str =~ m/^(.*?)($begre)$/;
1824                 my ($mid, $right) = ($1, $2);
1825                 if (length($mid) > 5) {
1826                         $mid = " ... ";
1827                 }
1828                 return "$left$mid$right";
1829
1830         } else {
1831                 $str =~ m/^($endre)(.*)$/;
1832                 my $body = $1;
1833                 my $tail = $2;
1834                 if (length($tail) > 4) {
1835                         $tail = "... ";
1836                 }
1837                 return "$body$tail";
1838         }
1839 }
1840
1841 # takes the same arguments as chop_str, but also wraps a <span> around the
1842 # result with a title attribute if it does get chopped. Additionally, the
1843 # string is HTML-escaped.
1844 sub chop_and_escape_str {
1845         my ($str) = @_;
1846
1847         my $chopped = chop_str(@_);
1848         $str = to_utf8($str);
1849         if ($chopped eq $str) {
1850                 return esc_html($chopped);
1851         } else {
1852                 $str =~ s/[[:cntrl:]]/?/g;
1853                 return $cgi->span({-title=>$str}, esc_html($chopped));
1854         }
1855 }
1856
1857 # Highlight selected fragments of string, using given CSS class,
1858 # and escape HTML.  It is assumed that fragments do not overlap.
1859 # Regions are passed as list of pairs (array references).
1860 #
1861 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1862 # '<span class="mark">foo</span>bar'
1863 sub esc_html_hl_regions {
1864         my ($str, $css_class, @sel) = @_;
1865         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1866         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1867         return esc_html($str, %opts) unless @sel;
1868
1869         my $out = '';
1870         my $pos = 0;
1871
1872         for my $s (@sel) {
1873                 my ($begin, $end) = @$s;
1874
1875                 # Don't create empty <span> elements.
1876                 next if $end <= $begin;
1877
1878                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1879                                        %opts);
1880
1881                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1882                         if ($begin - $pos > 0);
1883                 $out .= $cgi->span({-class => $css_class}, $escaped);
1884
1885                 $pos = $end;
1886         }
1887         $out .= esc_html(substr($str, $pos), %opts)
1888                 if ($pos < length($str));
1889
1890         return $out;
1891 }
1892
1893 # return positions of beginning and end of each match
1894 sub matchpos_list {
1895         my ($str, $regexp) = @_;
1896         return unless (defined $str && defined $regexp);
1897
1898         my @matches;
1899         while ($str =~ /$regexp/g) {
1900                 push @matches, [$-[0], $+[0]];
1901         }
1902         return @matches;
1903 }
1904
1905 # highlight match (if any), and escape HTML
1906 sub esc_html_match_hl {
1907         my ($str, $regexp) = @_;
1908         return esc_html($str) unless defined $regexp;
1909
1910         my @matches = matchpos_list($str, $regexp);
1911         return esc_html($str) unless @matches;
1912
1913         return esc_html_hl_regions($str, 'match', @matches);
1914 }
1915
1916
1917 # highlight match (if any) of shortened string, and escape HTML
1918 sub esc_html_match_hl_chopped {
1919         my ($str, $chopped, $regexp) = @_;
1920         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1921
1922         my @matches = matchpos_list($str, $regexp);
1923         return esc_html($chopped) unless @matches;
1924
1925         # filter matches so that we mark chopped string
1926         my $tail = "... "; # see chop_str
1927         unless ($chopped =~ s/\Q$tail\E$//) {
1928                 $tail = '';
1929         }
1930         my $chop_len = length($chopped);
1931         my $tail_len = length($tail);
1932         my @filtered;
1933
1934         for my $m (@matches) {
1935                 if ($m->[0] > $chop_len) {
1936                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1937                         last;
1938                 } elsif ($m->[1] > $chop_len) {
1939                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1940                         last;
1941                 }
1942                 push @filtered, $m;
1943         }
1944
1945         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1946 }
1947
1948 ## ----------------------------------------------------------------------
1949 ## functions returning short strings
1950
1951 # CSS class for given age value (in seconds)
1952 sub age_class {
1953         my $age = shift;
1954
1955         if (!defined $age) {
1956                 return "noage";
1957         } elsif ($age < 60*60*2) {
1958                 return "age0";
1959         } elsif ($age < 60*60*24*2) {
1960                 return "age1";
1961         } else {
1962                 return "age2";
1963         }
1964 }
1965
1966 # convert age in seconds to "nn units ago" string
1967 sub age_string {
1968         my $age = shift;
1969         my $age_str;
1970
1971         if ($age > 60*60*24*365*2) {
1972                 $age_str = (int $age/60/60/24/365);
1973                 $age_str .= " years ago";
1974         } elsif ($age > 60*60*24*(365/12)*2) {
1975                 $age_str = int $age/60/60/24/(365/12);
1976                 $age_str .= " months ago";
1977         } elsif ($age > 60*60*24*7*2) {
1978                 $age_str = int $age/60/60/24/7;
1979                 $age_str .= " weeks ago";
1980         } elsif ($age > 60*60*24*2) {
1981                 $age_str = int $age/60/60/24;
1982                 $age_str .= " days ago";
1983         } elsif ($age > 60*60*2) {
1984                 $age_str = int $age/60/60;
1985                 $age_str .= " hours ago";
1986         } elsif ($age > 60*2) {
1987                 $age_str = int $age/60;
1988                 $age_str .= " min ago";
1989         } elsif ($age > 2) {
1990                 $age_str = int $age;
1991                 $age_str .= " sec ago";
1992         } else {
1993                 $age_str .= " right now";
1994         }
1995         return $age_str;
1996 }
1997
1998 use constant {
1999         S_IFINVALID => 0030000,
2000         S_IFGITLINK => 0160000,
2001 };
2002
2003 # submodule/subproject, a commit object reference
2004 sub S_ISGITLINK {
2005         my $mode = shift;
2006
2007         return (($mode & S_IFMT) == S_IFGITLINK)
2008 }
2009
2010 # convert file mode in octal to symbolic file mode string
2011 sub mode_str {
2012         my $mode = oct shift;
2013
2014         if (S_ISGITLINK($mode)) {
2015                 return 'm---------';
2016         } elsif (S_ISDIR($mode & S_IFMT)) {
2017                 return 'drwxr-xr-x';
2018         } elsif (S_ISLNK($mode)) {
2019                 return 'lrwxrwxrwx';
2020         } elsif (S_ISREG($mode)) {
2021                 # git cares only about the executable bit
2022                 if ($mode & S_IXUSR) {
2023                         return '-rwxr-xr-x';
2024                 } else {
2025                         return '-rw-r--r--';
2026                 };
2027         } else {
2028                 return '----------';
2029         }
2030 }
2031
2032 # convert file mode in octal to file type string
2033 sub file_type {
2034         my $mode = shift;
2035
2036         if ($mode !~ m/^[0-7]+$/) {
2037                 return $mode;
2038         } else {
2039                 $mode = oct $mode;
2040         }
2041
2042         if (S_ISGITLINK($mode)) {
2043                 return "submodule";
2044         } elsif (S_ISDIR($mode & S_IFMT)) {
2045                 return "directory";
2046         } elsif (S_ISLNK($mode)) {
2047                 return "symlink";
2048         } elsif (S_ISREG($mode)) {
2049                 return "file";
2050         } else {
2051                 return "unknown";
2052         }
2053 }
2054
2055 # convert file mode in octal to file type description string
2056 sub file_type_long {
2057         my $mode = shift;
2058
2059         if ($mode !~ m/^[0-7]+$/) {
2060                 return $mode;
2061         } else {
2062                 $mode = oct $mode;
2063         }
2064
2065         if (S_ISGITLINK($mode)) {
2066                 return "submodule";
2067         } elsif (S_ISDIR($mode & S_IFMT)) {
2068                 return "directory";
2069         } elsif (S_ISLNK($mode)) {
2070                 return "symlink";
2071         } elsif (S_ISREG($mode)) {
2072                 if ($mode & S_IXUSR) {
2073                         return "executable";
2074                 } else {
2075                         return "file";
2076                 };
2077         } else {
2078                 return "unknown";
2079         }
2080 }
2081
2082
2083 ## ----------------------------------------------------------------------
2084 ## functions returning short HTML fragments, or transforming HTML fragments
2085 ## which don't belong to other sections
2086
2087 # format line of commit message.
2088 sub format_log_line_html {
2089         my $line = shift;
2090
2091         # Potentially abbreviated OID.
2092         my $regex = oid_nlen_regex("7,64");
2093
2094         $line = esc_html($line, -nbsp=>1);
2095         $line =~ s{
2096         \b
2097         (
2098             # The output of "git describe", e.g. v2.10.0-297-gf6727b0
2099             # or hadoop-20160921-113441-20-g094fb7d
2100             (?<!-) # see check_tag_ref(). Tags can't start with -
2101             [A-Za-z0-9.-]+
2102             (?!\.) # refs can't end with ".", see check_refname_format()
2103             -g$regex
2104             |
2105             # Just a normal looking Git SHA1
2106             $regex
2107         )
2108         \b
2109     }{
2110                 $cgi->a({-href => href(action=>"object", hash=>$1),
2111                                         -class => "text"}, $1);
2112         }egx;
2113
2114         return $line;
2115 }
2116
2117 # format marker of refs pointing to given object
2118
2119 # the destination action is chosen based on object type and current context:
2120 # - for annotated tags, we choose the tag view unless it's the current view
2121 #   already, in which case we go to shortlog view
2122 # - for other refs, we keep the current view if we're in history, shortlog or
2123 #   log view, and select shortlog otherwise
2124 sub format_ref_marker {
2125         my ($refs, $id) = @_;
2126         my $markers = '';
2127
2128         if (defined $refs->{$id}) {
2129                 foreach my $ref (@{$refs->{$id}}) {
2130                         # this code exploits the fact that non-lightweight tags are the
2131                         # only indirect objects, and that they are the only objects for which
2132                         # we want to use tag instead of shortlog as action
2133                         my ($type, $name) = qw();
2134                         my $indirect = ($ref =~ s/\^\{\}$//);
2135                         # e.g. tags/v2.6.11 or heads/next
2136                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2137                                 $type = $1;
2138                                 $name = $2;
2139                         } else {
2140                                 $type = "ref";
2141                                 $name = $ref;
2142                         }
2143
2144                         my $class = $type;
2145                         $class .= " indirect" if $indirect;
2146
2147                         my $dest_action = "shortlog";
2148
2149                         if ($indirect) {
2150                                 $dest_action = "tag" unless $action eq "tag";
2151                         } elsif ($action =~ /^(history|(short)?log)$/) {
2152                                 $dest_action = $action;
2153                         }
2154
2155                         my $dest = "";
2156                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2157                         $dest .= $ref;
2158
2159                         my $link = $cgi->a({
2160                                 -href => href(
2161                                         action=>$dest_action,
2162                                         hash=>$dest
2163                                 )}, esc_html($name));
2164
2165                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2166                                 $link . "</span>";
2167                 }
2168         }
2169
2170         if ($markers) {
2171                 return ' <span class="refs">'. $markers . '</span>';
2172         } else {
2173                 return "";
2174         }
2175 }
2176
2177 # format, perhaps shortened and with markers, title line
2178 sub format_subject_html {
2179         my ($long, $short, $href, $extra) = @_;
2180         $extra = '' unless defined($extra);
2181
2182         if (length($short) < length($long)) {
2183                 $long =~ s/[[:cntrl:]]/?/g;
2184                 return $cgi->a({-href => $href, -class => "list subject",
2185                                 -title => to_utf8($long)},
2186                        esc_html($short)) . $extra;
2187         } else {
2188                 return $cgi->a({-href => $href, -class => "list subject"},
2189                        esc_html($long)) . $extra;
2190         }
2191 }
2192
2193 # Rather than recomputing the url for an email multiple times, we cache it
2194 # after the first hit. This gives a visible benefit in views where the avatar
2195 # for the same email is used repeatedly (e.g. shortlog).
2196 # The cache is shared by all avatar engines (currently gravatar only), which
2197 # are free to use it as preferred. Since only one avatar engine is used for any
2198 # given page, there's no risk for cache conflicts.
2199 our %avatar_cache = ();
2200
2201 # Compute the picon url for a given email, by using the picon search service over at
2202 # http://www.cs.indiana.edu/picons/search.html
2203 sub picon_url {
2204         my $email = lc shift;
2205         if (!$avatar_cache{$email}) {
2206                 my ($user, $domain) = split('@', $email);
2207                 $avatar_cache{$email} =
2208                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2209                         "$domain/$user/" .
2210                         "users+domains+unknown/up/single";
2211         }
2212         return $avatar_cache{$email};
2213 }
2214
2215 # Compute the gravatar url for a given email, if it's not in the cache already.
2216 # Gravatar stores only the part of the URL before the size, since that's the
2217 # one computationally more expensive. This also allows reuse of the cache for
2218 # different sizes (for this particular engine).
2219 sub gravatar_url {
2220         my $email = lc shift;
2221         my $size = shift;
2222         $avatar_cache{$email} ||=
2223                 "//www.gravatar.com/avatar/" .
2224                         md5_hex($email) . "?s=";
2225         return $avatar_cache{$email} . $size;
2226 }
2227
2228 # Insert an avatar for the given $email at the given $size if the feature
2229 # is enabled.
2230 sub git_get_avatar {
2231         my ($email, %opts) = @_;
2232         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2233         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2234         $opts{-size} ||= 'default';
2235         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2236         my $url = "";
2237         if ($git_avatar eq 'gravatar') {
2238                 $url = gravatar_url($email, $size);
2239         } elsif ($git_avatar eq 'picon') {
2240                 $url = picon_url($email);
2241         }
2242         # Other providers can be added by extending the if chain, defining $url
2243         # as needed. If no variant puts something in $url, we assume avatars
2244         # are completely disabled/unavailable.
2245         if ($url) {
2246                 return $pre_white .
2247                        "<img width=\"$size\" " .
2248                             "class=\"avatar\" " .
2249                             "src=\"".esc_url($url)."\" " .
2250                             "alt=\"\" " .
2251                        "/>" . $post_white;
2252         } else {
2253                 return "";
2254         }
2255 }
2256
2257 sub format_search_author {
2258         my ($author, $searchtype, $displaytext) = @_;
2259         my $have_search = gitweb_check_feature('search');
2260
2261         if ($have_search) {
2262                 my $performed = "";
2263                 if ($searchtype eq 'author') {
2264                         $performed = "authored";
2265                 } elsif ($searchtype eq 'committer') {
2266                         $performed = "committed";
2267                 }
2268
2269                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2270                                 searchtext=>$author,
2271                                 searchtype=>$searchtype), class=>"list",
2272                                 title=>"Search for commits $performed by $author"},
2273                                 $displaytext);
2274
2275         } else {
2276                 return $displaytext;
2277         }
2278 }
2279
2280 # format the author name of the given commit with the given tag
2281 # the author name is chopped and escaped according to the other
2282 # optional parameters (see chop_str).
2283 sub format_author_html {
2284         my $tag = shift;
2285         my $co = shift;
2286         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2287         return "<$tag class=\"author\">" .
2288                format_search_author($co->{'author_name'}, "author",
2289                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2290                        $author) .
2291                "</$tag>";
2292 }
2293
2294 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2295 sub format_git_diff_header_line {
2296         my $line = shift;
2297         my $diffinfo = shift;
2298         my ($from, $to) = @_;
2299
2300         if ($diffinfo->{'nparents'}) {
2301                 # combined diff
2302                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2303                 if ($to->{'href'}) {
2304                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2305                                          esc_path($to->{'file'}));
2306                 } else { # file was deleted (no href)
2307                         $line .= esc_path($to->{'file'});
2308                 }
2309         } else {
2310                 # "ordinary" diff
2311                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2312                 if ($from->{'href'}) {
2313                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2314                                          'a/' . esc_path($from->{'file'}));
2315                 } else { # file was added (no href)
2316                         $line .= 'a/' . esc_path($from->{'file'});
2317                 }
2318                 $line .= ' ';
2319                 if ($to->{'href'}) {
2320                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2321                                          'b/' . esc_path($to->{'file'}));
2322                 } else { # file was deleted
2323                         $line .= 'b/' . esc_path($to->{'file'});
2324                 }
2325         }
2326
2327         return "<div class=\"diff header\">$line</div>\n";
2328 }
2329
2330 # format extended diff header line, before patch itself
2331 sub format_extended_diff_header_line {
2332         my $line = shift;
2333         my $diffinfo = shift;
2334         my ($from, $to) = @_;
2335
2336         # match <path>
2337         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2338                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2339                                        esc_path($from->{'file'}));
2340         }
2341         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2342                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2343                                  esc_path($to->{'file'}));
2344         }
2345         # match single <mode>
2346         if ($line =~ m/\s(\d{6})$/) {
2347                 $line .= '<span class="info"> (' .
2348                          file_type_long($1) .
2349                          ')</span>';
2350         }
2351         # match <hash>
2352         if ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", ",") |
2353             $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", ",")) {
2354                 # can match only for combined diff
2355                 $line = 'index ';
2356                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2357                         if ($from->{'href'}[$i]) {
2358                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2359                                                   -class=>"hash"},
2360                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2361                         } else {
2362                                 $line .= '0' x 7;
2363                         }
2364                         # separator
2365                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2366                 }
2367                 $line .= '..';
2368                 if ($to->{'href'}) {
2369                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2370                                          substr($diffinfo->{'to_id'},0,7));
2371                 } else {
2372                         $line .= '0' x 7;
2373                 }
2374
2375         } elsif ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", "..") |
2376                  $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", "..")) {
2377                 # can match only for ordinary diff
2378                 my ($from_link, $to_link);
2379                 if ($from->{'href'}) {
2380                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2381                                              substr($diffinfo->{'from_id'},0,7));
2382                 } else {
2383                         $from_link = '0' x 7;
2384                 }
2385                 if ($to->{'href'}) {
2386                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2387                                            substr($diffinfo->{'to_id'},0,7));
2388                 } else {
2389                         $to_link = '0' x 7;
2390                 }
2391                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2392                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2393         }
2394
2395         return $line . "<br/>\n";
2396 }
2397
2398 # format from-file/to-file diff header
2399 sub format_diff_from_to_header {
2400         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2401         my $line;
2402         my $result = '';
2403
2404         $line = $from_line;
2405         #assert($line =~ m/^---/) if DEBUG;
2406         # no extra formatting for "^--- /dev/null"
2407         if (! $diffinfo->{'nparents'}) {
2408                 # ordinary (single parent) diff
2409                 if ($line =~ m!^--- "?a/!) {
2410                         if ($from->{'href'}) {
2411                                 $line = '--- a/' .
2412                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2413                                                 esc_path($from->{'file'}));
2414                         } else {
2415                                 $line = '--- a/' .
2416                                         esc_path($from->{'file'});
2417                         }
2418                 }
2419                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2420
2421         } else {
2422                 # combined diff (merge commit)
2423                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2424                         if ($from->{'href'}[$i]) {
2425                                 $line = '--- ' .
2426                                         $cgi->a({-href=>href(action=>"blobdiff",
2427                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2428                                                              hash_parent_base=>$parents[$i],
2429                                                              file_parent=>$from->{'file'}[$i],
2430                                                              hash=>$diffinfo->{'to_id'},
2431                                                              hash_base=>$hash,
2432                                                              file_name=>$to->{'file'}),
2433                                                  -class=>"path",
2434                                                  -title=>"diff" . ($i+1)},
2435                                                 $i+1) .
2436                                         '/' .
2437                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2438                                                 esc_path($from->{'file'}[$i]));
2439                         } else {
2440                                 $line = '--- /dev/null';
2441                         }
2442                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2443                 }
2444         }
2445
2446         $line = $to_line;
2447         #assert($line =~ m/^\+\+\+/) if DEBUG;
2448         # no extra formatting for "^+++ /dev/null"
2449         if ($line =~ m!^\+\+\+ "?b/!) {
2450                 if ($to->{'href'}) {
2451                         $line = '+++ b/' .
2452                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2453                                         esc_path($to->{'file'}));
2454                 } else {
2455                         $line = '+++ b/' .
2456                                 esc_path($to->{'file'});
2457                 }
2458         }
2459         $result .= qq!<div class="diff to_file">$line</div>\n!;
2460
2461         return $result;
2462 }
2463
2464 # create note for patch simplified by combined diff
2465 sub format_diff_cc_simplified {
2466         my ($diffinfo, @parents) = @_;
2467         my $result = '';
2468
2469         $result .= "<div class=\"diff header\">" .
2470                    "diff --cc ";
2471         if (!is_deleted($diffinfo)) {
2472                 $result .= $cgi->a({-href => href(action=>"blob",
2473                                                   hash_base=>$hash,
2474                                                   hash=>$diffinfo->{'to_id'},
2475                                                   file_name=>$diffinfo->{'to_file'}),
2476                                     -class => "path"},
2477                                    esc_path($diffinfo->{'to_file'}));
2478         } else {
2479                 $result .= esc_path($diffinfo->{'to_file'});
2480         }
2481         $result .= "</div>\n" . # class="diff header"
2482                    "<div class=\"diff nodifferences\">" .
2483                    "Simple merge" .
2484                    "</div>\n"; # class="diff nodifferences"
2485
2486         return $result;
2487 }
2488
2489 sub diff_line_class {
2490         my ($line, $from, $to) = @_;
2491
2492         # ordinary diff
2493         my $num_sign = 1;
2494         # combined diff
2495         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2496                 $num_sign = scalar @{$from->{'href'}};
2497         }
2498
2499         my @diff_line_classifier = (
2500                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2501                 { regexp => qr/^\\/,               class => "incomplete"  },
2502                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2503                 # classifier for context must come before classifier add/rem,
2504                 # or we would have to use more complicated regexp, for example
2505                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2506                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2507                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2508         );
2509         for my $clsfy (@diff_line_classifier) {
2510                 return $clsfy->{'class'}
2511                         if ($line =~ $clsfy->{'regexp'});
2512         }
2513
2514         # fallback
2515         return "";
2516 }
2517
2518 # assumes that $from and $to are defined and correctly filled,
2519 # and that $line holds a line of chunk header for unified diff
2520 sub format_unidiff_chunk_header {
2521         my ($line, $from, $to) = @_;
2522
2523         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2524                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2525
2526         $from_lines = 0 unless defined $from_lines;
2527         $to_lines   = 0 unless defined $to_lines;
2528
2529         if ($from->{'href'}) {
2530                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2531                                      -class=>"list"}, $from_text);
2532         }
2533         if ($to->{'href'}) {
2534                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2535                                      -class=>"list"}, $to_text);
2536         }
2537         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2538                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2539         return $line;
2540 }
2541
2542 # assumes that $from and $to are defined and correctly filled,
2543 # and that $line holds a line of chunk header for combined diff
2544 sub format_cc_diff_chunk_header {
2545         my ($line, $from, $to) = @_;
2546
2547         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2548         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2549
2550         @from_text = split(' ', $ranges);
2551         for (my $i = 0; $i < @from_text; ++$i) {
2552                 ($from_start[$i], $from_nlines[$i]) =
2553                         (split(',', substr($from_text[$i], 1)), 0);
2554         }
2555
2556         $to_text   = pop @from_text;
2557         $to_start  = pop @from_start;
2558         $to_nlines = pop @from_nlines;
2559
2560         $line = "<span class=\"chunk_info\">$prefix ";
2561         for (my $i = 0; $i < @from_text; ++$i) {
2562                 if ($from->{'href'}[$i]) {
2563                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2564                                           -class=>"list"}, $from_text[$i]);
2565                 } else {
2566                         $line .= $from_text[$i];
2567                 }
2568                 $line .= " ";
2569         }
2570         if ($to->{'href'}) {
2571                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2572                                   -class=>"list"}, $to_text);
2573         } else {
2574                 $line .= $to_text;
2575         }
2576         $line .= " $prefix</span>" .
2577                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2578         return $line;
2579 }
2580
2581 # process patch (diff) line (not to be used for diff headers),
2582 # returning HTML-formatted (but not wrapped) line.
2583 # If the line is passed as a reference, it is treated as HTML and not
2584 # esc_html()'ed.
2585 sub format_diff_line {
2586         my ($line, $diff_class, $from, $to) = @_;
2587
2588         if (ref($line)) {
2589                 $line = $$line;
2590         } else {
2591                 chomp $line;
2592                 $line = untabify($line);
2593
2594                 if ($from && $to && $line =~ m/^\@{2} /) {
2595                         $line = format_unidiff_chunk_header($line, $from, $to);
2596                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2597                         $line = format_cc_diff_chunk_header($line, $from, $to);
2598                 } else {
2599                         $line = esc_html($line, -nbsp=>1);
2600                 }
2601         }
2602
2603         my $diff_classes = "diff";
2604         $diff_classes .= " $diff_class" if ($diff_class);
2605         $line = "<div class=\"$diff_classes\">$line</div>\n";
2606
2607         return $line;
2608 }
2609
2610 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2611 # linked.  Pass the hash of the tree/commit to snapshot.
2612 sub format_snapshot_links {
2613         my ($hash) = @_;
2614         my $num_fmts = @snapshot_fmts;
2615         if ($num_fmts > 1) {
2616                 # A parenthesized list of links bearing format names.
2617                 # e.g. "snapshot (_tar.gz_ _zip_)"
2618                 return "snapshot (" . join(' ', map
2619                         $cgi->a({
2620                                 -href => href(
2621                                         action=>"snapshot",
2622                                         hash=>$hash,
2623                                         snapshot_format=>$_
2624                                 )
2625                         }, $known_snapshot_formats{$_}{'display'})
2626                 , @snapshot_fmts) . ")";
2627         } elsif ($num_fmts == 1) {
2628                 # A single "snapshot" link whose tooltip bears the format name.
2629                 # i.e. "_snapshot_"
2630                 my ($fmt) = @snapshot_fmts;
2631                 return
2632                         $cgi->a({
2633                                 -href => href(
2634                                         action=>"snapshot",
2635                                         hash=>$hash,
2636                                         snapshot_format=>$fmt
2637                                 ),
2638                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2639                         }, "snapshot");
2640         } else { # $num_fmts == 0
2641                 return undef;
2642         }
2643 }
2644
2645 ## ......................................................................
2646 ## functions returning values to be passed, perhaps after some
2647 ## transformation, to other functions; e.g. returning arguments to href()
2648
2649 # returns hash to be passed to href to generate gitweb URL
2650 # in -title key it returns description of link
2651 sub get_feed_info {
2652         my $format = shift || 'Atom';
2653         my %res = (action => lc($format));
2654         my $matched_ref = 0;
2655
2656         # feed links are possible only for project views
2657         return unless (defined $project);
2658         # some views should link to OPML, or to generic project feed,
2659         # or don't have specific feed yet (so they should use generic)
2660         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2661
2662         my $branch = undef;
2663         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2664         # (fullname) to differentiate from tag links; this also makes
2665         # possible to detect branch links
2666         for my $ref (get_branch_refs()) {
2667                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2668                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2669                         $branch = $1;
2670                         $matched_ref = $ref;
2671                         last;
2672                 }
2673         }
2674         # find log type for feed description (title)
2675         my $type = 'log';
2676         if (defined $file_name) {
2677                 $type  = "history of $file_name";
2678                 $type .= "/" if ($action eq 'tree');
2679                 $type .= " on '$branch'" if (defined $branch);
2680         } else {
2681                 $type = "log of $branch" if (defined $branch);
2682         }
2683
2684         $res{-title} = $type;
2685         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2686         $res{'file_name'} = $file_name;
2687
2688         return %res;
2689 }
2690
2691 ## ----------------------------------------------------------------------
2692 ## git utility subroutines, invoking git commands
2693
2694 # returns path to the core git executable and the --git-dir parameter as list
2695 sub git_cmd {
2696         $number_of_git_cmds++;
2697         return $GIT, '--git-dir='.$git_dir;
2698 }
2699
2700 # quote the given arguments for passing them to the shell
2701 # quote_command("command", "arg 1", "arg with ' and ! characters")
2702 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2703 # Try to avoid using this function wherever possible.
2704 sub quote_command {
2705         return join(' ',
2706                 map { my $a = $_ =~ s/(['!])/'\\$1'/gr; "'$a'" } @_ );
2707 }
2708
2709 # get HEAD ref of given project as hash
2710 sub git_get_head_hash {
2711         return git_get_full_hash(shift, 'HEAD');
2712 }
2713
2714 sub git_get_full_hash {
2715         return git_get_hash(@_);
2716 }
2717
2718 sub git_get_short_hash {
2719         return git_get_hash(@_, '--short=7');
2720 }
2721
2722 sub git_get_hash {
2723         my ($project, $hash, @options) = @_;
2724         my $o_git_dir = $git_dir;
2725         my $retval = undef;
2726         $git_dir = "$projectroot/$project";
2727         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2728             '--verify', '-q', @options, $hash) {
2729                 $retval = <$fd>;
2730                 chomp $retval if defined $retval;
2731                 close $fd;
2732         }
2733         if (defined $o_git_dir) {
2734                 $git_dir = $o_git_dir;
2735         }
2736         return $retval;
2737 }
2738
2739 # get type of given object
2740 sub git_get_type {
2741         my $hash = shift;
2742
2743         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2744         my $type = <$fd>;
2745         close $fd or return;
2746         chomp $type;
2747         return $type;
2748 }
2749
2750 # repository configuration
2751 our $config_file = '';
2752 our %config;
2753
2754 # store multiple values for single key as anonymous array reference
2755 # single values stored directly in the hash, not as [ <value> ]
2756 sub hash_set_multi {
2757         my ($hash, $key, $value) = @_;
2758
2759         if (!exists $hash->{$key}) {
2760                 $hash->{$key} = $value;
2761         } elsif (!ref $hash->{$key}) {
2762                 $hash->{$key} = [ $hash->{$key}, $value ];
2763         } else {
2764                 push @{$hash->{$key}}, $value;
2765         }
2766 }
2767
2768 # return hash of git project configuration
2769 # optionally limited to some section, e.g. 'gitweb'
2770 sub git_parse_project_config {
2771         my $section_regexp = shift;
2772         my %config;
2773
2774         local $/ = "\0";
2775
2776         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2777                 or return;
2778
2779         while (my $keyval = <$fh>) {
2780                 chomp $keyval;
2781                 my ($key, $value) = split(/\n/, $keyval, 2);
2782
2783                 hash_set_multi(\%config, $key, $value)
2784                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2785         }
2786         close $fh;
2787
2788         return %config;
2789 }
2790
2791 # convert config value to boolean: 'true' or 'false'
2792 # no value, number > 0, 'true' and 'yes' values are true
2793 # rest of values are treated as false (never as error)
2794 sub config_to_bool {
2795         my $val = shift;
2796
2797         return 1 if !defined $val;             # section.key
2798
2799         # strip leading and trailing whitespace
2800         $val =~ s/^\s+//;
2801         $val =~ s/\s+$//;
2802
2803         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2804                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2805 }
2806
2807 # convert config value to simple decimal number
2808 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2809 # to be multiplied by 1024, 1048576, or 1073741824
2810 sub config_to_int {
2811         my $val = shift;
2812
2813         # strip leading and trailing whitespace
2814         $val =~ s/^\s+//;
2815         $val =~ s/\s+$//;
2816
2817         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2818                 $unit = lc($unit);
2819                 # unknown unit is treated as 1
2820                 return $num * ($unit eq 'g' ? 1073741824 :
2821                                $unit eq 'm' ?    1048576 :
2822                                $unit eq 'k' ?       1024 : 1);
2823         }
2824         return $val;
2825 }
2826
2827 # convert config value to array reference, if needed
2828 sub config_to_multi {
2829         my $val = shift;
2830
2831         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2832 }
2833
2834 sub git_get_project_config {
2835         my ($key, $type) = @_;
2836
2837         return unless defined $git_dir;
2838
2839         # key sanity check
2840         return unless ($key);
2841         # only subsection, if exists, is case sensitive,
2842         # and not lowercased by 'git config -z -l'
2843         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2844                 $lo =~ s/_//g;
2845                 $key = join(".", lc($hi), $mi, lc($lo));
2846                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2847         } else {
2848                 $key = lc($key);
2849                 $key =~ s/_//g;
2850                 return if ($key =~ /\W/);
2851         }
2852         $key =~ s/^gitweb\.//;
2853
2854         # type sanity check
2855         if (defined $type) {
2856                 $type =~ s/^--//;
2857                 $type = undef
2858                         unless ($type eq 'bool' || $type eq 'int');
2859         }
2860
2861         # get config
2862         if (!defined $config_file ||
2863             $config_file ne "$git_dir/config") {
2864                 %config = git_parse_project_config('gitweb');
2865                 $config_file = "$git_dir/config";
2866         }
2867
2868         # check if config variable (key) exists
2869         return unless exists $config{"gitweb.$key"};
2870
2871         # ensure given type
2872         if (!defined $type) {
2873                 return $config{"gitweb.$key"};
2874         } elsif ($type eq 'bool') {
2875                 # backward compatibility: 'git config --bool' returns true/false
2876                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2877         } elsif ($type eq 'int') {
2878                 return config_to_int($config{"gitweb.$key"});
2879         }
2880         return $config{"gitweb.$key"};
2881 }
2882
2883 # get hash of given path at given ref
2884 sub git_get_hash_by_path {
2885         my $base = shift;
2886         my $path = shift || return undef;
2887         my $type = shift;
2888
2889         $path =~ s,/+$,,;
2890
2891         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2892                 or die_error(500, "Open git-ls-tree failed");
2893         my $line = <$fd>;
2894         close $fd or return undef;
2895
2896         if (!defined $line) {
2897                 # there is no tree or hash given by $path at $base
2898                 return undef;
2899         }
2900
2901         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2902         $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/;
2903         if (defined $type && $type ne $2) {
2904                 # type doesn't match
2905                 return undef;
2906         }
2907         return $3;
2908 }
2909
2910 # get path of entry with given hash at given tree-ish (ref)
2911 # used to get 'from' filename for combined diff (merge commit) for renames
2912 sub git_get_path_by_hash {
2913         my $base = shift || return;
2914         my $hash = shift || return;
2915
2916         local $/ = "\0";
2917
2918         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2919                 or return undef;
2920         while (my $line = <$fd>) {
2921                 chomp $line;
2922
2923                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2924                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2925                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2926                         close $fd;
2927                         return $1;
2928                 }
2929         }
2930         close $fd;
2931         return undef;
2932 }
2933
2934 ## ......................................................................
2935 ## git utility functions, directly accessing git repository
2936
2937 # get the value of config variable either from file named as the variable
2938 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2939 # configuration variable in the repository config file.
2940 sub git_get_file_or_project_config {
2941         my ($path, $name) = @_;
2942
2943         $git_dir = "$projectroot/$path";
2944         open my $fd, '<', "$git_dir/$name"
2945                 or return git_get_project_config($name);
2946         my $conf = <$fd>;
2947         close $fd;
2948         if (defined $conf) {
2949                 chomp $conf;
2950         }
2951         return $conf;
2952 }
2953
2954 sub git_get_project_description {
2955         my $path = shift;
2956         return git_get_file_or_project_config($path, 'description');
2957 }
2958
2959 sub git_get_project_category {
2960         my $path = shift;
2961         return git_get_file_or_project_config($path, 'category');
2962 }
2963
2964
2965 # supported formats:
2966 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2967 #   - if its contents is a number, use it as tag weight,
2968 #   - otherwise add a tag with weight 1
2969 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2970 #   the same value multiple times increases tag weight
2971 # * `gitweb.ctag' multi-valued repo config variable
2972 sub git_get_project_ctags {
2973         my $project = shift;
2974         my $ctags = {};
2975
2976         $git_dir = "$projectroot/$project";
2977         if (opendir my $dh, "$git_dir/ctags") {
2978                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2979                 foreach my $tagfile (@files) {
2980                         open my $ct, '<', $tagfile
2981                                 or next;
2982                         my $val = <$ct>;
2983                         chomp $val if $val;
2984                         close $ct;
2985
2986                         (my $ctag = $tagfile) =~ s#.*/##;
2987                         if ($val =~ /^\d+$/) {
2988                                 $ctags->{$ctag} = $val;
2989                         } else {
2990                                 $ctags->{$ctag} = 1;
2991                         }
2992                 }
2993                 closedir $dh;
2994
2995         } elsif (open my $fh, '<', "$git_dir/ctags") {
2996                 while (my $line = <$fh>) {
2997                         chomp $line;
2998                         $ctags->{$line}++ if $line;
2999                 }
3000                 close $fh;
3001
3002         } else {
3003                 my $taglist = config_to_multi(git_get_project_config('ctag'));
3004                 foreach my $tag (@$taglist) {
3005                         $ctags->{$tag}++;
3006                 }
3007         }
3008
3009         return $ctags;
3010 }
3011
3012 # return hash, where keys are content tags ('ctags'),
3013 # and values are sum of weights of given tag in every project
3014 sub git_gather_all_ctags {
3015         my $projects = shift;
3016         my $ctags = {};
3017
3018         foreach my $p (@$projects) {
3019                 foreach my $ct (keys %{$p->{'ctags'}}) {
3020                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
3021                 }
3022         }
3023
3024         return $ctags;
3025 }
3026
3027 sub git_populate_project_tagcloud {
3028         my $ctags = shift;
3029
3030         # First, merge different-cased tags; tags vote on casing
3031         my %ctags_lc;
3032         foreach (keys %$ctags) {
3033                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
3034                 if (not $ctags_lc{lc $_}->{topcount}
3035                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
3036                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
3037                         $ctags_lc{lc $_}->{topname} = $_;
3038                 }
3039         }
3040
3041         my $cloud;
3042         my $matched = $input_params{'ctag'};
3043         if (eval { require HTML::TagCloud; 1; }) {
3044                 $cloud = HTML::TagCloud->new;
3045                 foreach my $ctag (sort keys %ctags_lc) {
3046                         # Pad the title with spaces so that the cloud looks
3047                         # less crammed.
3048                         my $title = esc_html($ctags_lc{$ctag}->{topname});
3049                         $title =~ s/ /&nbsp;/g;
3050                         $title =~ s/^/&nbsp;/g;
3051                         $title =~ s/$/&nbsp;/g;
3052                         if (defined $matched && $matched eq $ctag) {
3053                                 $title = qq(<span class="match">$title</span>);
3054                         }
3055                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3056                                     $ctags_lc{$ctag}->{count});
3057                 }
3058         } else {
3059                 $cloud = {};
3060                 foreach my $ctag (keys %ctags_lc) {
3061                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3062                         if (defined $matched && $matched eq $ctag) {
3063                                 $title = qq(<span class="match">$title</span>);
3064                         }
3065                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3066                         $cloud->{$ctag}{ctag} =
3067                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3068                 }
3069         }
3070         return $cloud;
3071 }
3072
3073 sub git_show_project_tagcloud {
3074         my ($cloud, $count) = @_;
3075         if (ref $cloud eq 'HTML::TagCloud') {
3076                 return $cloud->html_and_css($count);
3077         } else {
3078                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3079                 return
3080                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3081                         join (', ', map {
3082                                 $cloud->{$_}->{'ctag'}
3083                         } splice(@tags, 0, $count)) .
3084                         '</div>';
3085         }
3086 }
3087
3088 sub git_get_project_url_list {
3089         my $path = shift;
3090
3091         $git_dir = "$projectroot/$path";
3092         open my $fd, '<', "$git_dir/cloneurl"
3093                 or return wantarray ?
3094                 @{ config_to_multi(git_get_project_config('url')) } :
3095                    config_to_multi(git_get_project_config('url'));
3096         my @git_project_url_list = map { chomp; $_ } <$fd>;
3097         close $fd;
3098
3099         return wantarray ? @git_project_url_list : \@git_project_url_list;
3100 }
3101
3102 sub git_get_projects_list {
3103         my $filter = shift || '';
3104         my $paranoid = shift;
3105         my @list;
3106
3107         if (-d $projects_list) {
3108                 # search in directory
3109                 my $dir = $projects_list;
3110                 # remove the trailing "/"
3111                 $dir =~ s!/+$!!;
3112                 my $pfxlen = length("$dir");
3113                 my $pfxdepth = ($dir =~ tr!/!!);
3114                 # when filtering, search only given subdirectory
3115                 if ($filter && !$paranoid) {
3116                         $dir .= "/$filter";
3117                         $dir =~ s!/+$!!;
3118                 }
3119
3120                 File::Find::find({
3121                         follow_fast => 1, # follow symbolic links
3122                         follow_skip => 2, # ignore duplicates
3123                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3124                         wanted => sub {
3125                                 # global variables
3126                                 our $project_maxdepth;
3127                                 our $projectroot;
3128                                 # skip project-list toplevel, if we get it.
3129                                 return if (m!^[/.]$!);
3130                                 # only directories can be git repositories
3131                                 return unless (-d $_);
3132                                 # need search permission
3133                                 return unless (-x $_);
3134                                 # don't traverse too deep (Find is super slow on os x)
3135                                 # $project_maxdepth excludes depth of $projectroot
3136                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3137                                         $File::Find::prune = 1;
3138                                         return;
3139                                 }
3140
3141                                 my $path = substr($File::Find::name, $pfxlen + 1);
3142                                 # paranoidly only filter here
3143                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3144                                         next;
3145                                 }
3146                                 # we check related file in $projectroot
3147                                 if (check_export_ok("$projectroot/$path")) {
3148                                         push @list, { path => $path };
3149                                         $File::Find::prune = 1;
3150                                 }
3151                         },
3152                 }, "$dir");
3153
3154         } elsif (-f $projects_list) {
3155                 # read from file(url-encoded):
3156                 # 'git%2Fgit.git Linus+Torvalds'
3157                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3158                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3159                 open my $fd, '<', $projects_list or return;
3160         PROJECT:
3161                 while (my $line = <$fd>) {
3162                         chomp $line;
3163                         my ($path, $owner) = split ' ', $line;
3164                         $path = unescape($path);
3165                         $owner = unescape($owner);
3166                         if (!defined $path) {
3167                                 next;
3168                         }
3169                         # if $filter is rpovided, check if $path begins with $filter
3170                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3171                                 next;
3172                         }
3173                         if (check_export_ok("$projectroot/$path")) {
3174                                 my $pr = {
3175                                         path => $path
3176                                 };
3177                                 if ($owner) {
3178                                         $pr->{'owner'} = to_utf8($owner);
3179                                 }
3180                                 push @list, $pr;
3181                         }
3182                 }
3183                 close $fd;
3184         }
3185         return @list;
3186 }
3187
3188 # written with help of Tree::Trie module (Perl Artistic License, GPL compatible)
3189 # as side effects it sets 'forks' field to list of forks for forked projects
3190 sub filter_forks_from_projects_list {
3191         my $projects = shift;
3192
3193         my %trie; # prefix tree of directories (path components)
3194         # generate trie out of those directories that might contain forks
3195         foreach my $pr (@$projects) {
3196                 my $path = $pr->{'path'};
3197                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3198                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3199                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3200                 next unless (-d "$projectroot/$path"); # containing directory exists
3201                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3202
3203                 # add to trie
3204                 my @dirs = split('/', $path);
3205                 # walk the trie, until either runs out of components or out of trie
3206                 my $ref = \%trie;
3207                 while (scalar @dirs &&
3208                        exists($ref->{$dirs[0]})) {
3209                         $ref = $ref->{shift @dirs};
3210                 }
3211                 # create rest of trie structure from rest of components
3212                 foreach my $dir (@dirs) {
3213                         $ref = $ref->{$dir} = {};
3214                 }
3215                 # create end marker, store $pr as a data
3216                 $ref->{''} = $pr if (!exists $ref->{''});
3217         }
3218
3219         # filter out forks, by finding shortest prefix match for paths
3220         my @filtered;
3221  PROJECT:
3222         foreach my $pr (@$projects) {
3223                 # trie lookup
3224                 my $ref = \%trie;
3225         DIR:
3226                 foreach my $dir (split('/', $pr->{'path'})) {
3227                         if (exists $ref->{''}) {
3228                                 # found [shortest] prefix, is a fork - skip it
3229                                 push @{$ref->{''}{'forks'}}, $pr;
3230                                 next PROJECT;
3231                         }
3232                         if (!exists $ref->{$dir}) {
3233                                 # not in trie, cannot have prefix, not a fork
3234                                 push @filtered, $pr;
3235                                 next PROJECT;
3236                         }
3237                         # If the dir is there, we just walk one step down the trie.
3238                         $ref = $ref->{$dir};
3239                 }
3240                 # we ran out of trie
3241                 # (shouldn't happen: it's either no match, or end marker)
3242                 push @filtered, $pr;
3243         }
3244
3245         return @filtered;
3246 }
3247
3248 # note: fill_project_list_info must be run first,
3249 # for 'descr_long' and 'ctags' to be filled
3250 sub search_projects_list {
3251         my ($projlist, %opts) = @_;
3252         my $tagfilter  = $opts{'tagfilter'};
3253         my $search_re = $opts{'search_regexp'};
3254
3255         return @$projlist
3256                 unless ($tagfilter || $search_re);
3257
3258         # searching projects require filling to be run before it;
3259         fill_project_list_info($projlist,
3260                                $tagfilter  ? 'ctags' : (),
3261                                $search_re ? ('path', 'descr') : ());
3262         my @projects;
3263  PROJECT:
3264         foreach my $pr (@$projlist) {
3265
3266                 if ($tagfilter) {
3267                         next unless ref($pr->{'ctags'}) eq 'HASH';
3268                         next unless
3269                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3270                 }
3271
3272                 if ($search_re) {
3273                         next unless
3274                                 $pr->{'path'} =~ /$search_re/ ||
3275                                 $pr->{'descr_long'} =~ /$search_re/;
3276                 }
3277
3278                 push @projects, $pr;
3279         }
3280
3281         return @projects;
3282 }
3283
3284 our $gitweb_project_owner = undef;
3285 sub git_get_project_list_from_file {
3286
3287         return if (defined $gitweb_project_owner);
3288
3289         $gitweb_project_owner = {};
3290         # read from file (url-encoded):
3291         # 'git%2Fgit.git Linus+Torvalds'
3292         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3293         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3294         if (-f $projects_list) {
3295                 open(my $fd, '<', $projects_list);
3296                 while (my $line = <$fd>) {
3297                         chomp $line;
3298                         my ($pr, $ow) = split ' ', $line;
3299                         $pr = unescape($pr);
3300                         $ow = unescape($ow);
3301                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3302                 }
3303                 close $fd;
3304         }
3305 }
3306
3307 sub git_get_project_owner {
3308         my $project = shift;
3309         my $owner;
3310
3311         return undef unless $project;
3312         $git_dir = "$projectroot/$project";
3313
3314         if (!defined $gitweb_project_owner) {
3315                 git_get_project_list_from_file();
3316         }
3317
3318         if (exists $gitweb_project_owner->{$project}) {
3319                 $owner = $gitweb_project_owner->{$project};
3320         }
3321         if (!defined $owner){
3322                 $owner = git_get_project_config('owner');
3323         }
3324         if (!defined $owner) {
3325                 $owner = get_file_owner("$git_dir");
3326         }
3327
3328         return $owner;
3329 }
3330
3331 sub git_get_last_activity {
3332         my ($path) = @_;
3333         my $fd;
3334
3335         $git_dir = "$projectroot/$path";
3336         open($fd, "-|", git_cmd(), 'for-each-ref',
3337              '--format=%(committer)',
3338              '--sort=-committerdate',
3339              '--count=1',
3340              map { "refs/$_" } get_branch_refs ()) or return;
3341         my $most_recent = <$fd>;
3342         close $fd or return;
3343         if (defined $most_recent &&
3344             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3345                 my $timestamp = $1;
3346                 my $age = time - $timestamp;
3347                 return ($age, age_string($age));
3348         }
3349         return (undef, undef);
3350 }
3351
3352 # Implementation note: when a single remote is wanted, we cannot use 'git
3353 # remote show -n' because that command always work (assuming it's a remote URL
3354 # if it's not defined), and we cannot use 'git remote show' because that would
3355 # try to make a network roundtrip. So the only way to find if that particular
3356 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3357 # and when we find what we want.
3358 sub git_get_remotes_list {
3359         my $wanted = shift;
3360         my %remotes = ();
3361
3362         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3363         return unless $fd;
3364         while (my $remote = <$fd>) {
3365                 chomp $remote;
3366                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3367                 next if $wanted and not $remote eq $wanted;
3368                 my ($url, $key) = ($1, $2);
3369
3370                 $remotes{$remote} ||= { 'heads' => () };
3371                 $remotes{$remote}{$key} = $url;
3372         }
3373         close $fd or return;
3374         return wantarray ? %remotes : \%remotes;
3375 }
3376
3377 # Takes a hash of remotes as first parameter and fills it by adding the
3378 # available remote heads for each of the indicated remotes.
3379 sub fill_remote_heads {
3380         my $remotes = shift;
3381         my @heads = map { "remotes/$_" } keys %$remotes;
3382         my @remoteheads = git_get_heads_list(undef, @heads);
3383         foreach my $remote (keys %$remotes) {
3384                 $remotes->{$remote}{'heads'} = [ grep {
3385                         $_->{'name'} =~ s!^$remote/!!
3386                         } @remoteheads ];
3387         }
3388 }
3389
3390 sub git_get_references {
3391         my $type = shift || "";
3392         my %refs;
3393         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3394         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3395         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3396                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3397                 or return;
3398
3399         while (my $line = <$fd>) {
3400                 chomp $line;
3401                 if ($line =~ m!^($oid_regex)\srefs/($type.*)$!) {
3402                         if (defined $refs{$1}) {
3403                                 push @{$refs{$1}}, $2;
3404                         } else {
3405                                 $refs{$1} = [ $2 ];
3406                         }
3407                 }
3408         }
3409         close $fd or return;
3410         return \%refs;
3411 }
3412
3413 sub git_get_rev_name_tags {
3414         my $hash = shift || return undef;
3415
3416         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3417                 or return;
3418         my $name_rev = <$fd>;
3419         close $fd;
3420
3421         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3422                 return $1;
3423         } else {
3424                 # catches also '$hash undefined' output
3425                 return undef;
3426         }
3427 }
3428
3429 ## ----------------------------------------------------------------------
3430 ## parse to hash functions
3431
3432 sub parse_date {
3433         my $epoch = shift;
3434         my $tz = shift || "-0000";
3435
3436         my %date;
3437         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3438         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3439         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3440         $date{'hour'} = $hour;
3441         $date{'minute'} = $min;
3442         $date{'mday'} = $mday;
3443         $date{'day'} = $days[$wday];
3444         $date{'month'} = $months[$mon];
3445         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3446                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3447         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3448                              $mday, $months[$mon], $hour ,$min;
3449         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3450                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3451
3452         my ($tz_sign, $tz_hour, $tz_min) =
3453                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3454         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3455         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3456         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3457         $date{'hour_local'} = $hour;
3458         $date{'minute_local'} = $min;
3459         $date{'tz_local'} = $tz;
3460         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3461                                   1900+$year, $mon+1, $mday,
3462                                   $hour, $min, $sec, $tz);
3463         return %date;
3464 }
3465
3466 sub hide_mailaddrs_if_private {
3467         my $line = shift;
3468         return $line unless gitweb_check_feature('email-privacy');
3469         $line =~ s/<[^@>]+@[^>]+>/<redacted>/g;
3470         return $line;
3471 }
3472
3473 sub parse_tag {
3474         my $tag_id = shift;
3475         my %tag;
3476         my @comment;
3477
3478         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3479         $tag{'id'} = $tag_id;
3480         while (my $line = <$fd>) {
3481                 chomp $line;
3482                 if ($line =~ m/^object ($oid_regex)$/) {
3483                         $tag{'object'} = $1;
3484                 } elsif ($line =~ m/^type (.+)$/) {
3485                         $tag{'type'} = $1;
3486                 } elsif ($line =~ m/^tag (.+)$/) {
3487                         $tag{'name'} = $1;
3488                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3489                         $tag{'author'} = hide_mailaddrs_if_private($1);
3490                         $tag{'author_epoch'} = $2;
3491                         $tag{'author_tz'} = $3;
3492                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3493                                 $tag{'author_name'}  = $1;
3494                                 $tag{'author_email'} = $2;
3495                         } else {
3496                                 $tag{'author_name'} = $tag{'author'};
3497                         }
3498                 } elsif ($line =~ m/--BEGIN/) {
3499                         push @comment, $line;
3500                         last;
3501                 } elsif ($line eq "") {
3502                         last;
3503                 }
3504         }
3505         push @comment, <$fd>;
3506         $tag{'comment'} = \@comment;
3507         close $fd or return;
3508         if (!defined $tag{'name'}) {
3509                 return
3510         };
3511         return %tag
3512 }
3513
3514 sub parse_commit_text {
3515         my ($commit_text, $withparents) = @_;
3516         my @commit_lines = split '\n', $commit_text;
3517         my %co;
3518
3519         pop @commit_lines; # Remove '\0'
3520
3521         if (! @commit_lines) {
3522                 return;
3523         }
3524
3525         my $header = shift @commit_lines;
3526         if ($header !~ m/^$oid_regex/) {
3527                 return;
3528         }
3529         ($co{'id'}, my @parents) = split ' ', $header;
3530         while (my $line = shift @commit_lines) {
3531                 last if $line eq "\n";
3532                 if ($line =~ m/^tree ($oid_regex)$/) {
3533                         $co{'tree'} = $1;
3534                 } elsif ((!defined $withparents) && ($line =~ m/^parent ($oid_regex)$/)) {
3535                         push @parents, $1;
3536                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3537                         $co{'author'} = hide_mailaddrs_if_private(to_utf8($1));
3538                         $co{'author_epoch'} = $2;
3539                         $co{'author_tz'} = $3;
3540                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3541                                 $co{'author_name'}  = $1;
3542                                 $co{'author_email'} = $2;
3543                         } else {
3544                                 $co{'author_name'} = $co{'author'};
3545                         }
3546                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3547                         $co{'committer'} = hide_mailaddrs_if_private(to_utf8($1));
3548                         $co{'committer_epoch'} = $2;
3549                         $co{'committer_tz'} = $3;
3550                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3551                                 $co{'committer_name'}  = $1;
3552                                 $co{'committer_email'} = $2;
3553                         } else {
3554                                 $co{'committer_name'} = $co{'committer'};
3555                         }
3556                 }
3557         }
3558         if (!defined $co{'tree'}) {
3559                 return;
3560         };
3561         $co{'parents'} = \@parents;
3562         $co{'parent'} = $parents[0];
3563
3564         foreach my $title (@commit_lines) {
3565                 $title =~ s/^    //;
3566                 if ($title ne "") {
3567                         $co{'title'} = chop_str($title, 80, 5);
3568                         $co{'title_short'} = chop_str($title, 50, 5);
3569                         last;
3570                 }
3571         }
3572         if (! defined $co{'title'} || $co{'title'} eq "") {
3573                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3574         }
3575         # remove added spaces, redact e-mail addresses if applicable.
3576         foreach my $line (@commit_lines) {
3577                 $line =~ s/^    //;
3578                 $line = hide_mailaddrs_if_private($line);
3579         }
3580         $co{'comment'} = \@commit_lines;
3581
3582         my $age = time - $co{'committer_epoch'};
3583         $co{'age'} = $age;
3584         $co{'age_string'} = age_string($age);
3585         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3586         if ($age > 60*60*24*7*2) {
3587                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3588                 $co{'age_string_age'} = $co{'age_string'};
3589         } else {
3590                 $co{'age_string_date'} = $co{'age_string'};
3591                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3592         }
3593         return %co;
3594 }
3595
3596 sub parse_commit {
3597         my ($commit_id) = @_;
3598         my %co;
3599
3600         local $/ = "\0";
3601
3602         open my $fd, "-|", git_cmd(), "rev-list",
3603                 "--parents",
3604                 "--header",
3605                 "--max-count=1",
3606                 $commit_id,
3607                 "--",
3608                 or die_error(500, "Open git-rev-list failed");
3609         %co = parse_commit_text(<$fd>, 1);
3610         close $fd;
3611
3612         return %co;
3613 }
3614
3615 sub parse_commits {
3616         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3617         my @cos;
3618
3619         $maxcount ||= 1;
3620         $skip ||= 0;
3621
3622         local $/ = "\0";
3623
3624         open my $fd, "-|", git_cmd(), "rev-list",
3625                 "--header",
3626                 @args,
3627                 ("--max-count=" . $maxcount),
3628                 ("--skip=" . $skip),
3629                 @extra_options,
3630                 $commit_id,
3631                 "--",
3632                 ($filename ? ($filename) : ())
3633                 or die_error(500, "Open git-rev-list failed");
3634         while (my $line = <$fd>) {
3635                 my %co = parse_commit_text($line);
3636                 push @cos, \%co;
3637         }
3638         close $fd;
3639
3640         return wantarray ? @cos : \@cos;
3641 }
3642
3643 # parse line of git-diff-tree "raw" output
3644 sub parse_difftree_raw_line {
3645         my $line = shift;
3646         my %res;
3647
3648         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3649         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3650         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ($oid_regex) ($oid_regex) (.)([0-9]{0,3})\t(.*)$/) {
3651                 $res{'from_mode'} = $1;
3652                 $res{'to_mode'} = $2;
3653                 $res{'from_id'} = $3;
3654                 $res{'to_id'} = $4;
3655                 $res{'status'} = $5;
3656                 $res{'similarity'} = $6;
3657                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3658                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3659                 } else {
3660                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3661                 }
3662         }
3663         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3664         # combined diff (for merge commit)
3665         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:$oid_regex )+)([a-zA-Z]+)\t(.*)$//) {
3666                 $res{'nparents'}  = length($1);
3667                 $res{'from_mode'} = [ split(' ', $2) ];
3668                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3669                 $res{'from_id'} = [ split(' ', $3) ];
3670                 $res{'to_id'} = pop @{$res{'from_id'}};
3671                 $res{'status'} = [ split('', $4) ];
3672                 $res{'to_file'} = unquote($5);
3673         }
3674         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3675         elsif ($line =~ m/^($oid_regex)$/) {
3676                 $res{'commit'} = $1;
3677         }
3678
3679         return wantarray ? %res : \%res;
3680 }
3681
3682 # wrapper: return parsed line of git-diff-tree "raw" output
3683 # (the argument might be raw line, or parsed info)
3684 sub parsed_difftree_line {
3685         my $line_or_ref = shift;
3686
3687         if (ref($line_or_ref) eq "HASH") {
3688                 # pre-parsed (or generated by hand)
3689                 return $line_or_ref;
3690         } else {
3691                 return parse_difftree_raw_line($line_or_ref);
3692         }
3693 }
3694
3695 # parse line of git-ls-tree output
3696 sub parse_ls_tree_line {
3697         my $line = shift;
3698         my %opts = @_;
3699         my %res;
3700
3701         if ($opts{'-l'}) {
3702                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3703                 $line =~ m/^([0-9]+) (.+) ($oid_regex) +(-|[0-9]+)\t(.+)$/s;
3704
3705                 $res{'mode'} = $1;
3706                 $res{'type'} = $2;
3707                 $res{'hash'} = $3;
3708                 $res{'size'} = $4;
3709                 if ($opts{'-z'}) {
3710                         $res{'name'} = $5;
3711                 } else {
3712                         $res{'name'} = unquote($5);
3713                 }
3714         } else {
3715                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3716                 $line =~ m/^([0-9]+) (.+) ($oid_regex)\t(.+)$/s;
3717
3718                 $res{'mode'} = $1;
3719                 $res{'type'} = $2;
3720                 $res{'hash'} = $3;
3721                 if ($opts{'-z'}) {
3722                         $res{'name'} = $4;
3723                 } else {
3724                         $res{'name'} = unquote($4);
3725                 }
3726         }
3727
3728         return wantarray ? %res : \%res;
3729 }
3730
3731 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3732 sub parse_from_to_diffinfo {
3733         my ($diffinfo, $from, $to, @parents) = @_;
3734
3735         if ($diffinfo->{'nparents'}) {
3736                 # combined diff
3737                 $from->{'file'} = [];
3738                 $from->{'href'} = [];
3739                 fill_from_file_info($diffinfo, @parents)
3740                         unless exists $diffinfo->{'from_file'};
3741                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3742                         $from->{'file'}[$i] =
3743                                 defined $diffinfo->{'from_file'}[$i] ?
3744                                         $diffinfo->{'from_file'}[$i] :
3745                                         $diffinfo->{'to_file'};
3746                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3747                                 $from->{'href'}[$i] = href(action=>"blob",
3748                                                            hash_base=>$parents[$i],
3749                                                            hash=>$diffinfo->{'from_id'}[$i],
3750                                                            file_name=>$from->{'file'}[$i]);
3751                         } else {
3752                                 $from->{'href'}[$i] = undef;
3753                         }
3754                 }
3755         } else {
3756                 # ordinary (not combined) diff
3757                 $from->{'file'} = $diffinfo->{'from_file'};
3758                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3759                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3760                                                hash=>$diffinfo->{'from_id'},
3761                                                file_name=>$from->{'file'});
3762                 } else {
3763                         delete $from->{'href'};
3764                 }
3765         }
3766
3767         $to->{'file'} = $diffinfo->{'to_file'};
3768         if (!is_deleted($diffinfo)) { # file exists in result
3769                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3770                                      hash=>$diffinfo->{'to_id'},
3771                                      file_name=>$to->{'file'});
3772         } else {
3773                 delete $to->{'href'};
3774         }
3775 }
3776
3777 ## ......................................................................
3778 ## parse to array of hashes functions
3779
3780 sub git_get_heads_list {
3781         my ($limit, @classes) = @_;
3782         @classes = get_branch_refs() unless @classes;
3783         my @patterns = map { "refs/$_" } @classes;
3784         my @headslist;
3785
3786         open my $fd, '-|', git_cmd(), 'for-each-ref',
3787                 ($limit ? '--count='.($limit+1) : ()),
3788                 '--sort=-HEAD', '--sort=-committerdate',
3789                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3790                 @patterns
3791                 or return;
3792         while (my $line = <$fd>) {
3793                 my %ref_item;
3794
3795                 chomp $line;
3796                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3797                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3798                 my ($committer, $epoch, $tz) =
3799                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3800                 $ref_item{'fullname'}  = $name;
3801                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3802                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3803                 $ref_item{'name'} = $name;
3804                 # for refs neither in 'heads' nor 'remotes' we want to
3805                 # show their ref dir
3806                 my $ref_dir = (defined $1) ? $1 : '';
3807                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3808                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3809                 }
3810
3811                 $ref_item{'id'}    = $hash;
3812                 $ref_item{'title'} = $title || '(no commit message)';
3813                 $ref_item{'epoch'} = $epoch;
3814                 if ($epoch) {
3815                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3816                 } else {
3817                         $ref_item{'age'} = "unknown";
3818                 }
3819
3820                 push @headslist, \%ref_item;
3821         }
3822         close $fd;
3823
3824         return wantarray ? @headslist : \@headslist;
3825 }
3826
3827 sub git_get_tags_list {
3828         my $limit = shift;
3829         my @tagslist;
3830
3831         open my $fd, '-|', git_cmd(), 'for-each-ref',
3832                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3833                 '--format=%(objectname) %(objecttype) %(refname) '.
3834                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3835                 'refs/tags'
3836                 or return;
3837         while (my $line = <$fd>) {
3838                 my %ref_item;
3839
3840                 chomp $line;
3841                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3842                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3843                 my ($creator, $epoch, $tz) =
3844                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3845                 $ref_item{'fullname'} = $name;
3846                 $name =~ s!^refs/tags/!!;
3847
3848                 $ref_item{'type'} = $type;
3849                 $ref_item{'id'} = $id;
3850                 $ref_item{'name'} = $name;
3851                 if ($type eq "tag") {
3852                         $ref_item{'subject'} = $title;
3853                         $ref_item{'reftype'} = $reftype;
3854                         $ref_item{'refid'}   = $refid;
3855                 } else {
3856                         $ref_item{'reftype'} = $type;
3857                         $ref_item{'refid'}   = $id;
3858                 }
3859
3860                 if ($type eq "tag" || $type eq "commit") {
3861                         $ref_item{'epoch'} = $epoch;
3862                         if ($epoch) {
3863                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3864                         } else {
3865                                 $ref_item{'age'} = "unknown";
3866                         }
3867                 }
3868
3869                 push @tagslist, \%ref_item;
3870         }
3871         close $fd;
3872
3873         return wantarray ? @tagslist : \@tagslist;
3874 }
3875
3876 ## ----------------------------------------------------------------------
3877 ## filesystem-related functions
3878
3879 sub get_file_owner {
3880         my $path = shift;
3881
3882         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3883         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3884         if (!defined $gcos) {
3885                 return undef;
3886         }
3887         my $owner = $gcos;
3888         $owner =~ s/[,;].*$//;
3889         return to_utf8($owner);
3890 }
3891
3892 # assume that file exists
3893 sub insert_file {
3894         my $filename = shift;
3895
3896         open my $fd, '<', $filename;
3897         print map { to_utf8($_) } <$fd>;
3898         close $fd;
3899 }
3900
3901 ## ......................................................................
3902 ## mimetype related functions
3903
3904 sub mimetype_guess_file {
3905         my $filename = shift;
3906         my $mimemap = shift;
3907         -r $mimemap or return undef;
3908
3909         my %mimemap;
3910         open(my $mh, '<', $mimemap) or return undef;
3911         while (<$mh>) {
3912                 next if m/^#/; # skip comments
3913                 my ($mimetype, @exts) = split(/\s+/);
3914                 foreach my $ext (@exts) {
3915                         $mimemap{$ext} = $mimetype;
3916                 }
3917         }
3918         close($mh);
3919
3920         $filename =~ /\.([^.]*)$/;
3921         return $mimemap{$1};
3922 }
3923
3924 sub mimetype_guess {
3925         my $filename = shift;
3926         my $mime;
3927         $filename =~ /\./ or return undef;
3928
3929         if ($mimetypes_file) {
3930                 my $file = $mimetypes_file;
3931                 if ($file !~ m!^/!) { # if it is relative path
3932                         # it is relative to project
3933                         $file = "$projectroot/$project/$file";
3934                 }
3935                 $mime = mimetype_guess_file($filename, $file);
3936         }
3937         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3938         return $mime;
3939 }
3940
3941 sub blob_mimetype {
3942         my $fd = shift;
3943         my $filename = shift;
3944
3945         if ($filename) {
3946                 my $mime = mimetype_guess($filename);
3947                 $mime and return $mime;
3948         }
3949
3950         # just in case
3951         return $default_blob_plain_mimetype unless $fd;
3952
3953         if (-T $fd) {
3954                 return 'text/plain';
3955         } elsif (! $filename) {
3956                 return 'application/octet-stream';
3957         } elsif ($filename =~ m/\.png$/i) {
3958                 return 'image/png';
3959         } elsif ($filename =~ m/\.gif$/i) {
3960                 return 'image/gif';
3961         } elsif ($filename =~ m/\.jpe?g$/i) {
3962                 return 'image/jpeg';
3963         } else {
3964                 return 'application/octet-stream';
3965         }
3966 }
3967
3968 sub blob_contenttype {
3969         my ($fd, $file_name, $type) = @_;
3970
3971         $type ||= blob_mimetype($fd, $file_name);
3972         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3973                 $type .= "; charset=$default_text_plain_charset";
3974         }
3975
3976         return $type;
3977 }
3978
3979 # guess file syntax for syntax highlighting; return undef if no highlighting
3980 # the name of syntax can (in the future) depend on syntax highlighter used
3981 sub guess_file_syntax {
3982         my ($highlight, $file_name) = @_;
3983         return undef unless ($highlight && defined $file_name);
3984         my $basename = basename($file_name, '.in');
3985         return $highlight_basename{$basename}
3986                 if exists $highlight_basename{$basename};
3987
3988         $basename =~ /\.([^.]*)$/;
3989         my $ext = $1 or return undef;
3990         return $highlight_ext{$ext}
3991                 if exists $highlight_ext{$ext};
3992
3993         return undef;
3994 }
3995
3996 # run highlighter and return FD of its output,
3997 # or return original FD if no highlighting
3998 sub run_highlighter {
3999         my ($fd, $highlight, $syntax) = @_;
4000         return $fd unless ($highlight);
4001
4002         close $fd;
4003         my $syntax_arg = (defined $syntax) ? "--syntax $syntax" : "--force";
4004         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
4005                   quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
4006                     '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
4007                     '--', "-fe=$fallback_encoding")." | ".
4008                   quote_command($highlight_bin).
4009                   " --replace-tabs=8 --fragment $syntax_arg |"
4010                 or die_error(500, "Couldn't open file or run syntax highlighter");
4011         return $fd;
4012 }
4013
4014 ## ======================================================================
4015 ## functions printing HTML: header, footer, error page
4016
4017 sub get_page_title {
4018         my $title = to_utf8($site_name);
4019
4020         unless (defined $project) {
4021                 if (defined $project_filter) {
4022                         $title .= " - projects in '" . esc_path($project_filter) . "'";
4023                 }
4024                 return $title;
4025         }
4026         $title .= " - " . to_utf8($project);
4027
4028         return $title unless (defined $action);
4029         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
4030
4031         return $title unless (defined $file_name);
4032         $title .= " - " . esc_path($file_name);
4033         if ($action eq "tree" && $file_name !~ m|/$|) {
4034                 $title .= "/";
4035         }
4036
4037         return $title;
4038 }
4039
4040 sub get_content_type_html {
4041         # require explicit support from the UA if we are to send the page as
4042         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
4043         # we have to do this because MSIE sometimes globs '*/*', pretending to
4044         # support xhtml+xml but choking when it gets what it asked for.
4045         if (defined $cgi->http('HTTP_ACCEPT') &&
4046             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
4047             $cgi->Accept('application/xhtml+xml') != 0) {
4048                 return 'application/xhtml+xml';
4049         } else {
4050                 return 'text/html';
4051         }
4052 }
4053
4054 sub print_feed_meta {
4055         if (defined $project) {
4056                 my %href_params = get_feed_info();
4057                 if (!exists $href_params{'-title'}) {
4058                         $href_params{'-title'} = 'log';
4059                 }
4060
4061                 foreach my $format (qw(RSS Atom)) {
4062                         my $type = lc($format);
4063                         my %link_attr = (
4064                                 '-rel' => 'alternate',
4065                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4066                                 '-type' => "application/$type+xml"
4067                         );
4068
4069                         $href_params{'extra_options'} = undef;
4070                         $href_params{'action'} = $type;
4071                         $link_attr{'-href'} = esc_attr(href(%href_params));
4072                         print "<link ".
4073                               "rel=\"$link_attr{'-rel'}\" ".
4074                               "title=\"$link_attr{'-title'}\" ".
4075                               "href=\"$link_attr{'-href'}\" ".
4076                               "type=\"$link_attr{'-type'}\" ".
4077                               "/>\n";
4078
4079                         $href_params{'extra_options'} = '--no-merges';
4080                         $link_attr{'-href'} = esc_attr(href(%href_params));
4081                         $link_attr{'-title'} .= ' (no merges)';
4082                         print "<link ".
4083                               "rel=\"$link_attr{'-rel'}\" ".
4084                               "title=\"$link_attr{'-title'}\" ".
4085                               "href=\"$link_attr{'-href'}\" ".
4086                               "type=\"$link_attr{'-type'}\" ".
4087                               "/>\n";
4088                 }
4089
4090         } else {
4091                 printf('<link rel="alternate" title="%s projects list" '.
4092                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4093                        esc_attr($site_name),
4094                        esc_attr(href(project=>undef, action=>"project_index")));
4095                 printf('<link rel="alternate" title="%s projects feeds" '.
4096                        'href="%s" type="text/x-opml" />'."\n",
4097                        esc_attr($site_name),
4098                        esc_attr(href(project=>undef, action=>"opml")));
4099         }
4100 }
4101
4102 sub print_header_links {
4103         my $status = shift;
4104
4105         # print out each stylesheet that exist, providing backwards capability
4106         # for those people who defined $stylesheet in a config file
4107         if (defined $stylesheet) {
4108                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4109         } else {
4110                 foreach my $stylesheet (@stylesheets) {
4111                         next unless $stylesheet;
4112                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4113                 }
4114         }
4115         print_feed_meta()
4116                 if ($status eq '200 OK');
4117         if (defined $favicon) {
4118                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4119         }
4120 }
4121
4122 sub print_nav_breadcrumbs_path {
4123         my $dirprefix = undef;
4124         while (my $part = shift) {
4125                 $dirprefix .= "/" if defined $dirprefix;
4126                 $dirprefix .= $part;
4127                 print $cgi->a({-href => href(project => undef,
4128                                              project_filter => $dirprefix,
4129                                              action => "project_list")},
4130                               esc_html($part)) . " / ";
4131         }
4132 }
4133
4134 sub print_nav_breadcrumbs {
4135         my %opts = @_;
4136
4137         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4138                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4139         }
4140         if (defined $project) {
4141                 my @dirname = split '/', $project;
4142                 my $projectbasename = pop @dirname;
4143                 print_nav_breadcrumbs_path(@dirname);
4144                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4145                 if (defined $action) {
4146                         my $action_print = $action ;
4147                         if (defined $opts{-action_extra}) {
4148                                 $action_print = $cgi->a({-href => href(action=>$action)},
4149                                         $action);
4150                         }
4151                         print " / $action_print";
4152                 }
4153                 if (defined $opts{-action_extra}) {
4154                         print " / $opts{-action_extra}";
4155                 }
4156                 print "\n";
4157         } elsif (defined $project_filter) {
4158                 print_nav_breadcrumbs_path(split '/', $project_filter);
4159         }
4160 }
4161
4162 sub print_search_form {
4163         if (!defined $searchtext) {
4164                 $searchtext = "";
4165         }
4166         my $search_hash;
4167         if (defined $hash_base) {
4168                 $search_hash = $hash_base;
4169         } elsif (defined $hash) {
4170                 $search_hash = $hash;
4171         } else {
4172                 $search_hash = "HEAD";
4173         }
4174         my $action = $my_uri;
4175         my $use_pathinfo = gitweb_check_feature('pathinfo');
4176         if ($use_pathinfo) {
4177                 $action .= "/".esc_url($project);
4178         }
4179         print $cgi->start_form(-method => "get", -action => $action) .
4180               "<div class=\"search\">\n" .
4181               (!$use_pathinfo &&
4182               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4183               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4184               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4185               $cgi->popup_menu(-name => 'st', -default => 'commit',
4186                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4187               " " . $cgi->a({-href => href(action=>"search_help"),
4188                              -title => "search help" }, "?") . " search:\n",
4189               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4190               "<span title=\"Extended regular expression\">" .
4191               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4192                              -checked => $search_use_regexp) .
4193               "</span>" .
4194               "</div>" .
4195               $cgi->end_form() . "\n";
4196 }
4197
4198 sub git_header_html {
4199         my $status = shift || "200 OK";
4200         my $expires = shift;
4201         my %opts = @_;
4202
4203         my $title = get_page_title();
4204         print $cgi->header(-type=>get_content_type_html(), -charset => 'utf-8',
4205                            -status=> $status, -expires => $expires)
4206                 unless ($opts{'-no_http_header'});
4207         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4208         print <<EOF;
4209 <?xml version="1.0" encoding="utf-8"?>
4210 <!DOCTYPE html [
4211         <!ENTITY nbsp "&#xA0;">
4212         <!ENTITY sdot "&#x22C5;">
4213 ]>
4214 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4215 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4216 <!-- git core binaries version $git_version -->
4217 <head>
4218 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4219 <meta name="robots" content="index, nofollow"/>
4220 <title>$title</title>
4221 EOF
4222         # the stylesheet, favicon etc urls won't work correctly with path_info
4223         # unless we set the appropriate base URL
4224         if ($ENV{'PATH_INFO'}) {
4225                 print "<base href=\"".esc_url($base_url)."\" />\n";
4226         }
4227         print_header_links($status);
4228
4229         if (defined $site_html_head_string) {
4230                 print to_utf8($site_html_head_string);
4231         }
4232
4233         print "</head>\n" .
4234               "<body>\n";
4235
4236         if (defined $site_header && -f $site_header) {
4237                 insert_file($site_header);
4238         }
4239
4240         print "<div class=\"page_header\">\n";
4241         if (defined $logo) {
4242                 print $cgi->a({-href => esc_url($logo_url),
4243                                -title => $logo_label},
4244                               $cgi->img({-src => esc_url($logo),
4245                                          -width => 72, -height => 27,
4246                                          -alt => "git",
4247                                          -class => "logo"}));
4248         }
4249         print_nav_breadcrumbs(%opts);
4250         print "</div>\n";
4251
4252         my $have_search = gitweb_check_feature('search');
4253         if (defined $project && $have_search) {
4254                 print_search_form();
4255         }
4256 }
4257
4258 sub git_footer_html {
4259         my $feed_class = 'rss_logo';
4260
4261         print "<div class=\"page_footer\">\n";
4262         if (defined $project) {
4263                 my $descr = git_get_project_description($project);
4264                 if (defined $descr) {
4265                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4266                 }
4267
4268                 my %href_params = get_feed_info();
4269                 if (!%href_params) {
4270                         $feed_class .= ' generic';
4271                 }
4272                 $href_params{'-title'} ||= 'log';
4273
4274                 foreach my $format (qw(RSS Atom)) {
4275                         $href_params{'action'} = lc($format);
4276                         print $cgi->a({-href => href(%href_params),
4277                                       -title => "$href_params{'-title'} $format feed",
4278                                       -class => $feed_class}, $format)."\n";
4279                 }
4280
4281         } else {
4282                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4283                                              project_filter => $project_filter),
4284                               -class => $feed_class}, "OPML") . " ";
4285                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4286                                              project_filter => $project_filter),
4287                               -class => $feed_class}, "TXT") . "\n";
4288         }
4289         print "</div>\n"; # class="page_footer"
4290
4291         if (defined $t0 && gitweb_check_feature('timed')) {
4292                 print "<div id=\"generating_info\">\n";
4293                 print 'This page took '.
4294                       '<span id="generating_time" class="time_span">'.
4295                       tv_interval($t0, [ gettimeofday() ]).
4296                       ' seconds </span>'.
4297                       ' and '.
4298                       '<span id="generating_cmd">'.
4299                       $number_of_git_cmds.
4300                       '</span> git commands '.
4301                       " to generate.\n";
4302                 print "</div>\n"; # class="page_footer"
4303         }
4304
4305         if (defined $site_footer && -f $site_footer) {
4306                 insert_file($site_footer);
4307         }
4308
4309         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4310         if (defined $action &&
4311             $action eq 'blame_incremental') {
4312                 print qq!<script type="text/javascript">\n!.
4313                       qq!startBlame("!. esc_attr(href(action=>"blame_data", -replay=>1)) .qq!",\n!.
4314                       qq!           "!. esc_attr(href()) .qq!");\n!.
4315                       qq!</script>\n!;
4316         } else {
4317                 my ($jstimezone, $tz_cookie, $datetime_class) =
4318                         gitweb_get_feature('javascript-timezone');
4319
4320                 print qq!<script type="text/javascript">\n!.
4321                       qq!window.onload = function () {\n!;
4322                 if (gitweb_check_feature('javascript-actions')) {
4323                         print qq!       fixLinks();\n!;
4324                 }
4325                 if ($jstimezone && $tz_cookie && $datetime_class) {
4326                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4327                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4328                 }
4329                 print qq!};\n!.
4330                       qq!</script>\n!;
4331         }
4332
4333         print "</body>\n" .
4334               "</html>";
4335 }
4336
4337 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4338 # Example: die_error(404, 'Hash not found')
4339 # By convention, use the following status codes (as defined in RFC 2616):
4340 # 400: Invalid or missing CGI parameters, or
4341 #      requested object exists but has wrong type.
4342 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4343 #      this server or project.
4344 # 404: Requested object/revision/project doesn't exist.
4345 # 500: The server isn't configured properly, or
4346 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4347 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4348 # 503: The server is currently unavailable (because it is overloaded,
4349 #      or down for maintenance).  Generally, this is a temporary state.
4350 sub die_error {
4351         my $status = shift || 500;
4352         my $error = esc_html(shift) || "Internal Server Error";
4353         my $extra = shift;
4354         my %opts = @_;
4355
4356         my %http_responses = (
4357                 400 => '400 Bad Request',
4358                 403 => '403 Forbidden',
4359                 404 => '404 Not Found',
4360                 500 => '500 Internal Server Error',
4361                 503 => '503 Service Unavailable',
4362         );
4363         git_header_html($http_responses{$status}, undef, %opts);
4364         print <<EOF;
4365 <div class="page_body">
4366 <br /><br />
4367 $status - $error
4368 <br />
4369 EOF
4370         if (defined $extra) {
4371                 print "<hr />\n" .
4372                       "$extra\n";
4373         }
4374         print "</div>\n";
4375
4376         git_footer_html();
4377         goto DONE_GITWEB
4378                 unless ($opts{'-error_handler'});
4379 }
4380
4381 ## ----------------------------------------------------------------------
4382 ## functions printing or outputting HTML: navigation
4383
4384 sub git_print_page_nav {
4385         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4386         $extra = '' if !defined $extra; # pager or formats
4387
4388         my @navs = qw(summary shortlog log commit commitdiff tree);
4389         if ($suppress) {
4390                 @navs = grep { $_ ne $suppress } @navs;
4391         }
4392
4393         my %arg = map { $_ => {action=>$_} } @navs;
4394         if (defined $head) {
4395                 for (qw(commit commitdiff)) {
4396                         $arg{$_}{'hash'} = $head;
4397                 }
4398                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4399                         for (qw(shortlog log)) {
4400                                 $arg{$_}{'hash'} = $head;
4401                         }
4402                 }
4403         }
4404
4405         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4406         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4407
4408         my @actions = gitweb_get_feature('actions');
4409         my %repl = (
4410                 '%' => '%',
4411                 'n' => $project,         # project name
4412                 'f' => $git_dir,         # project path within filesystem
4413                 'h' => $treehead || '',  # current hash ('h' parameter)
4414                 'b' => $treebase || '',  # hash base ('hb' parameter)
4415         );
4416         while (@actions) {
4417                 my ($label, $link, $pos) = splice(@actions,0,3);
4418                 # insert
4419                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4420                 # munch munch
4421                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4422                 $arg{$label}{'_href'} = $link;
4423         }
4424
4425         print "<div class=\"page_nav\">\n" .
4426                 (join " | ",
4427                  map { $_ eq $current ?
4428                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4429                  } @navs);
4430         print "<br/>\n$extra<br/>\n" .
4431               "</div>\n";
4432 }
4433
4434 # returns a submenu for the navigation of the refs views (tags, heads,
4435 # remotes) with the current view disabled and the remotes view only
4436 # available if the feature is enabled
4437 sub format_ref_views {
4438         my ($current) = @_;
4439         my @ref_views = qw{tags heads};
4440         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4441         return join " | ", map {
4442                 $_ eq $current ? $_ :
4443                 $cgi->a({-href => href(action=>$_)}, $_)
4444         } @ref_views
4445 }
4446
4447 sub format_paging_nav {
4448         my ($action, $page, $has_next_link) = @_;
4449         my $paging_nav;
4450
4451
4452         if ($page > 0) {
4453                 $paging_nav .=
4454                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4455                         " &sdot; " .
4456                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4457                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4458         } else {
4459                 $paging_nav .= "first &sdot; prev";
4460         }
4461
4462         if ($has_next_link) {
4463                 $paging_nav .= " &sdot; " .
4464                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4465                                  -accesskey => "n", -title => "Alt-n"}, "next");
4466         } else {
4467                 $paging_nav .= " &sdot; next";
4468         }
4469
4470         return $paging_nav;
4471 }
4472
4473 ## ......................................................................
4474 ## functions printing or outputting HTML: div
4475
4476 sub git_print_header_div {
4477         my ($action, $title, $hash, $hash_base) = @_;
4478         my %args = ();
4479
4480         $args{'action'} = $action;
4481         $args{'hash'} = $hash if $hash;
4482         $args{'hash_base'} = $hash_base if $hash_base;
4483
4484         print "<div class=\"header\">\n" .
4485               $cgi->a({-href => href(%args), -class => "title"},
4486               $title ? $title : $action) .
4487               "\n</div>\n";
4488 }
4489
4490 sub format_repo_url {
4491         my ($name, $url) = @_;
4492         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4493 }
4494
4495 # Group output by placing it in a DIV element and adding a header.
4496 # Options for start_div() can be provided by passing a hash reference as the
4497 # first parameter to the function.
4498 # Options to git_print_header_div() can be provided by passing an array
4499 # reference. This must follow the options to start_div if they are present.
4500 # The content can be a scalar, which is output as-is, a scalar reference, which
4501 # is output after html escaping, an IO handle passed either as *handle or
4502 # *handle{IO}, or a function reference. In the latter case all following
4503 # parameters will be taken as argument to the content function call.
4504 sub git_print_section {
4505         my ($div_args, $header_args, $content);
4506         my $arg = shift;
4507         if (ref($arg) eq 'HASH') {
4508                 $div_args = $arg;
4509                 $arg = shift;
4510         }
4511         if (ref($arg) eq 'ARRAY') {
4512                 $header_args = $arg;
4513                 $arg = shift;
4514         }
4515         $content = $arg;
4516
4517         print $cgi->start_div($div_args);
4518         git_print_header_div(@$header_args);
4519
4520         if (ref($content) eq 'CODE') {
4521                 $content->(@_);
4522         } elsif (ref($content) eq 'SCALAR') {
4523                 print esc_html($$content);
4524         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4525                 print <$content>;
4526         } elsif (!ref($content) && defined($content)) {
4527                 print $content;
4528         }
4529
4530         print $cgi->end_div;
4531 }
4532
4533 sub format_timestamp_html {
4534         my $date = shift;
4535         my $strtime = $date->{'rfc2822'};
4536
4537         my (undef, undef, $datetime_class) =
4538                 gitweb_get_feature('javascript-timezone');
4539         if ($datetime_class) {
4540                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4541         }
4542
4543         my $localtime_format = '(%02d:%02d %s)';
4544         if ($date->{'hour_local'} < 6) {
4545                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4546         }
4547         $strtime .= ' ' .
4548                     sprintf($localtime_format,
4549                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4550
4551         return $strtime;
4552 }
4553
4554 # Outputs the author name and date in long form
4555 sub git_print_authorship {
4556         my $co = shift;
4557         my %opts = @_;
4558         my $tag = $opts{-tag} || 'div';
4559         my $author = $co->{'author_name'};
4560
4561         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4562         print "<$tag class=\"author_date\">" .
4563               format_search_author($author, "author", esc_html($author)) .
4564               " [".format_timestamp_html(\%ad)."]".
4565               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4566               "</$tag>\n";
4567 }
4568
4569 # Outputs table rows containing the full author or committer information,
4570 # in the format expected for 'commit' view (& similar).
4571 # Parameters are a commit hash reference, followed by the list of people
4572 # to output information for. If the list is empty it defaults to both
4573 # author and committer.
4574 sub git_print_authorship_rows {
4575         my $co = shift;
4576         # too bad we can't use @people = @_ || ('author', 'committer')
4577         my @people = @_;
4578         @people = ('author', 'committer') unless @people;
4579         foreach my $who (@people) {
4580                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4581                 print "<tr><td>$who</td><td>" .
4582                       format_search_author($co->{"${who}_name"}, $who,
4583                                            esc_html($co->{"${who}_name"})) . " " .
4584                       format_search_author($co->{"${who}_email"}, $who,
4585                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4586                       "</td><td rowspan=\"2\">" .
4587                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4588                       "</td></tr>\n" .
4589                       "<tr>" .
4590                       "<td></td><td>" .
4591                       format_timestamp_html(\%wd) .
4592                       "</td>" .
4593                       "</tr>\n";
4594         }
4595 }
4596
4597 sub git_print_page_path {
4598         my $name = shift;
4599         my $type = shift;
4600         my $hb = shift;
4601
4602
4603         print "<div class=\"page_path\">";
4604         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4605                       -title => 'tree root'}, to_utf8("[$project]"));
4606         print " / ";
4607         if (defined $name) {
4608                 my @dirname = split '/', $name;
4609                 my $basename = pop @dirname;
4610                 my $fullname = '';
4611
4612                 foreach my $dir (@dirname) {
4613                         $fullname .= ($fullname ? '/' : '') . $dir;
4614                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4615                                                      hash_base=>$hb),
4616                                       -title => $fullname}, esc_path($dir));
4617                         print " / ";
4618                 }
4619                 if (defined $type && $type eq 'blob') {
4620                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4621                                                      hash_base=>$hb),
4622                                       -title => $name}, esc_path($basename));
4623                 } elsif (defined $type && $type eq 'tree') {
4624                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4625                                                      hash_base=>$hb),
4626                                       -title => $name}, esc_path($basename));
4627                         print " / ";
4628                 } else {
4629                         print esc_path($basename);
4630                 }
4631         }
4632         print "<br/></div>\n";
4633 }
4634
4635 sub git_print_log {
4636         my $log = shift;
4637         my %opts = @_;
4638
4639         if ($opts{'-remove_title'}) {
4640                 # remove title, i.e. first line of log
4641                 shift @$log;
4642         }
4643         # remove leading empty lines
4644         while (defined $log->[0] && $log->[0] eq "") {
4645                 shift @$log;
4646         }
4647
4648         # print log
4649         my $skip_blank_line = 0;
4650         foreach my $line (@$log) {
4651                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-([Bb]y|[Tt]o)|C[Cc]|(Clos|Fix)es): /) {
4652                         if (! $opts{'-remove_signoff'}) {
4653                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4654                                 $skip_blank_line = 1;
4655                         }
4656                         next;
4657                 }
4658
4659                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4660                         if (! $opts{'-remove_signoff'}) {
4661                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4662                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4663                                         "</span><br/>\n";
4664                                 $skip_blank_line = 1;
4665                         }
4666                         next;
4667                 }
4668
4669                 # print only one empty line
4670                 # do not print empty line after signoff
4671                 if ($line eq "") {
4672                         next if ($skip_blank_line);
4673                         $skip_blank_line = 1;
4674                 } else {
4675                         $skip_blank_line = 0;
4676                 }
4677
4678                 print format_log_line_html($line) . "<br/>\n";
4679         }
4680
4681         if ($opts{'-final_empty_line'}) {
4682                 # end with single empty line
4683                 print "<br/>\n" unless $skip_blank_line;
4684         }
4685 }
4686
4687 # return link target (what link points to)
4688 sub git_get_link_target {
4689         my $hash = shift;
4690         my $link_target;
4691
4692         # read link
4693         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4694                 or return;
4695         {
4696                 local $/ = undef;
4697                 $link_target = <$fd>;
4698         }
4699         close $fd
4700                 or return;
4701
4702         return $link_target;
4703 }
4704
4705 # given link target, and the directory (basedir) the link is in,
4706 # return target of link relative to top directory (top tree);
4707 # return undef if it is not possible (including absolute links).
4708 sub normalize_link_target {
4709         my ($link_target, $basedir) = @_;
4710
4711         # absolute symlinks (beginning with '/') cannot be normalized
4712         return if (substr($link_target, 0, 1) eq '/');
4713
4714         # normalize link target to path from top (root) tree (dir)
4715         my $path;
4716         if ($basedir) {
4717                 $path = $basedir . '/' . $link_target;
4718         } else {
4719                 # we are in top (root) tree (dir)
4720                 $path = $link_target;
4721         }
4722
4723         # remove //, /./, and /../
4724         my @path_parts;
4725         foreach my $part (split('/', $path)) {
4726                 # discard '.' and ''
4727                 next if (!$part || $part eq '.');
4728                 # handle '..'
4729                 if ($part eq '..') {
4730                         if (@path_parts) {
4731                                 pop @path_parts;
4732                         } else {
4733                                 # link leads outside repository (outside top dir)
4734                                 return;
4735                         }
4736                 } else {
4737                         push @path_parts, $part;
4738                 }
4739         }
4740         $path = join('/', @path_parts);
4741
4742         return $path;
4743 }
4744
4745 # print tree entry (row of git_tree), but without encompassing <tr> element
4746 sub git_print_tree_entry {
4747         my ($t, $basedir, $hash_base, $have_blame) = @_;
4748
4749         my %base_key = ();
4750         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4751
4752         # The format of a table row is: mode list link.  Where mode is
4753         # the mode of the entry, list is the name of the entry, an href,
4754         # and link is the action links of the entry.
4755
4756         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4757         if (exists $t->{'size'}) {
4758                 print "<td class=\"size\">$t->{'size'}</td>\n";
4759         }
4760         if ($t->{'type'} eq "blob") {
4761                 print "<td class=\"list\">" .
4762                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4763                                                file_name=>"$basedir$t->{'name'}", %base_key),
4764                                 -class => "list"}, esc_path($t->{'name'}));
4765                 if (S_ISLNK(oct $t->{'mode'})) {
4766                         my $link_target = git_get_link_target($t->{'hash'});
4767                         if ($link_target) {
4768                                 my $norm_target = normalize_link_target($link_target, $basedir);
4769                                 if (defined $norm_target) {
4770                                         print " -> " .
4771                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4772                                                                      file_name=>$norm_target),
4773                                                        -title => $norm_target}, esc_path($link_target));
4774                                 } else {
4775                                         print " -> " . esc_path($link_target);
4776                                 }
4777                         }
4778                 }
4779                 print "</td>\n";
4780                 print "<td class=\"link\">";
4781                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4782                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4783                               "blob");
4784                 if ($have_blame) {
4785                         print " | " .
4786                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4787                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4788                                       "blame");
4789                 }
4790                 if (defined $hash_base) {
4791                         print " | " .
4792                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4793                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4794                                       "history");
4795                 }
4796                 print " | " .
4797                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4798                                                file_name=>"$basedir$t->{'name'}")},
4799                                 "raw");
4800                 print "</td>\n";
4801
4802         } elsif ($t->{'type'} eq "tree") {
4803                 print "<td class=\"list\">";
4804                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4805                                              file_name=>"$basedir$t->{'name'}",
4806                                              %base_key)},
4807                               esc_path($t->{'name'}));
4808                 print "</td>\n";
4809                 print "<td class=\"link\">";
4810                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4811                                              file_name=>"$basedir$t->{'name'}",
4812                                              %base_key)},
4813                               "tree");
4814                 if (defined $hash_base) {
4815                         print " | " .
4816                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4817                                                      file_name=>"$basedir$t->{'name'}")},
4818                                       "history");
4819                 }
4820                 print "</td>\n";
4821         } else {
4822                 # unknown object: we can only present history for it
4823                 # (this includes 'commit' object, i.e. submodule support)
4824                 print "<td class=\"list\">" .
4825                       esc_path($t->{'name'}) .
4826                       "</td>\n";
4827                 print "<td class=\"link\">";
4828                 if (defined $hash_base) {
4829                         print $cgi->a({-href => href(action=>"history",
4830                                                      hash_base=>$hash_base,
4831                                                      file_name=>"$basedir$t->{'name'}")},
4832                                       "history");
4833                 }
4834                 print "</td>\n";
4835         }
4836 }
4837
4838 ## ......................................................................
4839 ## functions printing large fragments of HTML
4840
4841 # get pre-image filenames for merge (combined) diff
4842 sub fill_from_file_info {
4843         my ($diff, @parents) = @_;
4844
4845         $diff->{'from_file'} = [ ];
4846         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4847         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4848                 if ($diff->{'status'}[$i] eq 'R' ||
4849                     $diff->{'status'}[$i] eq 'C') {
4850                         $diff->{'from_file'}[$i] =
4851                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4852                 }
4853         }
4854
4855         return $diff;
4856 }
4857
4858 # is current raw difftree line of file deletion
4859 sub is_deleted {
4860         my $diffinfo = shift;
4861
4862         return $diffinfo->{'to_id'} eq ('0' x 40) || $diffinfo->{'to_id'} eq ('0' x 64);
4863 }
4864
4865 # does patch correspond to [previous] difftree raw line
4866 # $diffinfo  - hashref of parsed raw diff format
4867 # $patchinfo - hashref of parsed patch diff format
4868 #              (the same keys as in $diffinfo)
4869 sub is_patch_split {
4870         my ($diffinfo, $patchinfo) = @_;
4871
4872         return defined $diffinfo && defined $patchinfo
4873                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4874 }
4875
4876
4877 sub git_difftree_body {
4878         my ($difftree, $hash, @parents) = @_;
4879         my ($parent) = $parents[0];
4880         my $have_blame = gitweb_check_feature('blame');
4881         print "<div class=\"list_head\">\n";
4882         if ($#{$difftree} > 10) {
4883                 print(($#{$difftree} + 1) . " files changed:\n");
4884         }
4885         print "</div>\n";
4886
4887         print "<table class=\"" .
4888               (@parents > 1 ? "combined " : "") .
4889               "diff_tree\">\n";
4890
4891         # header only for combined diff in 'commitdiff' view
4892         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4893         if ($has_header) {
4894                 # table header
4895                 print "<thead><tr>\n" .
4896                        "<th></th><th></th>\n"; # filename, patchN link
4897                 for (my $i = 0; $i < @parents; $i++) {
4898                         my $par = $parents[$i];
4899                         print "<th>" .
4900                               $cgi->a({-href => href(action=>"commitdiff",
4901                                                      hash=>$hash, hash_parent=>$par),
4902                                        -title => 'commitdiff to parent number ' .
4903                                                   ($i+1) . ': ' . substr($par,0,7)},
4904                                       $i+1) .
4905                               "&nbsp;</th>\n";
4906                 }
4907                 print "</tr></thead>\n<tbody>\n";
4908         }
4909
4910         my $alternate = 1;
4911         my $patchno = 0;
4912         foreach my $line (@{$difftree}) {
4913                 my $diff = parsed_difftree_line($line);
4914
4915                 if ($alternate) {
4916                         print "<tr class=\"dark\">\n";
4917                 } else {
4918                         print "<tr class=\"light\">\n";
4919                 }
4920                 $alternate ^= 1;
4921
4922                 if (exists $diff->{'nparents'}) { # combined diff
4923
4924                         fill_from_file_info($diff, @parents)
4925                                 unless exists $diff->{'from_file'};
4926
4927                         if (!is_deleted($diff)) {
4928                                 # file exists in the result (child) commit
4929                                 print "<td>" .
4930                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4931                                                              file_name=>$diff->{'to_file'},
4932                                                              hash_base=>$hash),
4933                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4934                                       "</td>\n";
4935                         } else {
4936                                 print "<td>" .
4937                                       esc_path($diff->{'to_file'}) .
4938                                       "</td>\n";
4939                         }
4940
4941                         if ($action eq 'commitdiff') {
4942                                 # link to patch
4943                                 $patchno++;
4944                                 print "<td class=\"link\">" .
4945                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4946                                               "patch") .
4947                                       " | " .
4948                                       "</td>\n";
4949                         }
4950
4951                         my $has_history = 0;
4952                         my $not_deleted = 0;
4953                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4954                                 my $hash_parent = $parents[$i];
4955                                 my $from_hash = $diff->{'from_id'}[$i];
4956                                 my $from_path = $diff->{'from_file'}[$i];
4957                                 my $status = $diff->{'status'}[$i];
4958
4959                                 $has_history ||= ($status ne 'A');
4960                                 $not_deleted ||= ($status ne 'D');
4961
4962                                 if ($status eq 'A') {
4963                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4964                                 } elsif ($status eq 'D') {
4965                                         print "<td class=\"link\">" .
4966                                               $cgi->a({-href => href(action=>"blob",
4967                                                                      hash_base=>$hash,
4968                                                                      hash=>$from_hash,
4969                                                                      file_name=>$from_path)},
4970                                                       "blob" . ($i+1)) .
4971                                               " | </td>\n";
4972                                 } else {
4973                                         if ($diff->{'to_id'} eq $from_hash) {
4974                                                 print "<td class=\"link nochange\">";
4975                                         } else {
4976                                                 print "<td class=\"link\">";
4977                                         }
4978                                         print $cgi->a({-href => href(action=>"blobdiff",
4979                                                                      hash=>$diff->{'to_id'},
4980                                                                      hash_parent=>$from_hash,
4981                                                                      hash_base=>$hash,
4982                                                                      hash_parent_base=>$hash_parent,
4983                                                                      file_name=>$diff->{'to_file'},
4984                                                                      file_parent=>$from_path)},
4985                                                       "diff" . ($i+1)) .
4986                                               " | </td>\n";
4987                                 }
4988                         }
4989
4990                         print "<td class=\"link\">";
4991                         if ($not_deleted) {
4992                                 print $cgi->a({-href => href(action=>"blob",
4993                                                              hash=>$diff->{'to_id'},
4994                                                              file_name=>$diff->{'to_file'},
4995                                                              hash_base=>$hash)},
4996                                               "blob");
4997                                 print " | " if ($has_history);
4998                         }
4999                         if ($has_history) {
5000                                 print $cgi->a({-href => href(action=>"history",
5001                                                              file_name=>$diff->{'to_file'},
5002                                                              hash_base=>$hash)},
5003                                               "history");
5004                         }
5005                         print "</td>\n";
5006
5007                         print "</tr>\n";
5008                         next; # instead of 'else' clause, to avoid extra indent
5009                 }
5010                 # else ordinary diff
5011
5012                 my ($to_mode_oct, $to_mode_str, $to_file_type);
5013                 my ($from_mode_oct, $from_mode_str, $from_file_type);
5014                 if ($diff->{'to_mode'} ne ('0' x 6)) {
5015                         $to_mode_oct = oct $diff->{'to_mode'};
5016                         if (S_ISREG($to_mode_oct)) { # only for regular file
5017                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
5018                         }
5019                         $to_file_type = file_type($diff->{'to_mode'});
5020                 }
5021                 if ($diff->{'from_mode'} ne ('0' x 6)) {
5022                         $from_mode_oct = oct $diff->{'from_mode'};
5023                         if (S_ISREG($from_mode_oct)) { # only for regular file
5024                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
5025                         }
5026                         $from_file_type = file_type($diff->{'from_mode'});
5027                 }
5028
5029                 if ($diff->{'status'} eq "A") { # created
5030                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
5031                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
5032                         $mode_chng   .= "]</span>";
5033                         print "<td>";
5034                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5035                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5036                                       -class => "list"}, esc_path($diff->{'file'}));
5037                         print "</td>\n";
5038                         print "<td>$mode_chng</td>\n";
5039                         print "<td class=\"link\">";
5040                         if ($action eq 'commitdiff') {
5041                                 # link to patch
5042                                 $patchno++;
5043                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5044                                               "patch") .
5045                                       " | ";
5046                         }
5047                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5048                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5049                                       "blob");
5050                         print "</td>\n";
5051
5052                 } elsif ($diff->{'status'} eq "D") { # deleted
5053                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5054                         print "<td>";
5055                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5056                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5057                                        -class => "list"}, esc_path($diff->{'file'}));
5058                         print "</td>\n";
5059                         print "<td>$mode_chng</td>\n";
5060                         print "<td class=\"link\">";
5061                         if ($action eq 'commitdiff') {
5062                                 # link to patch
5063                                 $patchno++;
5064                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5065                                               "patch") .
5066                                       " | ";
5067                         }
5068                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5069                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5070                                       "blob") . " | ";
5071                         if ($have_blame) {
5072                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5073                                                              file_name=>$diff->{'file'})},
5074                                               "blame") . " | ";
5075                         }
5076                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5077                                                      file_name=>$diff->{'file'})},
5078                                       "history");
5079                         print "</td>\n";
5080
5081                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5082                         my $mode_chnge = "";
5083                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5084                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5085                                 if ($from_file_type ne $to_file_type) {
5086                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5087                                 }
5088                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5089                                         if ($from_mode_str && $to_mode_str) {
5090                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5091                                         } elsif ($to_mode_str) {
5092                                                 $mode_chnge .= " mode: $to_mode_str";
5093                                         }
5094                                 }
5095                                 $mode_chnge .= "]</span>\n";
5096                         }
5097                         print "<td>";
5098                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5099                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5100                                       -class => "list"}, esc_path($diff->{'file'}));
5101                         print "</td>\n";
5102                         print "<td>$mode_chnge</td>\n";
5103                         print "<td class=\"link\">";
5104                         if ($action eq 'commitdiff') {
5105                                 # link to patch
5106                                 $patchno++;
5107                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5108                                               "patch") .
5109                                       " | ";
5110                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5111                                 # "commit" view and modified file (not onlu mode changed)
5112                                 print $cgi->a({-href => href(action=>"blobdiff",
5113                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5114                                                              hash_base=>$hash, hash_parent_base=>$parent,
5115                                                              file_name=>$diff->{'file'})},
5116                                               "diff") .
5117                                       " | ";
5118                         }
5119                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5120                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5121                                        "blob") . " | ";
5122                         if ($have_blame) {
5123                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5124                                                              file_name=>$diff->{'file'})},
5125                                               "blame") . " | ";
5126                         }
5127                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5128                                                      file_name=>$diff->{'file'})},
5129                                       "history");
5130                         print "</td>\n";
5131
5132                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5133                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5134                         my $nstatus = $status_name{$diff->{'status'}};
5135                         my $mode_chng = "";
5136                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5137                                 # mode also for directories, so we cannot use $to_mode_str
5138                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5139                         }
5140                         print "<td>" .
5141                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5142                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5143                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5144                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5145                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5146                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5147                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5148                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5149                               "<td class=\"link\">";
5150                         if ($action eq 'commitdiff') {
5151                                 # link to patch
5152                                 $patchno++;
5153                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5154                                               "patch") .
5155                                       " | ";
5156                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5157                                 # "commit" view and modified file (not only pure rename or copy)
5158                                 print $cgi->a({-href => href(action=>"blobdiff",
5159                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5160                                                              hash_base=>$hash, hash_parent_base=>$parent,
5161                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5162                                               "diff") .
5163                                       " | ";
5164                         }
5165                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5166                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5167                                       "blob") . " | ";
5168                         if ($have_blame) {
5169                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5170                                                              file_name=>$diff->{'to_file'})},
5171                                               "blame") . " | ";
5172                         }
5173                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5174                                                     file_name=>$diff->{'to_file'})},
5175                                       "history");
5176                         print "</td>\n";
5177
5178                 } # we should not encounter Unmerged (U) or Unknown (X) status
5179                 print "</tr>\n";
5180         }
5181         print "</tbody>" if $has_header;
5182         print "</table>\n";
5183 }
5184
5185 # Print context lines and then rem/add lines in a side-by-side manner.
5186 sub print_sidebyside_diff_lines {
5187         my ($ctx, $rem, $add) = @_;
5188
5189         # print context block before add/rem block
5190         if (@$ctx) {
5191                 print join '',
5192                         '<div class="chunk_block ctx">',
5193                                 '<div class="old">',
5194                                 @$ctx,
5195                                 '</div>',
5196                                 '<div class="new">',
5197                                 @$ctx,
5198                                 '</div>',
5199                         '</div>';
5200         }
5201
5202         if (!@$add) {
5203                 # pure removal
5204                 print join '',
5205                         '<div class="chunk_block rem">',
5206                                 '<div class="old">',
5207                                 @$rem,
5208                                 '</div>',
5209                         '</div>';
5210         } elsif (!@$rem) {
5211                 # pure addition
5212                 print join '',
5213                         '<div class="chunk_block add">',
5214                                 '<div class="new">',
5215                                 @$add,
5216                                 '</div>',
5217                         '</div>';
5218         } else {
5219                 print join '',
5220                         '<div class="chunk_block chg">',
5221                                 '<div class="old">',
5222                                 @$rem,
5223                                 '</div>',
5224                                 '<div class="new">',
5225                                 @$add,
5226                                 '</div>',
5227                         '</div>';
5228         }
5229 }
5230
5231 # Print context lines and then rem/add lines in inline manner.
5232 sub print_inline_diff_lines {
5233         my ($ctx, $rem, $add) = @_;
5234
5235         print @$ctx, @$rem, @$add;
5236 }
5237
5238 # Format removed and added line, mark changed part and HTML-format them.
5239 # Implementation is based on contrib/diff-highlight
5240 sub format_rem_add_lines_pair {
5241         my ($rem, $add, $num_parents) = @_;
5242
5243         # We need to untabify lines before split()'ing them;
5244         # otherwise offsets would be invalid.
5245         chomp $rem;
5246         chomp $add;
5247         $rem = untabify($rem);
5248         $add = untabify($add);
5249
5250         my @rem = split(//, $rem);
5251         my @add = split(//, $add);
5252         my ($esc_rem, $esc_add);
5253         # Ignore leading +/- characters for each parent.
5254         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5255         my ($prefix_has_nonspace, $suffix_has_nonspace);
5256
5257         my $shorter = (@rem < @add) ? @rem : @add;
5258         while ($prefix_len < $shorter) {
5259                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5260
5261                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5262                 $prefix_len++;
5263         }
5264
5265         while ($prefix_len + $suffix_len < $shorter) {
5266                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5267
5268                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5269                 $suffix_len++;
5270         }
5271
5272         # Mark lines that are different from each other, but have some common
5273         # part that isn't whitespace.  If lines are completely different, don't
5274         # mark them because that would make output unreadable, especially if
5275         # diff consists of multiple lines.
5276         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5277                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5278                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5279                 $esc_add = esc_html_hl_regions($add, 'marked',
5280                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5281         } else {
5282                 $esc_rem = esc_html($rem, -nbsp=>1);
5283                 $esc_add = esc_html($add, -nbsp=>1);
5284         }
5285
5286         return format_diff_line(\$esc_rem, 'rem'),
5287                format_diff_line(\$esc_add, 'add');
5288 }
5289
5290 # HTML-format diff context, removed and added lines.
5291 sub format_ctx_rem_add_lines {
5292         my ($ctx, $rem, $add, $num_parents) = @_;
5293         my (@new_ctx, @new_rem, @new_add);
5294         my $can_highlight = 0;
5295         my $is_combined = ($num_parents > 1);
5296
5297         # Highlight if every removed line has a corresponding added line.
5298         if (@$add > 0 && @$add == @$rem) {
5299                 $can_highlight = 1;
5300
5301                 # Highlight lines in combined diff only if the chunk contains
5302                 # diff between the same version, e.g.
5303                 #
5304                 #    - a
5305                 #   -  b
5306                 #    + c
5307                 #   +  d
5308                 #
5309                 # Otherwise the highlighting would be confusing.
5310                 if ($is_combined) {
5311                         for (my $i = 0; $i < @$add; $i++) {
5312                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5313                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5314
5315                                 $prefix_rem =~ s/-/+/g;
5316
5317                                 if ($prefix_rem ne $prefix_add) {
5318                                         $can_highlight = 0;
5319                                         last;
5320                                 }
5321                         }
5322                 }
5323         }
5324
5325         if ($can_highlight) {
5326                 for (my $i = 0; $i < @$add; $i++) {
5327                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5328                                 $rem->[$i], $add->[$i], $num_parents);
5329                         push @new_rem, $line_rem;
5330                         push @new_add, $line_add;
5331                 }
5332         } else {
5333                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5334                 @new_add = map { format_diff_line($_, 'add') } @$add;
5335         }
5336
5337         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5338
5339         return (\@new_ctx, \@new_rem, \@new_add);
5340 }
5341
5342 # Print context lines and then rem/add lines.
5343 sub print_diff_lines {
5344         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5345         my $is_combined = $num_parents > 1;
5346
5347         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5348                 $num_parents);
5349
5350         if ($diff_style eq 'sidebyside' && !$is_combined) {
5351                 print_sidebyside_diff_lines($ctx, $rem, $add);
5352         } else {
5353                 # default 'inline' style and unknown styles
5354                 print_inline_diff_lines($ctx, $rem, $add);
5355         }
5356 }
5357
5358 sub print_diff_chunk {
5359         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5360         my (@ctx, @rem, @add);
5361
5362         # The class of the previous line.
5363         my $prev_class = '';
5364
5365         return unless @chunk;
5366
5367         # incomplete last line might be among removed or added lines,
5368         # or both, or among context lines: find which
5369         for (my $i = 1; $i < @chunk; $i++) {
5370                 if ($chunk[$i][0] eq 'incomplete') {
5371                         $chunk[$i][0] = $chunk[$i-1][0];
5372                 }
5373         }
5374
5375         # guardian
5376         push @chunk, ["", ""];
5377
5378         foreach my $line_info (@chunk) {
5379                 my ($class, $line) = @$line_info;
5380
5381                 # print chunk headers
5382                 if ($class && $class eq 'chunk_header') {
5383                         print format_diff_line($line, $class, $from, $to);
5384                         next;
5385                 }
5386
5387                 ## print from accumulator when have some add/rem lines or end
5388                 # of chunk (flush context lines), or when have add and rem
5389                 # lines and new block is reached (otherwise add/rem lines could
5390                 # be reordered)
5391                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5392                     (@rem && @add && $class ne $prev_class)) {
5393                         print_diff_lines(\@ctx, \@rem, \@add,
5394                                          $diff_style, $num_parents);
5395                         @ctx = @rem = @add = ();
5396                 }
5397
5398                 ## adding lines to accumulator
5399                 # guardian value
5400                 last unless $line;
5401                 # rem, add or change
5402                 if ($class eq 'rem') {
5403                         push @rem, $line;
5404                 } elsif ($class eq 'add') {
5405                         push @add, $line;
5406                 }
5407                 # context line
5408                 if ($class eq 'ctx') {
5409                         push @ctx, $line;
5410                 }
5411
5412                 $prev_class = $class;
5413         }
5414 }
5415
5416 sub git_patchset_body {
5417         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5418         my ($hash_parent) = $hash_parents[0];
5419
5420         my $is_combined = (@hash_parents > 1);
5421         my $patch_idx = 0;
5422         my $patch_number = 0;
5423         my $patch_line;
5424         my $diffinfo;
5425         my $to_name;
5426         my (%from, %to);
5427         my @chunk; # for side-by-side diff
5428
5429         print "<div class=\"patchset\">\n";
5430
5431         # skip to first patch
5432         while ($patch_line = <$fd>) {
5433                 chomp $patch_line;
5434
5435                 last if ($patch_line =~ m/^diff /);
5436         }
5437
5438  PATCH:
5439         while ($patch_line) {
5440
5441                 # parse "git diff" header line
5442                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5443                         # $1 is from_name, which we do not use
5444                         $to_name = unquote($2);
5445                         $to_name =~ s!^b/!!;
5446                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5447                         # $1 is 'cc' or 'combined', which we do not use
5448                         $to_name = unquote($2);
5449                 } else {
5450                         $to_name = undef;
5451                 }
5452
5453                 # check if current patch belong to current raw line
5454                 # and parse raw git-diff line if needed
5455                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5456                         # this is continuation of a split patch
5457                         print "<div class=\"patch cont\">\n";
5458                 } else {
5459                         # advance raw git-diff output if needed
5460                         $patch_idx++ if defined $diffinfo;
5461
5462                         # read and prepare patch information
5463                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5464
5465                         # compact combined diff output can have some patches skipped
5466                         # find which patch (using pathname of result) we are at now;
5467                         if ($is_combined) {
5468                                 while ($to_name ne $diffinfo->{'to_file'}) {
5469                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5470                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5471                                               "</div>\n";  # class="patch"
5472
5473                                         $patch_idx++;
5474                                         $patch_number++;
5475
5476                                         last if $patch_idx > $#$difftree;
5477                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5478                                 }
5479                         }
5480
5481                         # modifies %from, %to hashes
5482                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5483
5484                         # this is first patch for raw difftree line with $patch_idx index
5485                         # we index @$difftree array from 0, but number patches from 1
5486                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5487                 }
5488
5489                 # git diff header
5490                 #assert($patch_line =~ m/^diff /) if DEBUG;
5491                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5492                 $patch_number++;
5493                 # print "git diff" header
5494                 print format_git_diff_header_line($patch_line, $diffinfo,
5495                                                   \%from, \%to);
5496
5497                 # print extended diff header
5498                 print "<div class=\"diff extended_header\">\n";
5499         EXTENDED_HEADER:
5500                 while ($patch_line = <$fd>) {
5501                         chomp $patch_line;
5502
5503                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5504
5505                         print format_extended_diff_header_line($patch_line, $diffinfo,
5506                                                                \%from, \%to);
5507                 }
5508                 print "</div>\n"; # class="diff extended_header"
5509
5510                 # from-file/to-file diff header
5511                 if (! $patch_line) {
5512                         print "</div>\n"; # class="patch"
5513                         last PATCH;
5514                 }
5515                 next PATCH if ($patch_line =~ m/^diff /);
5516                 #assert($patch_line =~ m/^---/) if DEBUG;
5517
5518                 my $last_patch_line = $patch_line;
5519                 $patch_line = <$fd>;
5520                 chomp $patch_line;
5521                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5522
5523                 print format_diff_from_to_header($last_patch_line, $patch_line,
5524                                                  $diffinfo, \%from, \%to,
5525                                                  @hash_parents);
5526
5527                 # the patch itself
5528         LINE:
5529                 while ($patch_line = <$fd>) {
5530                         chomp $patch_line;
5531
5532                         next PATCH if ($patch_line =~ m/^diff /);
5533
5534                         my $class = diff_line_class($patch_line, \%from, \%to);
5535
5536                         if ($class eq 'chunk_header') {
5537                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5538                                 @chunk = ();
5539                         }
5540
5541                         push @chunk, [ $class, $patch_line ];
5542                 }
5543
5544         } continue {
5545                 if (@chunk) {
5546                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5547                         @chunk = ();
5548                 }
5549                 print "</div>\n"; # class="patch"
5550         }
5551
5552         # for compact combined (--cc) format, with chunk and patch simplification
5553         # the patchset might be empty, but there might be unprocessed raw lines
5554         for (++$patch_idx if $patch_number > 0;
5555              $patch_idx < @$difftree;
5556              ++$patch_idx) {
5557                 # read and prepare patch information
5558                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5559
5560                 # generate anchor for "patch" links in difftree / whatchanged part
5561                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5562                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5563                       "</div>\n";  # class="patch"
5564
5565                 $patch_number++;
5566         }
5567
5568         if ($patch_number == 0) {
5569                 if (@hash_parents > 1) {
5570                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5571                 } else {
5572                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5573                 }
5574         }
5575
5576         print "</div>\n"; # class="patchset"
5577 }
5578
5579 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5580
5581 sub git_project_search_form {
5582         my ($searchtext, $search_use_regexp) = @_;
5583
5584         my $limit = '';
5585         if ($project_filter) {
5586                 $limit = " in '$project_filter/'";
5587         }
5588
5589         print "<div class=\"projsearch\">\n";
5590         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5591               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5592         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5593                 if (defined $project_filter);
5594         print $cgi->textfield(-name => 's', -value => $searchtext,
5595                               -title => "Search project by name and description$limit",
5596                               -size => 60) . "\n" .
5597               "<span title=\"Extended regular expression\">" .
5598               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5599                              -checked => $search_use_regexp) .
5600               "</span>\n" .
5601               $cgi->submit(-name => 'btnS', -value => 'Search') .
5602               $cgi->end_form() . "\n" .
5603               $cgi->a({-href => href(project => undef, searchtext => undef,
5604                                      project_filter => $project_filter)},
5605                       esc_html("List all projects$limit")) . "<br />\n";
5606         print "</div>\n";
5607 }
5608
5609 # entry for given @keys needs filling if at least one of keys in list
5610 # is not present in %$project_info
5611 sub project_info_needs_filling {
5612         my ($project_info, @keys) = @_;
5613
5614         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5615         foreach my $key (@keys) {
5616                 if (!exists $project_info->{$key}) {
5617                         return 1;
5618                 }
5619         }
5620         return;
5621 }
5622
5623 # fills project list info (age, description, owner, category, forks, etc.)
5624 # for each project in the list, removing invalid projects from
5625 # returned list, or fill only specified info.
5626 #
5627 # Invalid projects are removed from the returned list if and only if you
5628 # ask 'age' or 'age_string' to be filled, because they are the only fields
5629 # that run unconditionally git command that requires repository, and
5630 # therefore do always check if project repository is invalid.
5631 #
5632 # USAGE:
5633 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5634 #   ensures that 'descr_long' and 'ctags' fields are filled
5635 # * @project_list = fill_project_list_info(\@project_list)
5636 #   ensures that all fields are filled (and invalid projects removed)
5637 #
5638 # NOTE: modifies $projlist, but does not remove entries from it
5639 sub fill_project_list_info {
5640         my ($projlist, @wanted_keys) = @_;
5641         my @projects;
5642         my $filter_set = sub { return @_; };
5643         if (@wanted_keys) {
5644                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5645                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5646         }
5647
5648         my $show_ctags = gitweb_check_feature('ctags');
5649  PROJECT:
5650         foreach my $pr (@$projlist) {
5651                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5652                         my (@activity) = git_get_last_activity($pr->{'path'});
5653                         unless (@activity) {
5654                                 next PROJECT;
5655                         }
5656                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5657                 }
5658                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5659                         my $descr = git_get_project_description($pr->{'path'}) || "";
5660                         $descr = to_utf8($descr);
5661                         $pr->{'descr_long'} = $descr;
5662                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5663                 }
5664                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5665                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5666                 }
5667                 if ($show_ctags &&
5668                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5669                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5670                 }
5671                 if ($projects_list_group_categories &&
5672                     project_info_needs_filling($pr, $filter_set->('category'))) {
5673                         my $cat = git_get_project_category($pr->{'path'}) ||
5674                                                            $project_list_default_category;
5675                         $pr->{'category'} = to_utf8($cat);
5676                 }
5677
5678                 push @projects, $pr;
5679         }
5680
5681         return @projects;
5682 }
5683
5684 sub sort_projects_list {
5685         my ($projlist, $order) = @_;
5686
5687         sub order_str {
5688                 my $key = shift;
5689                 return sub { $a->{$key} cmp $b->{$key} };
5690         }
5691
5692         sub order_num_then_undef {
5693                 my $key = shift;
5694                 return sub {
5695                         defined $a->{$key} ?
5696                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5697                                 (defined $b->{$key} ? 1 : 0)
5698                 };
5699         }
5700
5701         my %orderings = (
5702                 project => order_str('path'),
5703                 descr => order_str('descr_long'),
5704                 owner => order_str('owner'),
5705                 age => order_num_then_undef('age'),
5706         );
5707
5708         my $ordering = $orderings{$order};
5709         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5710 }
5711
5712 # returns a hash of categories, containing the list of project
5713 # belonging to each category
5714 sub build_projlist_by_category {
5715         my ($projlist, $from, $to) = @_;
5716         my %categories;
5717
5718         $from = 0 unless defined $from;
5719         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5720
5721         for (my $i = $from; $i <= $to; $i++) {
5722                 my $pr = $projlist->[$i];
5723                 push @{$categories{ $pr->{'category'} }}, $pr;
5724         }
5725
5726         return wantarray ? %categories : \%categories;
5727 }
5728
5729 # print 'sort by' <th> element, generating 'sort by $name' replay link
5730 # if that order is not selected
5731 sub print_sort_th {
5732         print format_sort_th(@_);
5733 }
5734
5735 sub format_sort_th {
5736         my ($name, $order, $header) = @_;
5737         my $sort_th = "";
5738         $header ||= ucfirst($name);
5739
5740         if ($order eq $name) {
5741                 $sort_th .= "<th>$header</th>\n";
5742         } else {
5743                 $sort_th .= "<th>" .
5744                             $cgi->a({-href => href(-replay=>1, order=>$name),
5745                                      -class => "header"}, $header) .
5746                             "</th>\n";
5747         }
5748
5749         return $sort_th;
5750 }
5751
5752 sub git_project_list_rows {
5753         my ($projlist, $from, $to, $check_forks) = @_;
5754
5755         $from = 0 unless defined $from;
5756         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5757
5758         my $alternate = 1;
5759         for (my $i = $from; $i <= $to; $i++) {
5760                 my $pr = $projlist->[$i];
5761
5762                 if ($alternate) {
5763                         print "<tr class=\"dark\">\n";
5764                 } else {
5765                         print "<tr class=\"light\">\n";
5766                 }
5767                 $alternate ^= 1;
5768
5769                 if ($check_forks) {
5770                         print "<td>";
5771                         if ($pr->{'forks'}) {
5772                                 my $nforks = scalar @{$pr->{'forks'}};
5773                                 if ($nforks > 0) {
5774                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5775                                                        -title => "$nforks forks"}, "+");
5776                                 } else {
5777                                         print $cgi->span({-title => "$nforks forks"}, "+");
5778                                 }
5779                         }
5780                         print "</td>\n";
5781                 }
5782                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5783                                         -class => "list"},
5784                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5785                       "</td>\n" .
5786                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5787                                         -class => "list",
5788                                         -title => $pr->{'descr_long'}},
5789                                         $search_regexp
5790                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5791                                                                     $pr->{'descr'}, $search_regexp)
5792                                         : esc_html($pr->{'descr'})) .
5793                       "</td>\n";
5794                 unless ($omit_owner) {
5795                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5796                 }
5797                 unless ($omit_age_column) {
5798                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5799                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5800                 }
5801                 print"<td class=\"link\">" .
5802                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5803                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5804                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5805                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5806                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5807                       "</td>\n" .
5808                       "</tr>\n";
5809         }
5810 }
5811
5812 sub git_project_list_body {
5813         # actually uses global variable $project
5814         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5815         my @projects = @$projlist;
5816
5817         my $check_forks = gitweb_check_feature('forks');
5818         my $show_ctags  = gitweb_check_feature('ctags');
5819         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5820         $check_forks = undef
5821                 if ($tagfilter || $search_regexp);
5822
5823         # filtering out forks before filling info allows to do less work
5824         @projects = filter_forks_from_projects_list(\@projects)
5825                 if ($check_forks);
5826         # search_projects_list pre-fills required info
5827         @projects = search_projects_list(\@projects,
5828                                          'search_regexp' => $search_regexp,
5829                                          'tagfilter'  => $tagfilter)
5830                 if ($tagfilter || $search_regexp);
5831         # fill the rest
5832         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5833         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5834         push @all_fields, 'owner' unless($omit_owner);
5835         @projects = fill_project_list_info(\@projects, @all_fields);
5836
5837         $order ||= $default_projects_order;
5838         $from = 0 unless defined $from;
5839         $to = $#projects if (!defined $to || $#projects < $to);
5840
5841         # short circuit
5842         if ($from > $to) {
5843                 print "<center>\n".
5844                       "<b>No such projects found</b><br />\n".
5845                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5846                       "</center>\n<br />\n";
5847                 return;
5848         }
5849
5850         @projects = sort_projects_list(\@projects, $order);
5851
5852         if ($show_ctags) {
5853                 my $ctags = git_gather_all_ctags(\@projects);
5854                 my $cloud = git_populate_project_tagcloud($ctags);
5855                 print git_show_project_tagcloud($cloud, 64);
5856         }
5857
5858         print "<table class=\"project_list\">\n";
5859         unless ($no_header) {
5860                 print "<tr>\n";
5861                 if ($check_forks) {
5862                         print "<th></th>\n";
5863                 }
5864                 print_sort_th('project', $order, 'Project');
5865                 print_sort_th('descr', $order, 'Description');
5866                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5867                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5868                 print "<th></th>\n" . # for links
5869                       "</tr>\n";
5870         }
5871
5872         if ($projects_list_group_categories) {
5873                 # only display categories with projects in the $from-$to window
5874                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5875                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5876                 foreach my $cat (sort keys %categories) {
5877                         unless ($cat eq "") {
5878                                 print "<tr>\n";
5879                                 if ($check_forks) {
5880                                         print "<td></td>\n";
5881                                 }
5882                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5883                                 print "</tr>\n";
5884                         }
5885
5886                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5887                 }
5888         } else {
5889                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5890         }
5891
5892         if (defined $extra) {
5893                 print "<tr>\n";
5894                 if ($check_forks) {
5895                         print "<td></td>\n";
5896                 }
5897                 print "<td colspan=\"5\">$extra</td>\n" .
5898                       "</tr>\n";
5899         }
5900         print "</table>\n";
5901 }
5902
5903 sub git_log_body {
5904         # uses global variable $project
5905         my ($commitlist, $from, $to, $refs, $extra) = @_;
5906
5907         $from = 0 unless defined $from;
5908         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5909
5910         for (my $i = 0; $i <= $to; $i++) {
5911                 my %co = %{$commitlist->[$i]};
5912                 next if !%co;
5913                 my $commit = $co{'id'};
5914                 my $ref = format_ref_marker($refs, $commit);
5915                 git_print_header_div('commit',
5916                                "<span class=\"age\">$co{'age_string'}</span>" .
5917                                esc_html($co{'title'}) . $ref,
5918                                $commit);
5919                 print "<div class=\"title_text\">\n" .
5920                       "<div class=\"log_link\">\n" .
5921                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5922                       " | " .
5923                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5924                       " | " .
5925                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5926                       "<br/>\n" .
5927                       "</div>\n";
5928                       git_print_authorship(\%co, -tag => 'span');
5929                       print "<br/>\n</div>\n";
5930
5931                 print "<div class=\"log_body\">\n";
5932                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5933                 print "</div>\n";
5934         }
5935         if ($extra) {
5936                 print "<div class=\"page_nav\">\n";
5937                 print "$extra\n";
5938                 print "</div>\n";
5939         }
5940 }
5941
5942 sub git_shortlog_body {
5943         # uses global variable $project
5944         my ($commitlist, $from, $to, $refs, $extra) = @_;
5945
5946         $from = 0 unless defined $from;
5947         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5948
5949         print "<table class=\"shortlog\">\n";
5950         my $alternate = 1;
5951         for (my $i = $from; $i <= $to; $i++) {
5952                 my %co = %{$commitlist->[$i]};
5953                 my $commit = $co{'id'};
5954                 my $ref = format_ref_marker($refs, $commit);
5955                 if ($alternate) {
5956                         print "<tr class=\"dark\">\n";
5957                 } else {
5958                         print "<tr class=\"light\">\n";
5959                 }
5960                 $alternate ^= 1;
5961                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5962                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5963                       format_author_html('td', \%co, 10) . "<td>";
5964                 print format_subject_html($co{'title'}, $co{'title_short'},
5965                                           href(action=>"commit", hash=>$commit), $ref);
5966                 print "</td>\n" .
5967                       "<td class=\"link\">" .
5968                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5969                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5970                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5971                 my $snapshot_links = format_snapshot_links($commit);
5972                 if (defined $snapshot_links) {
5973                         print " | " . $snapshot_links;
5974                 }
5975                 print "</td>\n" .
5976                       "</tr>\n";
5977         }
5978         if (defined $extra) {
5979                 print "<tr>\n" .
5980                       "<td colspan=\"4\">$extra</td>\n" .
5981                       "</tr>\n";
5982         }
5983         print "</table>\n";
5984 }
5985
5986 sub git_history_body {
5987         # Warning: assumes constant type (blob or tree) during history
5988         my ($commitlist, $from, $to, $refs, $extra,
5989             $file_name, $file_hash, $ftype) = @_;
5990
5991         $from = 0 unless defined $from;
5992         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5993
5994         print "<table class=\"history\">\n";
5995         my $alternate = 1;
5996         for (my $i = $from; $i <= $to; $i++) {
5997                 my %co = %{$commitlist->[$i]};
5998                 if (!%co) {
5999                         next;
6000                 }
6001                 my $commit = $co{'id'};
6002
6003                 my $ref = format_ref_marker($refs, $commit);
6004
6005                 if ($alternate) {
6006                         print "<tr class=\"dark\">\n";
6007                 } else {
6008                         print "<tr class=\"light\">\n";
6009                 }
6010                 $alternate ^= 1;
6011                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6012         # shortlog:   format_author_html('td', \%co, 10)
6013                       format_author_html('td', \%co, 15, 3) . "<td>";
6014                 # originally git_history used chop_str($co{'title'}, 50)
6015                 print format_subject_html($co{'title'}, $co{'title_short'},
6016                                           href(action=>"commit", hash=>$commit), $ref);
6017                 print "</td>\n" .
6018                       "<td class=\"link\">" .
6019                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
6020                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
6021
6022                 if ($ftype eq 'blob') {
6023                         print " | " .
6024                               $cgi->a({-href => href(action=>"blob_plain", hash_base=>$commit, file_name=>$file_name)}, "raw");
6025
6026                         my $blob_current = $file_hash;
6027                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
6028                         if (defined $blob_current && defined $blob_parent &&
6029                                         $blob_current ne $blob_parent) {
6030                                 print " | " .
6031                                         $cgi->a({-href => href(action=>"blobdiff",
6032                                                                hash=>$blob_current, hash_parent=>$blob_parent,
6033                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
6034                                                                file_name=>$file_name)},
6035                                                 "diff to current");
6036                         }
6037                 }
6038                 print "</td>\n" .
6039                       "</tr>\n";
6040         }
6041         if (defined $extra) {
6042                 print "<tr>\n" .
6043                       "<td colspan=\"4\">$extra</td>\n" .
6044                       "</tr>\n";
6045         }
6046         print "</table>\n";
6047 }
6048
6049 sub git_tags_body {
6050         # uses global variable $project
6051         my ($taglist, $from, $to, $extra) = @_;
6052         $from = 0 unless defined $from;
6053         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
6054
6055         print "<table class=\"tags\">\n";
6056         my $alternate = 1;
6057         for (my $i = $from; $i <= $to; $i++) {
6058                 my $entry = $taglist->[$i];
6059                 my %tag = %$entry;
6060                 my $comment = $tag{'subject'};
6061                 my $comment_short;
6062                 if (defined $comment) {
6063                         $comment_short = chop_str($comment, 30, 5);
6064                 }
6065                 if ($alternate) {
6066                         print "<tr class=\"dark\">\n";
6067                 } else {
6068                         print "<tr class=\"light\">\n";
6069                 }
6070                 $alternate ^= 1;
6071                 if (defined $tag{'age'}) {
6072                         print "<td><i>$tag{'age'}</i></td>\n";
6073                 } else {
6074                         print "<td></td>\n";
6075                 }
6076                 print "<td>" .
6077                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6078                                -class => "list name"}, esc_html($tag{'name'})) .
6079                       "</td>\n" .
6080                       "<td>";
6081                 if (defined $comment) {
6082                         print format_subject_html($comment, $comment_short,
6083                                                   href(action=>"tag", hash=>$tag{'id'}));
6084                 }
6085                 print "</td>\n" .
6086                       "<td class=\"selflink\">";
6087                 if ($tag{'type'} eq "tag") {
6088                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6089                 } else {
6090                         print "&nbsp;";
6091                 }
6092                 print "</td>\n" .
6093                       "<td class=\"link\">" . " | " .
6094                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6095                 if ($tag{'reftype'} eq "commit") {
6096                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6097                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6098                 } elsif ($tag{'reftype'} eq "blob") {
6099                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6100                 }
6101                 print "</td>\n" .
6102                       "</tr>";
6103         }
6104         if (defined $extra) {
6105                 print "<tr>\n" .
6106                       "<td colspan=\"5\">$extra</td>\n" .
6107                       "</tr>\n";
6108         }
6109         print "</table>\n";
6110 }
6111
6112 sub git_heads_body {
6113         # uses global variable $project
6114         my ($headlist, $head_at, $from, $to, $extra) = @_;
6115         $from = 0 unless defined $from;
6116         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6117
6118         print "<table class=\"heads\">\n";
6119         my $alternate = 1;
6120         for (my $i = $from; $i <= $to; $i++) {
6121                 my $entry = $headlist->[$i];
6122                 my %ref = %$entry;
6123                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6124                 if ($alternate) {
6125                         print "<tr class=\"dark\">\n";
6126                 } else {
6127                         print "<tr class=\"light\">\n";
6128                 }
6129                 $alternate ^= 1;
6130                 print "<td><i>$ref{'age'}</i></td>\n" .
6131                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6132                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6133                                -class => "list name"},esc_html($ref{'name'})) .
6134                       "</td>\n" .
6135                       "<td class=\"link\">" .
6136                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6137                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6138                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6139                       "</td>\n" .
6140                       "</tr>";
6141         }
6142         if (defined $extra) {
6143                 print "<tr>\n" .
6144                       "<td colspan=\"3\">$extra</td>\n" .
6145                       "</tr>\n";
6146         }
6147         print "</table>\n";
6148 }
6149
6150 # Display a single remote block
6151 sub git_remote_block {
6152         my ($remote, $rdata, $limit, $head) = @_;
6153
6154         my $heads = $rdata->{'heads'};
6155         my $fetch = $rdata->{'fetch'};
6156         my $push = $rdata->{'push'};
6157
6158         my $urls_table = "<table class=\"projects_list\">\n" ;
6159
6160         if (defined $fetch) {
6161                 if ($fetch eq $push) {
6162                         $urls_table .= format_repo_url("URL", $fetch);
6163                 } else {
6164                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6165                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6166                 }
6167         } elsif (defined $push) {
6168                 $urls_table .= format_repo_url("Push URL", $push);
6169         } else {
6170                 $urls_table .= format_repo_url("", "No remote URL");
6171         }
6172
6173         $urls_table .= "</table>\n";
6174
6175         my $dots;
6176         if (defined $limit && $limit < @$heads) {
6177                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6178         }
6179
6180         print $urls_table;
6181         git_heads_body($heads, $head, 0, $limit, $dots);
6182 }
6183
6184 # Display a list of remote names with the respective fetch and push URLs
6185 sub git_remotes_list {
6186         my ($remotedata, $limit) = @_;
6187         print "<table class=\"heads\">\n";
6188         my $alternate = 1;
6189         my @remotes = sort keys %$remotedata;
6190
6191         my $limited = $limit && $limit < @remotes;
6192
6193         $#remotes = $limit - 1 if $limited;
6194
6195         while (my $remote = shift @remotes) {
6196                 my $rdata = $remotedata->{$remote};
6197                 my $fetch = $rdata->{'fetch'};
6198                 my $push = $rdata->{'push'};
6199                 if ($alternate) {
6200                         print "<tr class=\"dark\">\n";
6201                 } else {
6202                         print "<tr class=\"light\">\n";
6203                 }
6204                 $alternate ^= 1;
6205                 print "<td>" .
6206                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6207                                -class=> "list name"},esc_html($remote)) .
6208                       "</td>";
6209                 print "<td class=\"link\">" .
6210                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6211                       " | " .
6212                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6213                       "</td>";
6214
6215                 print "</tr>\n";
6216         }
6217
6218         if ($limited) {
6219                 print "<tr>\n" .
6220                       "<td colspan=\"3\">" .
6221                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6222                       "</td>\n" . "</tr>\n";
6223         }
6224
6225         print "</table>";
6226 }
6227
6228 # Display remote heads grouped by remote, unless there are too many
6229 # remotes, in which case we only display the remote names
6230 sub git_remotes_body {
6231         my ($remotedata, $limit, $head) = @_;
6232         if ($limit and $limit < keys %$remotedata) {
6233                 git_remotes_list($remotedata, $limit);
6234         } else {
6235                 fill_remote_heads($remotedata);
6236                 while (my ($remote, $rdata) = each %$remotedata) {
6237                         git_print_section({-class=>"remote", -id=>$remote},
6238                                 ["remotes", $remote, $remote], sub {
6239                                         git_remote_block($remote, $rdata, $limit, $head);
6240                                 });
6241                 }
6242         }
6243 }
6244
6245 sub git_search_message {
6246         my %co = @_;
6247
6248         my $greptype;
6249         if ($searchtype eq 'commit') {
6250                 $greptype = "--grep=";
6251         } elsif ($searchtype eq 'author') {
6252                 $greptype = "--author=";
6253         } elsif ($searchtype eq 'committer') {
6254                 $greptype = "--committer=";
6255         }
6256         $greptype .= $searchtext;
6257         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6258                                        $greptype, '--regexp-ignore-case',
6259                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6260
6261         my $paging_nav = '';
6262         if ($page > 0) {
6263                 $paging_nav .=
6264                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6265                                 "first") .
6266                         " &sdot; " .
6267                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6268                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6269         } else {
6270                 $paging_nav .= "first &sdot; prev";
6271         }
6272         my $next_link = '';
6273         if ($#commitlist >= 100) {
6274                 $next_link =
6275                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6276                                  -accesskey => "n", -title => "Alt-n"}, "next");
6277                 $paging_nav .= " &sdot; $next_link";
6278         } else {
6279                 $paging_nav .= " &sdot; next";
6280         }
6281
6282         git_header_html();
6283
6284         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6285         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6286         if ($page == 0 && !@commitlist) {
6287                 print "<p>No match.</p>\n";
6288         } else {
6289                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6290         }
6291
6292         git_footer_html();
6293 }
6294
6295 sub git_search_changes {
6296         my %co = @_;
6297
6298         local $/ = "\n";
6299         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6300                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6301                 ($search_use_regexp ? '--pickaxe-regex' : ())
6302                         or die_error(500, "Open git-log failed");
6303
6304         git_header_html();
6305
6306         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6307         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6308
6309         print "<table class=\"pickaxe search\">\n";
6310         my $alternate = 1;
6311         undef %co;
6312         my @files;
6313         while (my $line = <$fd>) {
6314                 chomp $line;
6315                 next unless $line;
6316
6317                 my %set = parse_difftree_raw_line($line);
6318                 if (defined $set{'commit'}) {
6319                         # finish previous commit
6320                         if (%co) {
6321                                 print "</td>\n" .
6322                                       "<td class=\"link\">" .
6323                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6324                                               "commit") .
6325                                       " | " .
6326                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6327                                                              hash_base=>$co{'id'})},
6328                                               "tree") .
6329                                       "</td>\n" .
6330                                       "</tr>\n";
6331                         }
6332
6333                         if ($alternate) {
6334                                 print "<tr class=\"dark\">\n";
6335                         } else {
6336                                 print "<tr class=\"light\">\n";
6337                         }
6338                         $alternate ^= 1;
6339                         %co = parse_commit($set{'commit'});
6340                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6341                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6342                               "<td><i>$author</i></td>\n" .
6343                               "<td>" .
6344                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6345                                       -class => "list subject"},
6346                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6347                 } elsif (defined $set{'to_id'}) {
6348                         next if is_deleted(\%set);
6349
6350                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6351                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6352                                       -class => "list"},
6353                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6354                               "<br/>\n";
6355                 }
6356         }
6357         close $fd;
6358
6359         # finish last commit (warning: repetition!)
6360         if (%co) {
6361                 print "</td>\n" .
6362                       "<td class=\"link\">" .
6363                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6364                               "commit") .
6365                       " | " .
6366                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6367                                              hash_base=>$co{'id'})},
6368                               "tree") .
6369                       "</td>\n" .
6370                       "</tr>\n";
6371         }
6372
6373         print "</table>\n";
6374
6375         git_footer_html();
6376 }
6377
6378 sub git_search_files {
6379         my %co = @_;
6380
6381         local $/ = "\n";
6382         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6383                 $search_use_regexp ? ('-E', '-i') : '-F',
6384                 $searchtext, $co{'tree'}
6385                         or die_error(500, "Open git-grep failed");
6386
6387         git_header_html();
6388
6389         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6390         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6391
6392         print "<table class=\"grep_search\">\n";
6393         my $alternate = 1;
6394         my $matches = 0;
6395         my $lastfile = '';
6396         my $file_href;
6397         while (my $line = <$fd>) {
6398                 chomp $line;
6399                 my ($file, $lno, $ltext, $binary);
6400                 last if ($matches++ > 1000);
6401                 if ($line =~ /^Binary file (.+) matches$/) {
6402                         $file = $1;
6403                         $binary = 1;
6404                 } else {
6405                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6406                         $file =~ s/^$co{'tree'}://;
6407                 }
6408                 if ($file ne $lastfile) {
6409                         $lastfile and print "</td></tr>\n";
6410                         if ($alternate++) {
6411                                 print "<tr class=\"dark\">\n";
6412                         } else {
6413                                 print "<tr class=\"light\">\n";
6414                         }
6415                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6416                                           file_name=>$file);
6417                         print "<td class=\"list\">".
6418                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6419                         print "</td><td>\n";
6420                         $lastfile = $file;
6421                 }
6422                 if ($binary) {
6423                         print "<div class=\"binary\">Binary file</div>\n";
6424                 } else {
6425                         $ltext = untabify($ltext);
6426                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6427                                 $ltext = esc_html($1, -nbsp=>1);
6428                                 $ltext .= '<span class="match">';
6429                                 $ltext .= esc_html($2, -nbsp=>1);
6430                                 $ltext .= '</span>';
6431                                 $ltext .= esc_html($3, -nbsp=>1);
6432                         } else {
6433                                 $ltext = esc_html($ltext, -nbsp=>1);
6434                         }
6435                         print "<div class=\"pre\">" .
6436                                 $cgi->a({-href => $file_href.'#l'.$lno,
6437                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6438                                 ' ' .  $ltext . "</div>\n";
6439                 }
6440         }
6441         if ($lastfile) {
6442                 print "</td></tr>\n";
6443                 if ($matches > 1000) {
6444                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6445                 }
6446         } else {
6447                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6448         }
6449         close $fd;
6450
6451         print "</table>\n";
6452
6453         git_footer_html();
6454 }
6455
6456 sub git_search_grep_body {
6457         my ($commitlist, $from, $to, $extra) = @_;
6458         $from = 0 unless defined $from;
6459         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6460
6461         print "<table class=\"commit_search\">\n";
6462         my $alternate = 1;
6463         for (my $i = $from; $i <= $to; $i++) {
6464                 my %co = %{$commitlist->[$i]};
6465                 if (!%co) {
6466                         next;
6467                 }
6468                 my $commit = $co{'id'};
6469                 if ($alternate) {
6470                         print "<tr class=\"dark\">\n";
6471                 } else {
6472                         print "<tr class=\"light\">\n";
6473                 }
6474                 $alternate ^= 1;
6475                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6476                       format_author_html('td', \%co, 15, 5) .
6477                       "<td>" .
6478                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6479                                -class => "list subject"},
6480                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6481                 my $comment = $co{'comment'};
6482                 foreach my $line (@$comment) {
6483                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6484                                 my ($lead, $match, $trail) = ($1, $2, $3);
6485                                 $match = chop_str($match, 70, 5, 'center');
6486                                 my $contextlen = int((80 - length($match))/2);
6487                                 $contextlen = 30 if ($contextlen > 30);
6488                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6489                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6490
6491                                 $lead  = esc_html($lead);
6492                                 $match = esc_html($match);
6493                                 $trail = esc_html($trail);
6494
6495                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6496                         }
6497                 }
6498                 print "</td>\n" .
6499                       "<td class=\"link\">" .
6500                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6501                       " | " .
6502                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6503                       " | " .
6504                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6505                 print "</td>\n" .
6506                       "</tr>\n";
6507         }
6508         if (defined $extra) {
6509                 print "<tr>\n" .
6510                       "<td colspan=\"3\">$extra</td>\n" .
6511                       "</tr>\n";
6512         }
6513         print "</table>\n";
6514 }
6515
6516 ## ======================================================================
6517 ## ======================================================================
6518 ## actions
6519
6520 sub git_project_list {
6521         my $order = $input_params{'order'};
6522         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6523                 die_error(400, "Unknown order parameter");
6524         }
6525
6526         my @list = git_get_projects_list($project_filter, $strict_export);
6527         if (!@list) {
6528                 die_error(404, "No projects found");
6529         }
6530
6531         git_header_html();
6532         if (defined $home_text && -f $home_text) {
6533                 print "<div class=\"index_include\">\n";
6534                 insert_file($home_text);
6535                 print "</div>\n";
6536         }
6537
6538         git_project_search_form($searchtext, $search_use_regexp);
6539         git_project_list_body(\@list, $order);
6540         git_footer_html();
6541 }
6542
6543 sub git_forks {
6544         my $order = $input_params{'order'};
6545         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6546                 die_error(400, "Unknown order parameter");
6547         }
6548
6549         my $filter = $project;
6550         $filter =~ s/\.git$//;
6551         my @list = git_get_projects_list($filter);
6552         if (!@list) {
6553                 die_error(404, "No forks found");
6554         }
6555
6556         git_header_html();
6557         git_print_page_nav('','');
6558         git_print_header_div('summary', "$project forks");
6559         git_project_list_body(\@list, $order);
6560         git_footer_html();
6561 }
6562
6563 sub git_project_index {
6564         my @projects = git_get_projects_list($project_filter, $strict_export);
6565         if (!@projects) {
6566                 die_error(404, "No projects found");
6567         }
6568
6569         print $cgi->header(
6570                 -type => 'text/plain',
6571                 -charset => 'utf-8',
6572                 -content_disposition => 'inline; filename="index.aux"');
6573
6574         foreach my $pr (@projects) {
6575                 if (!exists $pr->{'owner'}) {
6576                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6577                 }
6578
6579                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6580                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6581                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6582                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6583                 $path  =~ s/ /\+/g;
6584                 $owner =~ s/ /\+/g;
6585
6586                 print "$path $owner\n";
6587         }
6588 }
6589
6590 sub git_summary {
6591         my $descr = git_get_project_description($project) || "none";
6592         my %co = parse_commit("HEAD");
6593         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6594         my $head = $co{'id'};
6595         my $remote_heads = gitweb_check_feature('remote_heads');
6596
6597         my $owner = git_get_project_owner($project);
6598
6599         my $refs = git_get_references();
6600         # These get_*_list functions return one more to allow us to see if
6601         # there are more ...
6602         my @taglist  = git_get_tags_list(16);
6603         my @headlist = git_get_heads_list(16);
6604         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6605         my @forklist;
6606         my $check_forks = gitweb_check_feature('forks');
6607
6608         if ($check_forks) {
6609                 # find forks of a project
6610                 my $filter = $project;
6611                 $filter =~ s/\.git$//;
6612                 @forklist = git_get_projects_list($filter);
6613                 # filter out forks of forks
6614                 @forklist = filter_forks_from_projects_list(\@forklist)
6615                         if (@forklist);
6616         }
6617
6618         git_header_html();
6619         git_print_page_nav('summary','', $head);
6620
6621         print "<div class=\"title\">&nbsp;</div>\n";
6622         print "<table class=\"projects_list\">\n" .
6623               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6624         if ($owner and not $omit_owner) {
6625                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6626         }
6627         if (defined $cd{'rfc2822'}) {
6628                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6629                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6630         }
6631
6632         # use per project git URL list in $projectroot/$project/cloneurl
6633         # or make project git URL from git base URL and project name
6634         my $url_tag = "URL";
6635         my @url_list = git_get_project_url_list($project);
6636         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6637         foreach my $git_url (@url_list) {
6638                 next unless $git_url;
6639                 print format_repo_url($url_tag, $git_url);
6640                 $url_tag = "";
6641         }
6642
6643         # Tag cloud
6644         my $show_ctags = gitweb_check_feature('ctags');
6645         if ($show_ctags) {
6646                 my $ctags = git_get_project_ctags($project);
6647                 if (%$ctags) {
6648                         # without ability to add tags, don't show if there are none
6649                         my $cloud = git_populate_project_tagcloud($ctags);
6650                         print "<tr id=\"metadata_ctags\">" .
6651                               "<td>content tags</td>" .
6652                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6653                               "</tr>\n";
6654                 }
6655         }
6656
6657         print "</table>\n";
6658
6659         # If XSS prevention is on, we don't include README.html.
6660         # TODO: Allow a readme in some safe format.
6661         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6662                 print "<div class=\"title\">readme</div>\n" .
6663                       "<div class=\"readme\">\n";
6664                 insert_file("$projectroot/$project/README.html");
6665                 print "\n</div>\n"; # class="readme"
6666         }
6667
6668     if (!$prevent_xss) {
6669         $file_name = "README.md";
6670         my $proj_head_hash = git_get_head_hash($project);
6671         my $readme_blob_hash = git_get_hash_by_path($proj_head_hash, "readme.md", "blob");
6672
6673         if ($readme_blob_hash) { # if README.md exists
6674             print "<div class=\"header\">$file_name</div>\n";
6675             print "<div class=\"readme page_body\">"; # TODO find/create a better CSS class than page_body
6676             print get_markdown($file_name, $readme_blob_hash);
6677             print "</div>";
6678         }
6679     }
6680
6681         # we need to request one more than 16 (0..15) to check if
6682         # those 16 are all
6683         my @commitlist = $head ? parse_commits($head, 17) : ();
6684         if (@commitlist) {
6685                 git_print_header_div('shortlog');
6686                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6687                                   $#commitlist <=  15 ? undef :
6688                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6689         }
6690
6691         if (@taglist) {
6692                 git_print_header_div('tags');
6693                 git_tags_body(\@taglist, 0, 15,
6694                               $#taglist <=  15 ? undef :
6695                               $cgi->a({-href => href(action=>"tags")}, "..."));
6696         }
6697
6698         if (@headlist) {
6699                 git_print_header_div('heads');
6700                 git_heads_body(\@headlist, $head, 0, 15,
6701                                $#headlist <= 15 ? undef :
6702                                $cgi->a({-href => href(action=>"heads")}, "..."));
6703         }
6704
6705         if (%remotedata) {
6706                 git_print_header_div('remotes');
6707                 git_remotes_body(\%remotedata, 15, $head);
6708         }
6709
6710         if (@forklist) {
6711                 git_print_header_div('forks');
6712                 git_project_list_body(\@forklist, 'age', 0, 15,
6713                                       $#forklist <= 15 ? undef :
6714                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6715                                       'no_header');
6716         }
6717
6718         git_footer_html();
6719 }
6720
6721 sub git_tag {
6722         my %tag = parse_tag($hash);
6723
6724         if (! %tag) {
6725                 die_error(404, "Unknown tag object");
6726         }
6727
6728         my $head = git_get_head_hash($project);
6729         git_header_html();
6730         git_print_page_nav('','', $head,undef,$head);
6731         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6732         print "<div class=\"title_text\">\n" .
6733               "<table class=\"object_header\">\n" .
6734               "<tr>\n" .
6735               "<td>object</td>\n" .
6736               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6737                                $tag{'object'}) . "</td>\n" .
6738               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6739                                               $tag{'type'}) . "</td>\n" .
6740               "</tr>\n";
6741         if (defined($tag{'author'})) {
6742                 git_print_authorship_rows(\%tag, 'author');
6743         }
6744         print "</table>\n\n" .
6745               "</div>\n";
6746         print "<div class=\"page_body\">";
6747         my $comment = $tag{'comment'};
6748         foreach my $line (@$comment) {
6749                 chomp $line;
6750                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6751         }
6752         print "</div>\n";
6753         git_footer_html();
6754 }
6755
6756 sub git_blame_common {
6757         my $format = shift || 'porcelain';
6758         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6759                 $format = 'incremental';
6760                 $action = 'blame_incremental'; # for page title etc
6761         }
6762
6763         # permissions
6764         gitweb_check_feature('blame')
6765                 or die_error(403, "Blame view not allowed");
6766
6767         # error checking
6768         die_error(400, "No file name given") unless $file_name;
6769         $hash_base ||= git_get_head_hash($project);
6770         die_error(404, "Couldn't find base commit") unless $hash_base;
6771         my %co = parse_commit($hash_base)
6772                 or die_error(404, "Commit not found");
6773         my $ftype = "blob";
6774         if (!defined $hash) {
6775                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6776                         or die_error(404, "Error looking up file");
6777         } else {
6778                 $ftype = git_get_type($hash);
6779                 if ($ftype !~ "blob") {
6780                         die_error(400, "Object is not a blob");
6781                 }
6782         }
6783
6784         my $fd;
6785         if ($format eq 'incremental') {
6786                 # get file contents (as base)
6787                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6788                         or die_error(500, "Open git-cat-file failed");
6789         } elsif ($format eq 'data') {
6790                 # run git-blame --incremental
6791                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6792                         $hash_base, "--", $file_name
6793                         or die_error(500, "Open git-blame --incremental failed");
6794         } else {
6795                 # run git-blame --porcelain
6796                 open $fd, "-|", git_cmd(), "blame", '-p',
6797                         $hash_base, '--', $file_name
6798                         or die_error(500, "Open git-blame --porcelain failed");
6799         }
6800         binmode $fd, ':utf8';
6801
6802         # incremental blame data returns early
6803         if ($format eq 'data') {
6804                 print $cgi->header(
6805                         -type=>"text/plain", -charset => "utf-8",
6806                         -status=> "200 OK");
6807                 local $| = 1; # output autoflush
6808                 while (my $line = <$fd>) {
6809                         print to_utf8($line);
6810                 }
6811                 close $fd
6812                         or print "ERROR $!\n";
6813
6814                 print 'END';
6815                 if (defined $t0 && gitweb_check_feature('timed')) {
6816                         print ' '.
6817                               tv_interval($t0, [ gettimeofday() ]).
6818                               ' '.$number_of_git_cmds;
6819                 }
6820                 print "\n";
6821
6822                 return;
6823         }
6824
6825         # page header
6826         git_header_html();
6827         my $formats_nav =
6828                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6829                         "blob") .
6830                 " | ";
6831         if ($format eq 'incremental') {
6832                 $formats_nav .=
6833                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6834                                 "blame") . " (non-incremental)";
6835         } else {
6836                 $formats_nav .=
6837                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6838                                 "blame") . " (incremental)";
6839         }
6840         $formats_nav .=
6841                 " | " .
6842                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6843                         "history") .
6844                 " | " .
6845                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6846                         "HEAD");
6847         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6848         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6849         git_print_page_path($file_name, $ftype, $hash_base);
6850
6851         # page body
6852         if ($format eq 'incremental') {
6853                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6854                       "This page requires JavaScript to run.\n Use ".
6855                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6856                               'this page').
6857                       " instead.\n".
6858                       "</b></center></div>\n</noscript>\n";
6859
6860                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6861         }
6862
6863         print qq!<div class="page_body">\n!;
6864         print qq!<div id="progress_info">... / ...</div>\n!
6865                 if ($format eq 'incremental');
6866         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6867               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6868               qq!<thead>\n!.
6869               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6870               qq!</thead>\n!.
6871               qq!<tbody>\n!;
6872
6873         my @rev_color = qw(light dark);
6874         my $num_colors = scalar(@rev_color);
6875         my $current_color = 0;
6876
6877         if ($format eq 'incremental') {
6878                 my $color_class = $rev_color[$current_color];
6879
6880                 #contents of a file
6881                 my $linenr = 0;
6882         LINE:
6883                 while (my $line = <$fd>) {
6884                         chomp $line;
6885                         $linenr++;
6886
6887                         print qq!<tr id="l$linenr" class="$color_class">!.
6888                               qq!<td class="sha1"><a href=""> </a></td>!.
6889                               qq!<td class="linenr">!.
6890                               qq!<a class="linenr" href="">$linenr</a></td>!;
6891                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6892                         print qq!</tr>\n!;
6893                 }
6894
6895         } else { # porcelain, i.e. ordinary blame
6896                 my %metainfo = (); # saves information about commits
6897
6898                 # blame data
6899         LINE:
6900                 while (my $line = <$fd>) {
6901                         chomp $line;
6902                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6903                         # no <lines in group> for subsequent lines in group of lines
6904                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6905                            ($line =~ /^($oid_regex) (\d+) (\d+)(?: (\d+))?$/);
6906                         if (!exists $metainfo{$full_rev}) {
6907                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6908                         }
6909                         my $meta = $metainfo{$full_rev};
6910                         my $data;
6911                         while ($data = <$fd>) {
6912                                 chomp $data;
6913                                 last if ($data =~ s/^\t//); # contents of line
6914                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6915                                         $meta->{$1} = $2 unless exists $meta->{$1};
6916                                 }
6917                                 if ($data =~ /^previous /) {
6918                                         $meta->{'nprevious'}++;
6919                                 }
6920                         }
6921                         my $short_rev = substr($full_rev, 0, 8);
6922                         my $author = $meta->{'author'};
6923                         my %date =
6924                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6925                         my $date = $date{'iso-tz'};
6926                         if ($group_size) {
6927                                 $current_color = ($current_color + 1) % $num_colors;
6928                         }
6929                         my $tr_class = $rev_color[$current_color];
6930                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6931                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6932                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6933                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6934                         if ($group_size) {
6935                                 print "<td class=\"sha1\"";
6936                                 print " title=\"". esc_html($author) . ", $date\"";
6937                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6938                                 print ">";
6939                                 print $cgi->a({-href => href(action=>"commit",
6940                                                              hash=>$full_rev,
6941                                                              file_name=>$file_name)},
6942                                               esc_html($short_rev));
6943                                 if ($group_size >= 2) {
6944                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6945                                         if (@author_initials) {
6946                                                 print "<br />" .
6947                                                       esc_html(join('', @author_initials));
6948                                                 #           or join('.', ...)
6949                                         }
6950                                 }
6951                                 print "</td>\n";
6952                         }
6953                         # 'previous' <sha1 of parent commit> <filename at commit>
6954                         if (exists $meta->{'previous'} &&
6955                             $meta->{'previous'} =~ /^($oid_regex) (.*)$/) {
6956                                 $meta->{'parent'} = $1;
6957                                 $meta->{'file_parent'} = unquote($2);
6958                         }
6959                         my $linenr_commit =
6960                                 exists($meta->{'parent'}) ?
6961                                 $meta->{'parent'} : $full_rev;
6962                         my $linenr_filename =
6963                                 exists($meta->{'file_parent'}) ?
6964                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6965                         my $blamed = href(action => 'blame',
6966                                           file_name => $linenr_filename,
6967                                           hash_base => $linenr_commit);
6968                         print "<td class=\"linenr\">";
6969                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6970                                         -class => "linenr" },
6971                                       esc_html($lineno));
6972                         print "</td>";
6973                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6974                         print "</tr>\n";
6975                 } # end while
6976
6977         }
6978
6979         # footer
6980         print "</tbody>\n".
6981               "</table>\n"; # class="blame"
6982         print "</div>\n";   # class="blame_body"
6983         close $fd
6984                 or print "Reading blob failed\n";
6985
6986         git_footer_html();
6987 }
6988
6989 sub git_blame {
6990         git_blame_common();
6991 }
6992
6993 sub git_blame_incremental {
6994         git_blame_common('incremental');
6995 }
6996
6997 sub git_blame_data {
6998         git_blame_common('data');
6999 }
7000
7001 sub git_tags {
7002         my $head = git_get_head_hash($project);
7003         git_header_html();
7004         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
7005         git_print_header_div('summary', $project);
7006
7007         my @tagslist = git_get_tags_list();
7008         if (@tagslist) {
7009                 git_tags_body(\@tagslist);
7010         }
7011         git_footer_html();
7012 }
7013
7014 sub git_heads {
7015         my $head = git_get_head_hash($project);
7016         git_header_html();
7017         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
7018         git_print_header_div('summary', $project);
7019
7020         my @headslist = git_get_heads_list();
7021         if (@headslist) {
7022                 git_heads_body(\@headslist, $head);
7023         }
7024         git_footer_html();
7025 }
7026
7027 # used both for single remote view and for list of all the remotes
7028 sub git_remotes {
7029         gitweb_check_feature('remote_heads')
7030                 or die_error(403, "Remote heads view is disabled");
7031
7032         my $head = git_get_head_hash($project);
7033         my $remote = $input_params{'hash'};
7034
7035         my $remotedata = git_get_remotes_list($remote);
7036         die_error(500, "Unable to get remote information") unless defined $remotedata;
7037
7038         unless (%$remotedata) {
7039                 die_error(404, defined $remote ?
7040                         "Remote $remote not found" :
7041                         "No remotes found");
7042         }
7043
7044         git_header_html(undef, undef, -action_extra => $remote);
7045         git_print_page_nav('', '',  $head, undef, $head,
7046                 format_ref_views($remote ? '' : 'remotes'));
7047
7048         fill_remote_heads($remotedata);
7049         if (defined $remote) {
7050                 git_print_header_div('remotes', "$remote remote for $project");
7051                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
7052         } else {
7053                 git_print_header_div('summary', "$project remotes");
7054                 git_remotes_body($remotedata, undef, $head);
7055         }
7056
7057         git_footer_html();
7058 }
7059
7060 sub git_blob_plain {
7061         my $type = shift;
7062         my $expires;
7063
7064         if (!defined $hash) {
7065                 if (defined $file_name) {
7066                         my $base = $hash_base || git_get_head_hash($project);
7067                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7068                                 or die_error(404, "Cannot find file");
7069                 } else {
7070                         die_error(400, "No file name defined");
7071                 }
7072         } elsif ($hash =~ m/^$oid_regex$/) {
7073                 # blobs defined by non-textual hash id's can be cached
7074                 $expires = "+1d";
7075         }
7076
7077         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7078                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7079
7080         # content-type (can include charset)
7081         $type = blob_contenttype($fd, $file_name, $type);
7082
7083         # "save as" filename, even when no $file_name is given
7084         my $save_as = "$hash";
7085         if (defined $file_name) {
7086                 $save_as = $file_name;
7087         } elsif ($type =~ m/^text\//) {
7088                 $save_as .= '.txt';
7089         }
7090
7091         # With XSS prevention on, blobs of all types except a few known safe
7092         # ones are served with "Content-Disposition: attachment" to make sure
7093         # they don't run in our security domain.  For certain image types,
7094         # blob view writes an <img> tag referring to blob_plain view, and we
7095         # want to be sure not to break that by serving the image as an
7096         # attachment (though Firefox 3 doesn't seem to care).
7097         my $sandbox = $prevent_xss &&
7098                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7099
7100         # serve text/* as text/plain
7101         if ($prevent_xss &&
7102             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7103              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7104                 my $rest = $1;
7105                 $rest = defined $rest ? $rest : '';
7106                 $type = "text/plain$rest";
7107         }
7108
7109         print $cgi->header(
7110                 -type => $type,
7111                 -expires => $expires,
7112                 -content_disposition =>
7113                         ($sandbox ? 'attachment' : 'inline')
7114                         . '; filename="' . $save_as . '"');
7115         local $/ = undef;
7116         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7117         binmode STDOUT, ':raw';
7118         print <$fd>;
7119         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7120         close $fd;
7121 }
7122
7123 sub git_blob {
7124         my $expires;
7125
7126         if (!defined $hash) {
7127                 if (defined $file_name) {
7128                         my $base = $hash_base || git_get_head_hash($project);
7129                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7130                                 or die_error(404, "Cannot find file");
7131                 } else {
7132                         die_error(400, "No file name defined");
7133                 }
7134         } elsif ($hash =~ m/^$oid_regex$/) {
7135                 # blobs defined by non-textual hash id's can be cached
7136                 $expires = "+1d";
7137         }
7138
7139         my $have_blame = gitweb_check_feature('blame');
7140         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7141                 or die_error(500, "Couldn't cat $file_name, $hash");
7142         my $mimetype = blob_mimetype($fd, $file_name);
7143         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7144         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7145                 close $fd;
7146                 return git_blob_plain($mimetype);
7147         }
7148         # we can have blame only for text/* mimetype
7149         $have_blame &&= ($mimetype =~ m!^text/!);
7150
7151         my $highlight = gitweb_check_feature('highlight');
7152         my $syntax = guess_file_syntax($highlight, $file_name);
7153         $fd = run_highlighter($fd, $highlight, $syntax);
7154
7155         my $ismarkdown = ($file_name =~ /md$/);
7156
7157         git_header_html(undef, $expires);
7158         my $formats_nav = '';
7159         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7160                 if (defined $file_name) {
7161                         if ($have_blame) {
7162                                 $formats_nav .=
7163                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7164                                                 "blame") .
7165                                         " | ";
7166                         }
7167                         $formats_nav .=
7168                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7169                                         "history") .
7170                                 " | " .
7171                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7172                                         "raw") .
7173                                 " | " .
7174                                 $cgi->a({-href => href(action=>"blob",
7175                                                        hash_base=>"HEAD", file_name=>$file_name)},
7176                                         "HEAD");
7177                 } else {
7178                         $formats_nav .=
7179                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7180                                         "raw");
7181                 }
7182                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7183                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7184         } else {
7185                 print "<div class=\"page_nav\">\n" .
7186                       "<br/><br/></div>\n" .
7187                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7188         }
7189         git_print_page_path($file_name, "blob", $hash_base);
7190         print "<div class=\"page_body\">\n";
7191         if ($mimetype =~ m!^image/!) {
7192                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7193                 if ($file_name) {
7194                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7195                 }
7196                 print qq! src="! .
7197                       esc_attr(href(action=>"blob_plain", hash=>$hash,
7198                            hash_base=>$hash_base, file_name=>$file_name)) .
7199                       qq!" />\n!;
7200     } elsif ($ismarkdown) {
7201         print qq!<div class="readme page_body">\n!;
7202         print get_markdown($file_name, $hash);
7203         print qq!</div>\n!; #  $cmd_markdownify
7204     } else {
7205                 my $nr;
7206                 while (my $line = <$fd>) {
7207                         chomp $line;
7208                         $nr++;
7209                         $line = untabify($line);
7210                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7211                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7212                                $highlight ? sanitize($line) : esc_html($line, -nbsp=>1);
7213                 }
7214         }
7215         close $fd
7216                 or print "Reading blob failed.\n";
7217         print "</div>";
7218         git_footer_html();
7219 }
7220
7221 sub get_norm_rel_path { # http://www.perlmonks.org/bare/?node_id=11907
7222    my $unnormpath = shift;
7223    while ($unnormpath =~ m!/\.!) {
7224        $unnormpath =~ s!/[^\/]+/\.\.!!;
7225        # print "Path is now -+$unnormpath+-\n";
7226    }
7227    return $unnormpath;
7228 }
7229 sub get_markdown {
7230    my $tfilename = shift;
7231    my $thash = shift;
7232    my $rethtmlstr = "";
7233    use open ":encoding(utf8)"; # needed to have utf8 survive through the shell pipe
7234    my $cmd_markdownify = $GIT . " " . git_cmd() . " cat-file blob " . $thash . " | " . $PERL . " -e 'my \$str = do { local \$/; <STDIN> }; \$str =~ s/<!--.*?--\s*>//gs; print \$str;' | " . $MD . " |";
7235    open (FOO, $cmd_markdownify) or die_error(500, "Open git-cat-file blob '$thash' failed");
7236    while (<FOO>) {
7237        if ($_ =~ /(<img[^>]src=")(.*?)"/) {
7238            my $origcut = "".$2;
7239            my $testcut = "".$2;
7240            my $is_anchor = ($testcut =~ /^#/);
7241            my $is_absolute = ($testcut =~ /^http/);
7242            my $is_relative_up = ($testcut =~ /^\.\./);
7243            my $is_local_link = ((!$is_anchor) and (!$is_absolute));
7244            my $tdir = dirname($tfilename);
7245            my $is_tdir_proper = (($tdir ne "") and ($tdir ne "."));
7246            #print "XX: $origcut ($is_anchor, $is_absolute - $is_local_link) ($is_relative_up, $is_tdir_proper, $tdir, $tfilename)\n"; # dbg
7247            if ($is_local_link) {
7248                if ($is_relative_up) { # normalize
7249                    if ($is_tdir_proper) {
7250                        # cheat with absolute path here:
7251                        my $resolved = get_norm_rel_path( File::Spec->rel2abs ("$origcut", "/$tdir" ) );
7252                        $resolved = substr $resolved, 1;
7253                        #print "YY: $resolved\n";
7254                        $_ =~ s!(<img[^>]src=")(.*?)"!$1?p=$project;a=blob_plain;f=$resolved"!gi;
7255                    }
7256                } else {
7257                    $_ =~ s!(<img[^>]src=")(.*?)"!$1?p=$project;a=blob_plain;f=$2"!gi;
7258                    #print "ZZ: $_\n";
7259                }
7260            }
7261        }
7262        if ($_ =~ /(<a[^>]href=")(.*?)"/) {
7263            my $origcut = "".$2;
7264            my $testcut = "".$2;
7265            my $is_anchor = ($testcut =~ /^#/);
7266            my $is_absolute = ($testcut =~ /^http/);
7267            my $is_relative_up = ($testcut =~ /^\.\./);
7268            my $is_local_link = ((!$is_anchor) and (!$is_absolute));
7269            my $tdir = dirname($tfilename);
7270            my $is_tdir_proper = (($tdir ne "") and ($tdir ne "."));
7271            #print "XX: $origcut ($is_anchor, $is_absolute - $is_local_link) ($is_relative_up, $is_tdir_proper, $tdir, $tfilename)\n"; # dbg
7272            if ($is_local_link) {
7273                if ($is_relative_up) { # normalize
7274                    if ($is_tdir_proper) {
7275                        # cheat with absolute path here:
7276                        my $resolved = get_norm_rel_path( File::Spec->rel2abs ("$origcut", "/$tdir" ) );
7277                        $resolved = substr $resolved, 1;
7278                        #print "YY: $resolved\n";
7279                        $_ =~ s!(<a[^>]href=")(.*?)"!$1?p=$project;a=blob;f=$resolved"!gi;
7280                    }
7281                } else {
7282                    $_ =~ s!(<a[^>]href=")(.*?)"!$1?p=$project;a=blob;f=$2"!gi;
7283                    #print "ZZ: $_\n";
7284                }
7285            }
7286        }
7287        $rethtmlstr .= $_;
7288    }
7289    close(FOO);
7290    return $rethtmlstr;
7291 }
7292
7293 sub git_tree {
7294         if (!defined $hash_base) {
7295                 $hash_base = "HEAD";
7296         }
7297         if (!defined $hash) {
7298                 if (defined $file_name) {
7299                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7300                 } else {
7301                         $hash = $hash_base;
7302                 }
7303         }
7304         die_error(404, "No such tree") unless defined($hash);
7305
7306         my $show_sizes = gitweb_check_feature('show-sizes');
7307         my $have_blame = gitweb_check_feature('blame');
7308
7309         my @entries = ();
7310         {
7311                 local $/ = "\0";
7312                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7313                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7314                         or die_error(500, "Open git-ls-tree failed");
7315                 @entries = map { chomp; $_ } <$fd>;
7316                 close $fd
7317                         or die_error(404, "Reading tree failed");
7318         }
7319
7320         my $refs = git_get_references();
7321         my $ref = format_ref_marker($refs, $hash_base);
7322         git_header_html();
7323         my $basedir = '';
7324         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7325                 my @views_nav = ();
7326                 if (defined $file_name) {
7327                         push @views_nav,
7328                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7329                                         "history"),
7330                                 $cgi->a({-href => href(action=>"tree",
7331                                                        hash_base=>"HEAD", file_name=>$file_name)},
7332                                         "HEAD"),
7333                 }
7334                 my $snapshot_links = format_snapshot_links($hash);
7335                 if (defined $snapshot_links) {
7336                         # FIXME: Should be available when we have no hash base as well.
7337                         push @views_nav, $snapshot_links;
7338                 }
7339                 git_print_page_nav('tree','', $hash_base, undef, undef,
7340                                    join(' | ', @views_nav));
7341                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7342         } else {
7343                 undef $hash_base;
7344                 print "<div class=\"page_nav\">\n";
7345                 print "<br/><br/></div>\n";
7346                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7347         }
7348         if (defined $file_name) {
7349                 $basedir = $file_name;
7350                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7351                         $basedir .= '/';
7352                 }
7353                 git_print_page_path($file_name, 'tree', $hash_base);
7354         }
7355         print "<div class=\"page_body\">\n";
7356         print "<table class=\"tree\">\n";
7357         my $alternate = 1;
7358         # '..' (top directory) link if possible
7359         if (defined $hash_base &&
7360             defined $file_name && $file_name =~ m![^/]+$!) {
7361                 if ($alternate) {
7362                         print "<tr class=\"dark\">\n";
7363                 } else {
7364                         print "<tr class=\"light\">\n";
7365                 }
7366                 $alternate ^= 1;
7367
7368                 my $up = $file_name;
7369                 $up =~ s!/?[^/]+$!!;
7370                 undef $up unless $up;
7371                 # based on git_print_tree_entry
7372                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7373                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7374                 print '<td class="list">';
7375                 print $cgi->a({-href => href(action=>"tree",
7376                                              hash_base=>$hash_base,
7377                                              file_name=>$up)},
7378                               "..");
7379                 print "</td>\n";
7380                 print "<td class=\"link\"></td>\n";
7381
7382                 print "</tr>\n";
7383         }
7384         foreach my $line (@entries) {
7385                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7386
7387                 if ($alternate) {
7388                         print "<tr class=\"dark\">\n";
7389                 } else {
7390                         print "<tr class=\"light\">\n";
7391                 }
7392                 $alternate ^= 1;
7393
7394                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7395
7396                 print "</tr>\n";
7397         }
7398         print "</table>\n" .
7399               "</div>";
7400         git_footer_html();
7401 }
7402
7403 sub sanitize_for_filename {
7404     my $name = shift;
7405
7406     $name =~ s!/!-!g;
7407     $name =~ s/[^[:alnum:]_.-]//g;
7408
7409     return $name;
7410 }
7411
7412 sub snapshot_name {
7413         my ($project, $hash) = @_;
7414
7415         # path/to/project.git  -> project
7416         # path/to/project/.git -> project
7417         my $name = to_utf8($project);
7418         $name =~ s,([^/])/*\.git$,$1,;
7419         $name = sanitize_for_filename(basename($name));
7420
7421         my $ver = $hash;
7422         if ($hash =~ /^[0-9a-fA-F]+$/) {
7423                 # shorten SHA-1 hash
7424                 my $full_hash = git_get_full_hash($project, $hash);
7425                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7426                         $ver = git_get_short_hash($project, $hash);
7427                 }
7428         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7429                 # tags don't need shortened SHA-1 hash
7430                 $ver = $1;
7431         } else {
7432                 # branches and other need shortened SHA-1 hash
7433                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7434                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7435                         my $ref_dir = (defined $1) ? $1 : '';
7436                         $ver = $2;
7437
7438                         $ref_dir = sanitize_for_filename($ref_dir);
7439                         # for refs neither in heads nor remotes we want to
7440                         # add a ref dir to archive name
7441                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7442                                 $ver = $ref_dir . '-' . $ver;
7443                         }
7444                 }
7445                 $ver .= '-' . git_get_short_hash($project, $hash);
7446         }
7447         # special case of sanitization for filename - we change
7448         # slashes to dots instead of dashes
7449         # in case of hierarchical branch names
7450         $ver =~ s!/!.!g;
7451         $ver =~ s/[^[:alnum:]_.-]//g;
7452
7453         # name = project-version_string
7454         $name = "$name-$ver";
7455
7456         return wantarray ? ($name, $name) : $name;
7457 }
7458
7459 sub exit_if_unmodified_since {
7460         my ($latest_epoch) = @_;
7461         our $cgi;
7462
7463         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7464         if (defined $if_modified) {
7465                 my $since;
7466                 if (eval { require HTTP::Date; 1; }) {
7467                         $since = HTTP::Date::str2time($if_modified);
7468                 } elsif (eval { require Time::ParseDate; 1; }) {
7469                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7470                 }
7471                 if (defined $since && $latest_epoch <= $since) {
7472                         my %latest_date = parse_date($latest_epoch);
7473                         print $cgi->header(
7474                                 -last_modified => $latest_date{'rfc2822'},
7475                                 -status => '304 Not Modified');
7476                         goto DONE_GITWEB;
7477                 }
7478         }
7479 }
7480
7481 sub git_snapshot {
7482         my $format = $input_params{'snapshot_format'};
7483         if (!@snapshot_fmts) {
7484                 die_error(403, "Snapshots not allowed");
7485         }
7486         # default to first supported snapshot format
7487         $format ||= $snapshot_fmts[0];
7488         if ($format !~ m/^[a-z0-9]+$/) {
7489                 die_error(400, "Invalid snapshot format parameter");
7490         } elsif (!exists($known_snapshot_formats{$format})) {
7491                 die_error(400, "Unknown snapshot format");
7492         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7493                 die_error(403, "Snapshot format not allowed");
7494         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7495                 die_error(403, "Unsupported snapshot format");
7496         }
7497
7498         my $type = git_get_type("$hash^{}");
7499         if (!$type) {
7500                 die_error(404, 'Object does not exist');
7501         }  elsif ($type eq 'blob') {
7502                 die_error(400, 'Object is not a tree-ish');
7503         }
7504
7505         my ($name, $prefix) = snapshot_name($project, $hash);
7506         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7507
7508         my %co = parse_commit($hash);
7509         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7510
7511         my $cmd = quote_command(
7512                 git_cmd(), 'archive',
7513                 "--format=$known_snapshot_formats{$format}{'format'}",
7514                 "--prefix=$prefix/", $hash);
7515         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7516                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7517         }
7518
7519         $filename =~ s/(["\\])/\\$1/g;
7520         my %latest_date;
7521         if (%co) {
7522                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7523         }
7524
7525         print $cgi->header(
7526                 -type => $known_snapshot_formats{$format}{'type'},
7527                 -content_disposition => 'inline; filename="' . $filename . '"',
7528                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7529                 -status => '200 OK');
7530
7531         open my $fd, "-|", $cmd
7532                 or die_error(500, "Execute git-archive failed");
7533         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7534         binmode STDOUT, ':raw';
7535         print <$fd>;
7536         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7537         close $fd;
7538 }
7539
7540 sub git_log_generic {
7541         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7542
7543         my $head = git_get_head_hash($project);
7544         if (!defined $base) {
7545                 $base = $head;
7546         }
7547         if (!defined $page) {
7548                 $page = 0;
7549         }
7550         my $refs = git_get_references();
7551
7552         my $commit_hash = $base;
7553         if (defined $parent) {
7554                 $commit_hash = "$parent..$base";
7555         }
7556         my @commitlist =
7557                 parse_commits($commit_hash, 101, (100 * $page),
7558                               defined $file_name ? ($file_name, "--full-history") : ());
7559
7560         my $ftype;
7561         if (!defined $file_hash && defined $file_name) {
7562                 # some commits could have deleted file in question,
7563                 # and not have it in tree, but one of them has to have it
7564                 for (my $i = 0; $i < @commitlist; $i++) {
7565                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7566                         last if defined $file_hash;
7567                 }
7568         }
7569         if (defined $file_hash) {
7570                 $ftype = git_get_type($file_hash);
7571         }
7572         if (defined $file_name && !defined $ftype) {
7573                 die_error(500, "Unknown type of object");
7574         }
7575         my %co;
7576         if (defined $file_name) {
7577                 %co = parse_commit($base)
7578                         or die_error(404, "Unknown commit object");
7579         }
7580
7581
7582         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7583         my $next_link = '';
7584         if ($#commitlist >= 100) {
7585                 $next_link =
7586                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7587                                  -accesskey => "n", -title => "Alt-n"}, "next");
7588         }
7589         my $patch_max = gitweb_get_feature('patches');
7590         if ($patch_max && !defined $file_name &&
7591                 !gitweb_check_feature('email-privacy')) {
7592                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7593                         $paging_nav .= " &sdot; " .
7594                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7595                                         "patches");
7596                 }
7597         }
7598
7599         git_header_html();
7600         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7601         if (defined $file_name) {
7602                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7603         } else {
7604                 git_print_header_div('summary', $project)
7605         }
7606         git_print_page_path($file_name, $ftype, $hash_base)
7607                 if (defined $file_name);
7608
7609         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7610                      $file_name, $file_hash, $ftype);
7611
7612         git_footer_html();
7613 }
7614
7615 sub git_log {
7616         git_log_generic('log', \&git_log_body,
7617                         $hash, $hash_parent);
7618 }
7619
7620 sub git_commit {
7621         $hash ||= $hash_base || "HEAD";
7622         my %co = parse_commit($hash)
7623             or die_error(404, "Unknown commit object");
7624
7625         my $parent  = $co{'parent'};
7626         my $parents = $co{'parents'}; # listref
7627
7628         # we need to prepare $formats_nav before any parameter munging
7629         my $formats_nav;
7630         if (!defined $parent) {
7631                 # --root commitdiff
7632                 $formats_nav .= '(initial)';
7633         } elsif (@$parents == 1) {
7634                 # single parent commit
7635                 $formats_nav .=
7636                         '(parent: ' .
7637                         $cgi->a({-href => href(action=>"commit",
7638                                                hash=>$parent)},
7639                                 esc_html(substr($parent, 0, 7))) .
7640                         ')';
7641         } else {
7642                 # merge commit
7643                 $formats_nav .=
7644                         '(merge: ' .
7645                         join(' ', map {
7646                                 $cgi->a({-href => href(action=>"commit",
7647                                                        hash=>$_)},
7648                                         esc_html(substr($_, 0, 7)));
7649                         } @$parents ) .
7650                         ')';
7651         }
7652         if (gitweb_check_feature('patches') && @$parents <= 1 &&
7653                 !gitweb_check_feature('email-privacy')) {
7654                 $formats_nav .= " | " .
7655                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7656                                 "patch");
7657         }
7658
7659         if (!defined $parent) {
7660                 $parent = "--root";
7661         }
7662         my @difftree;
7663         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7664                 @diff_opts,
7665                 (@$parents <= 1 ? $parent : '-c'),
7666                 $hash, "--"
7667                 or die_error(500, "Open git-diff-tree failed");
7668         @difftree = map { chomp; $_ } <$fd>;
7669         close $fd or die_error(404, "Reading git-diff-tree failed");
7670
7671         # non-textual hash id's can be cached
7672         my $expires;
7673         if ($hash =~ m/^$oid_regex$/) {
7674                 $expires = "+1d";
7675         }
7676         my $refs = git_get_references();
7677         my $ref = format_ref_marker($refs, $co{'id'});
7678
7679         git_header_html(undef, $expires);
7680         git_print_page_nav('commit', '',
7681                            $hash, $co{'tree'}, $hash,
7682                            $formats_nav);
7683
7684         if (defined $co{'parent'}) {
7685                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7686         } else {
7687                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7688         }
7689         print "<div class=\"title_text\">\n" .
7690               "<table class=\"object_header\">\n";
7691         git_print_authorship_rows(\%co);
7692         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7693         print "<tr>" .
7694               "<td>tree</td>" .
7695               "<td class=\"sha1\">" .
7696               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7697                        class => "list"}, $co{'tree'}) .
7698               "</td>" .
7699               "<td class=\"link\">" .
7700               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7701                       "tree");
7702         my $snapshot_links = format_snapshot_links($hash);
7703         if (defined $snapshot_links) {
7704                 print " | " . $snapshot_links;
7705         }
7706         print "</td>" .
7707               "</tr>\n";
7708
7709         foreach my $par (@$parents) {
7710                 print "<tr>" .
7711                       "<td>parent</td>" .
7712                       "<td class=\"sha1\">" .
7713                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7714                                class => "list"}, $par) .
7715                       "</td>" .
7716                       "<td class=\"link\">" .
7717                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7718                       " | " .
7719                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7720                       "</td>" .
7721                       "</tr>\n";
7722         }
7723         print "</table>".
7724               "</div>\n";
7725
7726         print "<div class=\"page_body\">\n";
7727         git_print_log($co{'comment'});
7728         print "</div>\n";
7729
7730         git_difftree_body(\@difftree, $hash, @$parents);
7731
7732         git_footer_html();
7733 }
7734
7735 sub git_object {
7736         # object is defined by:
7737         # - hash or hash_base alone
7738         # - hash_base and file_name
7739         my $type;
7740
7741         # - hash or hash_base alone
7742         if ($hash || ($hash_base && !defined $file_name)) {
7743                 my $object_id = $hash || $hash_base;
7744
7745                 open my $fd, "-|", quote_command(
7746                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7747                         or die_error(404, "Object does not exist");
7748                 $type = <$fd>;
7749                 defined $type && chomp $type;
7750                 close $fd
7751                         or die_error(404, "Object does not exist");
7752
7753         # - hash_base and file_name
7754         } elsif ($hash_base && defined $file_name) {
7755                 $file_name =~ s,/+$,,;
7756
7757                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7758                         or die_error(404, "Base object does not exist");
7759
7760                 # here errors should not happen
7761                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7762                         or die_error(500, "Open git-ls-tree failed");
7763                 my $line = <$fd>;
7764                 close $fd;
7765
7766                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7767                 unless ($line && $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/) {
7768                         die_error(404, "File or directory for given base does not exist");
7769                 }
7770                 $type = $2;
7771                 $hash = $3;
7772         } else {
7773                 die_error(400, "Not enough information to find object");
7774         }
7775
7776         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7777                                           hash=>$hash, hash_base=>$hash_base,
7778                                           file_name=>$file_name),
7779                              -status => '302 Found');
7780 }
7781
7782 sub git_blobdiff {
7783         my $format = shift || 'html';
7784         my $diff_style = $input_params{'diff_style'} || 'inline';
7785
7786         my $fd;
7787         my @difftree;
7788         my %diffinfo;
7789         my $expires;
7790
7791         # preparing $fd and %diffinfo for git_patchset_body
7792         # new style URI
7793         if (defined $hash_base && defined $hash_parent_base) {
7794                 if (defined $file_name) {
7795                         # read raw output
7796                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7797                                 $hash_parent_base, $hash_base,
7798                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7799                                 or die_error(500, "Open git-diff-tree failed");
7800                         @difftree = map { chomp; $_ } <$fd>;
7801                         close $fd
7802                                 or die_error(404, "Reading git-diff-tree failed");
7803                         @difftree
7804                                 or die_error(404, "Blob diff not found");
7805
7806                 } elsif (defined $hash &&
7807                          $hash =~ $oid_regex) {
7808                         # try to find filename from $hash
7809
7810                         # read filtered raw output
7811                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7812                                 $hash_parent_base, $hash_base, "--"
7813                                 or die_error(500, "Open git-diff-tree failed");
7814                         @difftree =
7815                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7816                                 # $hash == to_id
7817                                 grep { /^:[0-7]{6} [0-7]{6} $oid_regex $hash/ }
7818                                 map { chomp; $_ } <$fd>;
7819                         close $fd
7820                                 or die_error(404, "Reading git-diff-tree failed");
7821                         @difftree
7822                                 or die_error(404, "Blob diff not found");
7823
7824                 } else {
7825                         die_error(400, "Missing one of the blob diff parameters");
7826                 }
7827
7828                 if (@difftree > 1) {
7829                         die_error(400, "Ambiguous blob diff specification");
7830                 }
7831
7832                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7833                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7834                 $file_name   ||= $diffinfo{'to_file'};
7835
7836                 $hash_parent ||= $diffinfo{'from_id'};
7837                 $hash        ||= $diffinfo{'to_id'};
7838
7839                 # non-textual hash id's can be cached
7840                 if ($hash_base =~ m/^$oid_regex$/ &&
7841                     $hash_parent_base =~ m/^$oid_regex$/) {
7842                         $expires = '+1d';
7843                 }
7844
7845                 # open patch output
7846                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7847                         '-p', ($format eq 'html' ? "--full-index" : ()),
7848                         $hash_parent_base, $hash_base,
7849                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7850                         or die_error(500, "Open git-diff-tree failed");
7851         }
7852
7853         # old/legacy style URI -- not generated anymore since 1.4.3.
7854         if (!%diffinfo) {
7855                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7856         }
7857
7858         # header
7859         if ($format eq 'html') {
7860                 my $formats_nav =
7861                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7862                                 "raw");
7863                 $formats_nav .= diff_style_nav($diff_style);
7864                 git_header_html(undef, $expires);
7865                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7866                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7867                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7868                 } else {
7869                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7870                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7871                 }
7872                 if (defined $file_name) {
7873                         git_print_page_path($file_name, "blob", $hash_base);
7874                 } else {
7875                         print "<div class=\"page_path\"></div>\n";
7876                 }
7877
7878         } elsif ($format eq 'plain') {
7879                 print $cgi->header(
7880                         -type => 'text/plain',
7881                         -charset => 'utf-8',
7882                         -expires => $expires,
7883                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7884
7885                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7886
7887         } else {
7888                 die_error(400, "Unknown blobdiff format");
7889         }
7890
7891         # patch
7892         if ($format eq 'html') {
7893                 print "<div class=\"page_body\">\n";
7894
7895                 git_patchset_body($fd, $diff_style,
7896                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7897                 close $fd;
7898
7899                 print "</div>\n"; # class="page_body"
7900                 git_footer_html();
7901
7902         } else {
7903                 while (my $line = <$fd>) {
7904                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7905                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7906
7907                         print $line;
7908
7909                         last if $line =~ m!^\+\+\+!;
7910                 }
7911                 local $/ = undef;
7912                 print <$fd>;
7913                 close $fd;
7914         }
7915 }
7916
7917 sub git_blobdiff_plain {
7918         git_blobdiff('plain');
7919 }
7920
7921 # assumes that it is added as later part of already existing navigation,
7922 # so it returns "| foo | bar" rather than just "foo | bar"
7923 sub diff_style_nav {
7924         my ($diff_style, $is_combined) = @_;
7925         $diff_style ||= 'inline';
7926
7927         return "" if ($is_combined);
7928
7929         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7930         my %styles = @styles;
7931         @styles =
7932                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7933
7934         return join '',
7935                 map { " | ".$_ }
7936                 map {
7937                         $_ eq $diff_style ? $styles{$_} :
7938                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7939                 } @styles;
7940 }
7941
7942 sub git_commitdiff {
7943         my %params = @_;
7944         my $format = $params{-format} || 'html';
7945         my $diff_style = $input_params{'diff_style'} || 'inline';
7946
7947         my ($patch_max) = gitweb_get_feature('patches');
7948         if ($format eq 'patch') {
7949                 die_error(403, "Patch view not allowed") unless $patch_max;
7950         }
7951
7952         $hash ||= $hash_base || "HEAD";
7953         my %co = parse_commit($hash)
7954             or die_error(404, "Unknown commit object");
7955
7956         # choose format for commitdiff for merge
7957         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7958                 $hash_parent = '--cc';
7959         }
7960         # we need to prepare $formats_nav before almost any parameter munging
7961         my $formats_nav;
7962         if ($format eq 'html') {
7963                 $formats_nav =
7964                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7965                                 "raw");
7966                 if ($patch_max && @{$co{'parents'}} <= 1 &&
7967                         !gitweb_check_feature('email-privacy')) {
7968                         $formats_nav .= " | " .
7969                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7970                                         "patch");
7971                 }
7972                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7973
7974                 if (defined $hash_parent &&
7975                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7976                         # commitdiff with two commits given
7977                         my $hash_parent_short = $hash_parent;
7978                         if ($hash_parent =~ m/^$oid_regex$/) {
7979                                 $hash_parent_short = substr($hash_parent, 0, 7);
7980                         }
7981                         $formats_nav .=
7982                                 ' (from';
7983                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7984                                 if ($co{'parents'}[$i] eq $hash_parent) {
7985                                         $formats_nav .= ' parent ' . ($i+1);
7986                                         last;
7987                                 }
7988                         }
7989                         $formats_nav .= ': ' .
7990                                 $cgi->a({-href => href(-replay=>1,
7991                                                        hash=>$hash_parent, hash_base=>undef)},
7992                                         esc_html($hash_parent_short)) .
7993                                 ')';
7994                 } elsif (!$co{'parent'}) {
7995                         # --root commitdiff
7996                         $formats_nav .= ' (initial)';
7997                 } elsif (scalar @{$co{'parents'}} == 1) {
7998                         # single parent commit
7999                         $formats_nav .=
8000                                 ' (parent: ' .
8001                                 $cgi->a({-href => href(-replay=>1,
8002                                                        hash=>$co{'parent'}, hash_base=>undef)},
8003                                         esc_html(substr($co{'parent'}, 0, 7))) .
8004                                 ')';
8005                 } else {
8006                         # merge commit
8007                         if ($hash_parent eq '--cc') {
8008                                 $formats_nav .= ' | ' .
8009                                         $cgi->a({-href => href(-replay=>1,
8010                                                                hash=>$hash, hash_parent=>'-c')},
8011                                                 'combined');
8012                         } else { # $hash_parent eq '-c'
8013                                 $formats_nav .= ' | ' .
8014                                         $cgi->a({-href => href(-replay=>1,
8015                                                                hash=>$hash, hash_parent=>'--cc')},
8016                                                 'compact');
8017                         }
8018                         $formats_nav .=
8019                                 ' (merge: ' .
8020                                 join(' ', map {
8021                                         $cgi->a({-href => href(-replay=>1,
8022                                                                hash=>$_, hash_base=>undef)},
8023                                                 esc_html(substr($_, 0, 7)));
8024                                 } @{$co{'parents'}} ) .
8025                                 ')';
8026                 }
8027         }
8028
8029         my $hash_parent_param = $hash_parent;
8030         if (!defined $hash_parent_param) {
8031                 # --cc for multiple parents, --root for parentless
8032                 $hash_parent_param =
8033                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
8034         }
8035
8036         # read commitdiff
8037         my $fd;
8038         my @difftree;
8039         if ($format eq 'html') {
8040                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8041                         "--no-commit-id", "--patch-with-raw", "--full-index",
8042                         $hash_parent_param, $hash, "--"
8043                         or die_error(500, "Open git-diff-tree failed");
8044
8045                 while (my $line = <$fd>) {
8046                         chomp $line;
8047                         # empty line ends raw part of diff-tree output
8048                         last unless $line;
8049                         push @difftree, scalar parse_difftree_raw_line($line);
8050                 }
8051
8052         } elsif ($format eq 'plain') {
8053                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8054                         '-p', $hash_parent_param, $hash, "--"
8055                         or die_error(500, "Open git-diff-tree failed");
8056         } elsif ($format eq 'patch') {
8057                 # For commit ranges, we limit the output to the number of
8058                 # patches specified in the 'patches' feature.
8059                 # For single commits, we limit the output to a single patch,
8060                 # diverging from the git-format-patch default.
8061                 my @commit_spec = ();
8062                 if ($hash_parent) {
8063                         if ($patch_max > 0) {
8064                                 push @commit_spec, "-$patch_max";
8065                         }
8066                         push @commit_spec, '-n', "$hash_parent..$hash";
8067                 } else {
8068                         if ($params{-single}) {
8069                                 push @commit_spec, '-1';
8070                         } else {
8071                                 if ($patch_max > 0) {
8072                                         push @commit_spec, "-$patch_max";
8073                                 }
8074                                 push @commit_spec, "-n";
8075                         }
8076                         push @commit_spec, '--root', $hash;
8077                 }
8078                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
8079                         '--encoding=utf8', '--stdout', @commit_spec
8080                         or die_error(500, "Open git-format-patch failed");
8081         } else {
8082                 die_error(400, "Unknown commitdiff format");
8083         }
8084
8085         # non-textual hash id's can be cached
8086         my $expires;
8087         if ($hash =~ m/^$oid_regex$/) {
8088                 $expires = "+1d";
8089         }
8090
8091         # write commit message
8092         if ($format eq 'html') {
8093                 my $refs = git_get_references();
8094                 my $ref = format_ref_marker($refs, $co{'id'});
8095
8096                 git_header_html(undef, $expires);
8097                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
8098                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
8099                 print "<div class=\"title_text\">\n" .
8100                       "<table class=\"object_header\">\n";
8101                 git_print_authorship_rows(\%co);
8102                 print "</table>".
8103                       "</div>\n";
8104                 print "<div class=\"page_body\">\n";
8105                 if (@{$co{'comment'}} > 1) {
8106                         print "<div class=\"log\">\n";
8107                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
8108                         print "</div>\n"; # class="log"
8109                 }
8110
8111         } elsif ($format eq 'plain') {
8112                 my $refs = git_get_references("tags");
8113                 my $tagname = git_get_rev_name_tags($hash);
8114                 my $filename = basename($project) . "-$hash.patch";
8115
8116                 print $cgi->header(
8117                         -type => 'text/plain',
8118                         -charset => 'utf-8',
8119                         -expires => $expires,
8120                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8121                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
8122                 print "From: " . to_utf8($co{'author'}) . "\n";
8123                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
8124                 print "Subject: " . to_utf8($co{'title'}) . "\n";
8125
8126                 print "X-Git-Tag: $tagname\n" if $tagname;
8127                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
8128
8129                 foreach my $line (@{$co{'comment'}}) {
8130                         print to_utf8($line) . "\n";
8131                 }
8132                 print "---\n\n";
8133         } elsif ($format eq 'patch') {
8134                 my $filename = basename($project) . "-$hash.patch";
8135
8136                 print $cgi->header(
8137                         -type => 'text/plain',
8138                         -charset => 'utf-8',
8139                         -expires => $expires,
8140                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8141         }
8142
8143         # write patch
8144         if ($format eq 'html') {
8145                 my $use_parents = !defined $hash_parent ||
8146                         $hash_parent eq '-c' || $hash_parent eq '--cc';
8147                 git_difftree_body(\@difftree, $hash,
8148                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8149                 print "<br/>\n";
8150
8151                 git_patchset_body($fd, $diff_style,
8152                                   \@difftree, $hash,
8153                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8154                 close $fd;
8155                 print "</div>\n"; # class="page_body"
8156                 git_footer_html();
8157
8158         } elsif ($format eq 'plain') {
8159                 local $/ = undef;
8160                 print <$fd>;
8161                 close $fd
8162                         or print "Reading git-diff-tree failed\n";
8163         } elsif ($format eq 'patch') {
8164                 local $/ = undef;
8165                 print <$fd>;
8166                 close $fd
8167                         or print "Reading git-format-patch failed\n";
8168         }
8169 }
8170
8171 sub git_commitdiff_plain {
8172         git_commitdiff(-format => 'plain');
8173 }
8174
8175 # format-patch-style patches
8176 sub git_patch {
8177         git_commitdiff(-format => 'patch', -single => 1);
8178 }
8179
8180 sub git_patches {
8181         git_commitdiff(-format => 'patch');
8182 }
8183
8184 sub git_history {
8185         git_log_generic('history', \&git_history_body,
8186                         $hash_base, $hash_parent_base,
8187                         $file_name, $hash);
8188 }
8189
8190 sub git_search {
8191         $searchtype ||= 'commit';
8192
8193         # check if appropriate features are enabled
8194         gitweb_check_feature('search')
8195                 or die_error(403, "Search is disabled");
8196         if ($searchtype eq 'pickaxe') {
8197                 # pickaxe may take all resources of your box and run for several minutes
8198                 # with every query - so decide by yourself how public you make this feature
8199                 gitweb_check_feature('pickaxe')
8200                         or die_error(403, "Pickaxe search is disabled");
8201         }
8202         if ($searchtype eq 'grep') {
8203                 # grep search might be potentially CPU-intensive, too
8204                 gitweb_check_feature('grep')
8205                         or die_error(403, "Grep search is disabled");
8206         }
8207
8208         if (!defined $searchtext) {
8209                 die_error(400, "Text field is empty");
8210         }
8211         if (!defined $hash) {
8212                 $hash = git_get_head_hash($project);
8213         }
8214         my %co = parse_commit($hash);
8215         if (!%co) {
8216                 die_error(404, "Unknown commit object");
8217         }
8218         if (!defined $page) {
8219                 $page = 0;
8220         }
8221
8222         if ($searchtype eq 'commit' ||
8223             $searchtype eq 'author' ||
8224             $searchtype eq 'committer') {
8225                 git_search_message(%co);
8226         } elsif ($searchtype eq 'pickaxe') {
8227                 git_search_changes(%co);
8228         } elsif ($searchtype eq 'grep') {
8229                 git_search_files(%co);
8230         } else {
8231                 die_error(400, "Unknown search type");
8232         }
8233 }
8234
8235 sub git_search_help {
8236         git_header_html();
8237         git_print_page_nav('','', $hash,$hash,$hash);
8238         print <<EOT;
8239 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8240 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8241 the pattern entered is recognized as the POSIX extended
8242 <a href="https://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8243 insensitive).</p>
8244 <dl>
8245 <dt><b>commit</b></dt>
8246 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8247 EOT
8248         my $have_grep = gitweb_check_feature('grep');
8249         if ($have_grep) {
8250                 print <<EOT;
8251 <dt><b>grep</b></dt>
8252 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8253     a different one) are searched for the given pattern. On large trees, this search can take
8254 a while and put some strain on the server, so please use it with some consideration. Note that
8255 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8256 case-sensitive.</dd>
8257 EOT
8258         }
8259         print <<EOT;
8260 <dt><b>author</b></dt>
8261 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8262 <dt><b>committer</b></dt>
8263 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8264 EOT
8265         my $have_pickaxe = gitweb_check_feature('pickaxe');
8266         if ($have_pickaxe) {
8267                 print <<EOT;
8268 <dt><b>pickaxe</b></dt>
8269 <dd>All commits that caused the string to appear or disappear from any file (changes that
8270 added, removed or "modified" the string) will be listed. This search can take a while and
8271 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8272 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8273 EOT
8274         }
8275         print "</dl>\n";
8276         git_footer_html();
8277 }
8278
8279 sub git_shortlog {
8280         git_log_generic('shortlog', \&git_shortlog_body,
8281                         $hash, $hash_parent);
8282 }
8283
8284 ## ......................................................................
8285 ## feeds (RSS, Atom; OPML)
8286
8287 sub git_feed {
8288         my $format = shift || 'atom';
8289         my $have_blame = gitweb_check_feature('blame');
8290
8291         # Atom: http://www.atomenabled.org/developers/syndication/
8292         # RSS:  https://web.archive.org/web/20030729001534/http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8293         if ($format ne 'rss' && $format ne 'atom') {
8294                 die_error(400, "Unknown web feed format");
8295         }
8296
8297         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8298         my $head = $hash || 'HEAD';
8299         my @commitlist = parse_commits($head, 150, 0, $file_name);
8300
8301         my %latest_commit;
8302         my %latest_date;
8303         my $content_type = "application/$format+xml";
8304         if (defined $cgi->http('HTTP_ACCEPT') &&
8305                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8306                 # browser (feed reader) prefers text/xml
8307                 $content_type = 'text/xml';
8308         }
8309         if (defined($commitlist[0])) {
8310                 %latest_commit = %{$commitlist[0]};
8311                 my $latest_epoch = $latest_commit{'committer_epoch'};
8312                 exit_if_unmodified_since($latest_epoch);
8313                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8314         }
8315         print $cgi->header(
8316                 -type => $content_type,
8317                 -charset => 'utf-8',
8318                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8319                 -status => '200 OK');
8320
8321         # Optimization: skip generating the body if client asks only
8322         # for Last-Modified date.
8323         return if ($cgi->request_method() eq 'HEAD');
8324
8325         # header variables
8326         my $title = "$site_name - $project/$action";
8327         my $feed_type = 'log';
8328         if (defined $hash) {
8329                 $title .= " - '$hash'";
8330                 $feed_type = 'branch log';
8331                 if (defined $file_name) {
8332                         $title .= " :: $file_name";
8333                         $feed_type = 'history';
8334                 }
8335         } elsif (defined $file_name) {
8336                 $title .= " - $file_name";
8337                 $feed_type = 'history';
8338         }
8339         $title .= " $feed_type";
8340         $title = esc_html($title);
8341         my $descr = git_get_project_description($project);
8342         if (defined $descr) {
8343                 $descr = esc_html($descr);
8344         } else {
8345                 $descr = "$project " .
8346                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8347                          " feed";
8348         }
8349         my $owner = git_get_project_owner($project);
8350         $owner = esc_html($owner);
8351
8352         #header
8353         my $alt_url;
8354         if (defined $file_name) {
8355                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8356         } elsif (defined $hash) {
8357                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8358         } else {
8359                 $alt_url = href(-full=>1, action=>"summary");
8360         }
8361         $alt_url = esc_attr($alt_url);
8362         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8363         if ($format eq 'rss') {
8364                 print <<XML;
8365 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8366 <channel>
8367 XML
8368                 print "<title>$title</title>\n" .
8369                       "<link>$alt_url</link>\n" .
8370                       "<description>$descr</description>\n" .
8371                       "<language>en</language>\n" .
8372                       # project owner is responsible for 'editorial' content
8373                       "<managingEditor>$owner</managingEditor>\n";
8374                 if (defined $logo || defined $favicon) {
8375                         # prefer the logo to the favicon, since RSS
8376                         # doesn't allow both
8377                         my $img = esc_url($logo || $favicon);
8378                         print "<image>\n" .
8379                               "<url>$img</url>\n" .
8380                               "<title>$title</title>\n" .
8381                               "<link>$alt_url</link>\n" .
8382                               "</image>\n";
8383                 }
8384                 if (%latest_date) {
8385                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8386                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8387                 }
8388                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8389         } elsif ($format eq 'atom') {
8390                 print <<XML;
8391 <feed xmlns="http://www.w3.org/2005/Atom">
8392 XML
8393                 print "<title>$title</title>\n" .
8394                       "<subtitle>$descr</subtitle>\n" .
8395                       '<link rel="alternate" type="text/html" href="' .
8396                       $alt_url . '" />' . "\n" .
8397                       '<link rel="self" type="' . $content_type . '" href="' .
8398                       $cgi->self_url() . '" />' . "\n" .
8399                       "<id>" . esc_url(href(-full=>1)) . "</id>\n" .
8400                       # use project owner for feed author
8401                       "<author><name>$owner</name></author>\n";
8402                 if (defined $favicon) {
8403                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8404                 }
8405                 if (defined $logo) {
8406                         # not twice as wide as tall: 72 x 27 pixels
8407                         print "<logo>" . esc_url($logo) . "</logo>\n";
8408                 }
8409                 if (! %latest_date) {
8410                         # dummy date to keep the feed valid until commits trickle in:
8411                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8412                 } else {
8413                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8414                 }
8415                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8416         }
8417
8418         # contents
8419         for (my $i = 0; $i <= $#commitlist; $i++) {
8420                 my %co = %{$commitlist[$i]};
8421                 my $commit = $co{'id'};
8422                 # we read 150, we always show 30 and the ones more recent than 48 hours
8423                 if (($i >= 20) && ((time - $co{'committer_epoch'}) > 48*60*60)) {
8424                         last;
8425                 }
8426                 my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
8427
8428                 # get list of changed files
8429                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8430                         $co{'parent'} || "--root",
8431                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8432                         or next;
8433                 my @difftree = map { chomp; $_ } <$fd>;
8434                 close $fd
8435                         or next;
8436
8437                 # print element (entry, item)
8438                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8439                 if ($format eq 'rss') {
8440                         print "<item>\n" .
8441                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8442                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8443                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8444                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8445                               "<link>" . esc_html($co_url) . "</link>\n" .
8446                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8447                               "<content:encoded>" .
8448                               "<![CDATA[\n";
8449                 } elsif ($format eq 'atom') {
8450                         print "<entry>\n" .
8451                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8452                               "<updated>$cd{'iso-8601'}</updated>\n" .
8453                               "<author>\n" .
8454                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8455                         if ($co{'author_email'}) {
8456                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8457                         }
8458                         print "</author>\n" .
8459                               # use committer for contributor
8460                               "<contributor>\n" .
8461                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8462                         if ($co{'committer_email'}) {
8463                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8464                         }
8465                         print "</contributor>\n" .
8466                               "<published>$cd{'iso-8601'}</published>\n" .
8467                               "<link rel=\"alternate\" type=\"text/html\" href=\"" . esc_attr($co_url) . "\" />\n" .
8468                               "<id>" . esc_html($co_url) . "</id>\n" .
8469                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8470                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8471                 }
8472                 my $comment = $co{'comment'};
8473                 print "<pre>\n";
8474                 foreach my $line (@$comment) {
8475                         $line = esc_html($line);
8476                         print "$line\n";
8477                 }
8478                 print "</pre><ul>\n";
8479                 foreach my $difftree_line (@difftree) {
8480                         my %difftree = parse_difftree_raw_line($difftree_line);
8481                         next if !$difftree{'from_id'};
8482
8483                         my $file = $difftree{'file'} || $difftree{'to_file'};
8484
8485                         print "<li>" .
8486                               "[" .
8487                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8488                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8489                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8490                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8491                                       -title => "diff"}, 'D');
8492                         if ($have_blame) {
8493                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8494                                                              file_name=>$file, hash_base=>$commit),
8495                                               -title => "blame"}, 'B');
8496                         }
8497                         # if this is not a feed of a file history
8498                         if (!defined $file_name || $file_name ne $file) {
8499                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8500                                                              file_name=>$file, hash=>$commit),
8501                                               -title => "history"}, 'H');
8502                         }
8503                         $file = esc_path($file);
8504                         print "] ".
8505                               "$file</li>\n";
8506                 }
8507                 if ($format eq 'rss') {
8508                         print "</ul>]]>\n" .
8509                               "</content:encoded>\n" .
8510                               "</item>\n";
8511                 } elsif ($format eq 'atom') {
8512                         print "</ul>\n</div>\n" .
8513                               "</content>\n" .
8514                               "</entry>\n";
8515                 }
8516         }
8517
8518         # end of feed
8519         if ($format eq 'rss') {
8520                 print "</channel>\n</rss>\n";
8521         } elsif ($format eq 'atom') {
8522                 print "</feed>\n";
8523         }
8524 }
8525
8526 sub git_rss {
8527         git_feed('rss');
8528 }
8529
8530 sub git_atom {
8531         git_feed('atom');
8532 }
8533
8534 sub git_opml {
8535         my @list = git_get_projects_list($project_filter, $strict_export);
8536         if (!@list) {
8537                 die_error(404, "No projects found");
8538         }
8539
8540         print $cgi->header(
8541                 -type => 'text/xml',
8542                 -charset => 'utf-8',
8543                 -content_disposition => 'inline; filename="opml.xml"');
8544
8545         my $title = esc_html($site_name);
8546         my $filter = " within subdirectory ";
8547         if (defined $project_filter) {
8548                 $filter .= esc_html($project_filter);
8549         } else {
8550                 $filter = "";
8551         }
8552         print <<XML;
8553 <?xml version="1.0" encoding="utf-8"?>
8554 <opml version="1.0">
8555 <head>
8556   <title>$title OPML Export$filter</title>
8557 </head>
8558 <body>
8559 <outline text="git RSS feeds">
8560 XML
8561
8562         foreach my $pr (@list) {
8563                 my %proj = %$pr;
8564                 my $head = git_get_head_hash($proj{'path'});
8565                 if (!defined $head) {
8566                         next;
8567                 }
8568                 $git_dir = "$projectroot/$proj{'path'}";
8569                 my %co = parse_commit($head);
8570                 if (!%co) {
8571                         next;
8572                 }
8573
8574                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8575                 my $rss  = esc_attr(href('project' => $proj{'path'}, 'action' => 'rss', -full => 1));
8576                 my $html = esc_attr(href('project' => $proj{'path'}, 'action' => 'summary', -full => 1));
8577                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8578         }
8579         print <<XML;
8580 </outline>
8581 </body>
8582 </opml>
8583 XML
8584 }